More miscellany from the outstanding bugs list

[CamDawg]

The offensive Cleric script casts Chaotic Commands at enemies, and the offensive Mage script at the caster - I do rather enjoy the ray on enfeeblement cast on self.

 

// please don't cast chaotic commands on enemies
COPY ~scripts/cleric1.bs~ ~scripts/cleric1.bs~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~See(NearestEnemyOf(Myself))\([%tab% %lnl%%mnl%%wnl%]HaveSpell(CLERIC_CHAOTIC_COMMANDS)\)~ 
  ~False()~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

// targets for the misc heals are poorly defined, can be mistargeted
COPY ~scripts/cleric2.bs~ ~scripts/cleric2.bs~
 ~scripts/cleric3.bs~ ~scripts/cleric3.bs~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~\(HPPercentLT(LastSeenBy(Myself),10)\~ ~See([PC]) \1~
REPLACE_TEXTUALLY ~MostDamagedOf(Myself)~ ~MostDamagedOf([PC])~
REPLACE_TEXTUALLY ~Spell(MostDamagedOf(Myself),CLERIC_CURE_LIGHT_WOUNDS)~ Spell(Myself,CLERIC_CURE_LIGHT_WOUNDS)~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

// please don't cast ray of enfeeblement on yourself
COPY ~scripts/mage3.bs~ ~scripts/mage3.bs~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~Spell(Myself,WIZARD_RAY_OF_ENFEEBLEMENT)~ ~Spell(LastSeenBy(Myself),WIZARD_RAY_OF_ENFEEBLEMENT)~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

Blades were not receiving their one-half penalty to their Pick Pockets ability - Ah, nothing more fun than hacking around the engine. cdblpp[1-5] are all pickpocket adjustment spells.

// blade pp fix
COPY_EXISTING ~clabba02.2da~ ~override~
 SET_2DA_ENTRY_LATER ~blade~ 8 1 ~AP_CDBLPP1~
 FOR (col = 2; col < 18; col = col + 2) BEGIN
SET_2DA_ENTRY_LATER ~blade~ 8 col ~AP_CDBLPP3~
 END
 FOR (col = 3; col < 18; col = col + 2) BEGIN
SET_2DA_ENTRY_LATER ~blade~ 8 col ~AP_CDBLPP2~
 END
 FOR (col = 17; col < 37; col = col + 2) BEGIN
SET_2DA_ENTRY_LATER ~blade~ 8 col ~AP_CDBLPP4~
 END
 FOR (col = 18; col < 37; col = col + 2) BEGIN
SET_2DA_ENTRY_LATER ~blade~ 8 col ~AP_CDBLPP5~
 END
 SET_2DA_ENTRIES_NOW ~blade~ 1
 BUT_ONLY_IF_IT_CHANGES

 

Tolgerias' (Gov't. District/Sphere) messenger Madeen would still tell the player to see Tolgerias and leave a journal entry even if Tolgerias was already dead - Another victim of Tolgerias's split DV personality.

 

// madeen should go away if Tolgerias dead--check for other DV
EXTEND_TOP ~madeen.bcs~ ~bg2fixpack/baf/madeen.baf~

IF
 Dead("TOLGER")
THEN
 RESPONSE #100
DestroySelf()
END

 

Sea's Bounty wench would fail to note if Edwin had been changed into a female - since she mentions his beard and flirts, should add a gender check here.

// gracie at sea's bounty shouldn't flirt with edwina or mention her beard
ADD_STATE_TRIGGER ~SBWENCH~ 6 ~Gender("Edwin",MALE)~

 

Dialog loop with Viconia if the protagonist was female where she would ask "What brought you to the Life?" repeatedly - Didn't find a loop, but the banter could occur more than once since one response wasn't setting the LOCALS tracking variable.

// Viccy not setting variable to track whether this talk has occurred
ADD_TRANS_ACTION BVICONI
BEGIN 27 END
BEGIN 1 END
~SetGlobal("BViconia12","LOCALS",1)~

 

NPC dialogue with Bodhi does not reflect the fact that the player knows Gaelan's offer is reduced to 15K gold - Korgan and Yoshimo both mention how the deal is so much better because you're saving gold, even if you've talked to Gaelan and he's informed you that you only need 15k. A variable for tracking whether Gaelan has reduced the required gold is now set, and Yoshimo and Korgan no longer make these comments if the offers are known to be identical. This one's borderline; thoughts?

 

// interjections to bodhi now reflect that party members know gaelan has sweetened deal
ADD_TRANS_ACTION GAELAN BEGIN 51 85 END BEGIN END ~SetGlobal("CDGaelanSweetensOffer","GLOBAL",1)~
ADD_TRANS_TRIGGER BODHI	  6 ~Global("CDGaelanSweetensOffer","GLOBAL",0)~ DO 11 12
ADD_TRANS_TRIGGER ANOMENJ  222 ~Global("CDGaelanSweetensOffer","GLOBAL",0)~ DO 1 2
ADD_TRANS_TRIGGER AERIEJ	88 ~Global("CDGaelanSweetensOffer","GLOBAL",0)~ DO 2 3
ADD_TRANS_TRIGGER VALYGARJ  88 ~Global("CDGaelanSweetensOffer","GLOBAL",0)~ DO 3 4
ADD_TRANS_TRIGGER MINSCJ   126 ~Global("CDGaelanSweetensOffer","GLOBAL",0)~ DO 4 5
ADD_TRANS_TRIGGER JAHEIRAJ 408 ~Global("CDGaelanSweetensOffer","GLOBAL",0)~ DO 5 6
ADD_TRANS_TRIGGER MAZZYJ   149 ~Global("CDGaelanSweetensOffer","GLOBAL",0)~ DO 6 7
ADD_TRANS_TRIGGER KELDORJ  154 ~Global("CDGaelanSweetensOffer","GLOBAL",0)~ DO 7 8

 

I'll knock out some more of these tomorrow.

[CamDawg]

The Fallen Deva was using the Deva's AI script instead of its own, so its death animation was wrong; also contained a check for disease on the PC and casting Cure Disease so removed this as the check for this state was never implemented - The state exists; is it not being set by the disease opcode? Script is easy:

 

// fallen devas using normal deva script
COPY_EXISTING ~devaevil.cre~ ~override~
 PATCH_IF (SOURCE_SIZE > 0x2d3) THEN BEGIN // protects against invalid files
WRITE_ASCII 0x248 ~devaevil~ // override script
 END
 BUT_ONLY_IF_IT_CHANGES

 

The Deva had only one memorized Globe Of Blades and Cure Serious Wounds, but the Fallen Deva had three of both - also easy:

 

// normal devas don't have as many spells memorized as fallen devas
COPY_EXISTING ~devagood.cre~ ~override~
 PATCH_IF (SOURCE_SIZE > 0x2d3) THEN BEGIN // protects against invalid files
ADD_MEMORIZED_SPELL ~SPPR502~ #4 ~priest~ // cure critical wounds
ADD_MEMORIZED_SPELL ~SPPR502~ #4 ~priest~ // cure critical wounds
ADD_MEMORIZED_SPELL ~SPPR725~ #6 ~priest~ // globe o' blades
ADD_MEMORIZED_SPELL ~SPPR725~ #6 ~priest~ // globe o' blades
 END
 BUT_ONLY_IF_IT_CHANGES

 

Captain Rerdes could be killed in Lady Galvena's room in the Brynnlaw Festhall and would reappear when player went back into the hallway - Rerdes appearing is controlled by the SpawnCaptain global, but it was using an area variable in Lady Galvena's room.

 

// multiple rerdes due to bad var scope
COPY ~ar1613.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~"SpawnCaptain","AR1613"~ ~"SpawnCaptain","GLOBAL"~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

Warhammer +1,+4 vs. Giant Humanoids was not giving the THAC0/damage bonuses vs. giant humanoids indicated - The bonuses were being run through EFF files, filtered in the same way as the extra effects. In short, only giants would get bonuses against other giants. Changed so that any wielder gets bonuses against giants. Skullcrusher had similar issues, though they probably weren't making much of a difference since non-humanoid PCs are fairly rare.

 

// damage/thac0 bonuses mistargeted, may not be applying
COPY_EXISTING ~blun18.itm~ ~override~ // skullcrusher
		  ~hamm04.itm~ ~override~ // hammer +1/+4 v giantkin
 READ_LONG   0x64 "abil_off"
 READ_SHORT  0x68 "abil_num"
 READ_LONG   0x6a "fx_off"
 READ_SHORT  0x70 "fx_num"
 FOR (index2 = 0; index2 < fx_num; index2 = index2 + 1) BEGIN
READ_SHORT ("%fx_off%" +		(0x30 * "%index2%")) "opcode"
PATCH_IF ("%opcode%" = 177) BEGIN
  WRITE_LONG ("%fx_off%" + 0x04 + (0x30 * "%index2%")) 0 // any
  WRITE_LONG ("%fx_off%" + 0x08 + (0x30 * "%index2%")) 2 // ea.ids
END
 END
 FOR (index = 0; index < abil_num; index = index + 1) BEGIN
READ_SHORT  ("%abil_off%" + 0x20 + ("%index%" * 0x38)) "abil_fx_idx"
READ_SHORT  ("%abil_off%" + 0x1e + ("%index%" * 0x38)) "abil_fx_num"
FOR (index3 = 0; index3 < abil_fx_num; index3 = index3 + 1) BEGIN
  READ_SHORT ("%fx_off%" +		(0x30 * ("%index3%" + "%abil_fx_idx%"))) "opcode"
  PATCH_IF ("%opcode%" = 177) BEGIN
	WRITE_LONG ("%fx_off%" + 0x04 + (0x30 * ("%index3%" + "%abil_fx_idx%"))) 0 // any
	WRITE_LONG ("%fx_off%" + 0x08 + (0x30 * ("%index3%" + "%abil_fx_idx%"))) 2 // ea.ids
  END
END
 END
 BUT_ONLY_IF_IT_CHANGES

 

 

Crimson Chain typo: thread - Darkmail +3 typo: thread - Also included Elven Chain +1 (CHAN13), Sylvan Chain +2 (CHAN14), Bladesinger Chain +4 (CHAN16). These are unusable by archers, but the descriptions are not reflecting this. Fixed via GTU.

 

Not listed on the list, but Flame Tongue's description doesn't mention its +1 THAC0 bonus. Fixed via GTU.

 

Also not on the list, but if Mekrath gave you the mission to retrieve his mirror from the imp, he wouldn't clear the journal entry under some dialogue branches. If you also just decided to kill him instead, the journal entry will never disappear.

 

// mekrath not clearing his journal entry; also see
ADD_TRANS_ACTION MEKRAT
BEGIN 15 END
BEGIN 1 END
~EraseJournalEntry(4660)~

Added to the area script:

IF
 Dead("Mekrath")
 Global("CDClearJournal","MYAREA",0)
THEN
 RESPONSE #100
EraseJournalEntry(4660)
SetGlobal("CDClearJournal","MYAREA",1)
END

 

Ring of Djinni summoning behaves differently than other summoning items: thread - Kinda fixed. The issue here is that your summoning item is supposed to disappear if the summoned djinni dies. If its HPs drop below five, it destroys your ring and disappears--but this doesn't account for all of the other ways you can die like insta-kill spells and stat drains. I've assigned the djinni a DV and added scripting to baldur(25).bcs to destroy the ring if the djinni is dead, but it still leaves one issue. If the djinni is destroyed via death spell or death fog, it's removed and not considered technically dead by the engine. Any ideas on how to get by this?

 

COPY_EXISTING ~sumdjinn.cre~ ~override~
 WRITE_EVALUATED_ASCII 0x280 ~%SOURCE_RES%~ #18
 BUT_ONLY_IF_IT_CHANGES

EXTEND_BOTTOM ~baldur.bcs~   ~bg2fixpack/baf/sumdj01.baf~
EXTEND_BOTTOM ~baldur25.bcs~ ~bg2fixpack/baf/sumdj01.baf~

IF
 Dead("sumdjinn")
 PartyHasItem("ring26")
THEN
 RESPONSE #100
DisplayStringHead(Player1,3035) // With the death of your Djinni, the summoning ring vanishes.
TakePartyItem("ring26") // Ring of Djinni Summoning
DestroyItem("ring26") // Ring of Djinni Summoning
END

 

Stalkers not getting proper backstab bonuses: thread - Another GTU error. Stalkers max backstab bonuses at x3 by design, but the GTU kit description indicates bonuses up to x5; original description is correct here. The confusion arises from the stalker's original SoA CLAB file--it lays out a progression all the way up to x6 backstab bonuses, but with the XP cap the best you'd actually see was x3 at level 17. With ToB, the levels beyond 17 were obtainable but the backstab multipliers were removed by Bioware, meaning the best you could do remained x3. The kit description has been corrected in the GTU to reflect that the max backstab bonus is x3.

[Nythrun]

STATE_DISEASED is not set by most (all?) types of disease. One more for Detectable Spells, if disease were common enough that anyone cared.

 

IF
 Die()
THEN
 Response #100
YouCantHaveNiceThings()
END

in sumdj01.bcs? (Please don't put stuff in baldur.bcs that's not limited by variables, please?)

 

Stalker description is something of a mess, as every class has a X1 backstab bonus (i.e., they do damage * 1). They cap at quadruple damage, which is listed in the kit description as though it were X3. GTU the multipliers to \(double\|triple\|quadruple\) ?

[CamDawg]

Healer scripts don't recognize when allies have been dominated/charmed so heal them while fighting them; Planetars' healer scripts are the same if the Planetar is hostile - The first half wanders into the area of trying to make sensible scripts, which is well beyond the scope of the Fixpack. The second half is quite nice though--hostile fallen planetars summoned via wish still had a "let's help the PC script" assigned which would cause them to, for example, cast restoration on level-drained party members. planet01 (another hostile planetar) has no script at all, but seems unused AFAICT.

 

// hostile planetars via wish would still cast spells to benefit the party
COPY_EXISTING ~planwish.cre~ ~override~ // hostile planetar summoned via wish
 PATCH_IF (SOURCE_SIZE > 0x2d3) BEGIN // protects against invalid files
WRITE_ASCII 0x248 ~planet01~ // override script
 END
 BUT_ONLY_IF_IT_CHANGES

 

Weapons that add to attacks/round ruin GWW, Dual-wielding messes up WW and GWW HLA's attacks/round - A combination of ApR overflow (similar to the spin + Melf's Minute Meteor issues already faced) and haste disabling offhand attacks. We really need to come up with a generalized solution for the former; not much can be done for the latter.

 

On both party rest dialogs in the Viconia romance in ToB, no resting would occur; on the latter she would gain all her spells back as if she had rested - Heh. There are no RestParty() calls on the former, and only Rest() call on the latter (and a few branches end with none, too). I poked around all of the dream scripts; Anomen also has one in SoA where the party doesn't rest. Also noticed a broken branch in an Aerie LT if you tell Viconia to get bent. So:

 

// when NPC have just-before-rest LTs, often don't properly rest the party
ADD_TRANS_ACTION BANOMEN
BEGIN 370 END
BEGIN END
~RestParty()~
REPLACE_ACTION_TEXT ~bvicon25~ ~Rest()~ ~RestParty()~
ADD_TRANS_ACTION ~bvicon25~
BEGIN 81 82 127 END
BEGIN END
~RestParty()~

// one option to tell off viccy in aerie LT prematurely ends dialogue
EXTEND_BOTTOM BVICONI 548
IF ~~ THEN EXTERN BAERIE 434
END

[CamDawg]

(Please don't put stuff in baldur.bcs that's not limited by variables, please?)

Not that I deserve it, but let's give me a little credit. My experiences with Die() have been flaky, at best. I was hoping baldur.bcs would catch the destruction from death fog, but no dice--might as well stick it back in sumdj01.bcs.

 

Stalker description is something of a mess, as every class has a X1 backstab bonus (i.e., they do damage * 1). They cap at quadruple damage, which is listed in the kit description as though it were X3. GTU the multipliers to \(double\|triple\|quadruple\) ?

Good point, will do.

[Nythrun]

Not that I deserve it, but let's give me a little credit. .

 

No. Sorry.

 

 

 

 

You get oodles of credit instead, I just forget sometimes that you don't subscribe to the same "Die() and AttackOneRound() actually do work" heresy that I do

 

The only fully-extensible solution I know for APR madness is energy blades style 4.5 attacks per round (which will hit 5 when an offhand weapon is equipped or if you have fighter levels). Nobody likes it, though

[CamDawg]

Cutscene in upper levels of Ust Natha (priestess, drow and duergar) could be cut off at the edge of the screen and therefore unviewable - Added a call to center the screen on the priestess and add a cutspy to view the scene.

 

// ust natha scenery cutscene can occur offscreen, meaning player stands in dark for no apparent reason
COPY_EXISTING ~dadrow20.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~StartCutSceneMode()~ 
  ~StartCutSceneMode() CreateCreature("cutspy",[3864.273],0) MoveViewPoint([3864.273],INSTANT)~
REPLACE_TEXTUALLY ~EscapeArea()~
  ~EscapeArea() ActionOverride("cutspy",DestroySelf()) MoveViewObject(Player1,INSTANT)~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

Exploit of healing Imoen when she leaves the group at 1 HP in Irenicus' dungeon then inviting her back in the group as unkillable damage-soaker - Just make her escape uninterruptable.

// close exploit of forcing imoen to rejoin in CI when trying to run away
ADD_TRANS_ACTION IMOENP
BEGIN 3 END
BEGIN END
~SetInterrupt(FALSE) DialogInterrupt(FALSE)~

 

Dialog for Llarsh at the Council building would sometimes not recognize when Valygar had been found, so player could present the Corthala Tax Notice and the journal entry for this would never disappear - Add tracking variable to Valygar's dialogue:

// add traking variable to meeting valygar...
ADD_TRANS_ACTION VALYGAR
BEGIN 0 END
BEGIN END
~SetGlobal("CDMetBigV","GLOBAL",1)~
// ... so that you can no longer ask about how to find him
ADD_TRANS_TRIGGER LLARSH 0 ~Global("CDMetBigV","GLOBAL",0)~ DO 1 2
ADD_TRANS_TRIGGER LLARSH 2 ~Global("CDMetBigV","GLOBAL",0)~ DO 0 1

 

Minor script bug with Arledrian's (upper level of Gaelan Bayle's house) attack when the player sided with Bodhi - Area script was using the wrong scope in its action, causing the block to always be true and send Arledrian a constant stream of ActionOverrides.

 

// Arledrian goes hostile but stands there due to area script bug
COPY_EXISTING ~ar0312.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~SetGlobal("ArledHostile","GLOBAL",1)~ ~SetGlobal("ArledHostile","AR0312",1)~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

If Hervo was killed/abused by the player with Valygar in the party, Valygar would go hostile but remain in-party unselectable and immobile - Added a LeaveParty() to this script block.

 

// valygar goes hostile if something happens to hervo, but should leave the party first
COPY_EXISTING ~valygar.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~SetGlobal("vgAttackTheParty","LOCALS",1)~ ~SetGlobal("vgAttackTheParty","LOCALS",1) LeaveParty()~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

[CamDawg]

If Valygar was imprisoned/petrified and restored before Tolgerias was dead, he would drop his "Valygar's Body" item and it would remain after he rejoined. - Easy fix; add this to the bottom of baldur.bcs:

 

IF
 !Dead("Valygar")
 PartyHasItem("misc7l")
THEN
 RESPONSE #100
TakePartyItem("misc7l")
DestroyItem("misc7l")
END

 

The audio resource for four of Higgold's dialogs was incorrect - Fixed via GTU. He was using his 'bravo, bravo' sound file for lines about problems in the play.

[CamDawg]

This is, I believe, the last of the low-hanging fruit from the outstanding bugs list.

 

If the leader fanatic was spoken to right after Viconia was rescued, he would either respond or instantly kill her, as though she hadn't been rescued - Just add a check to make sure she isn't free already:

// viconia shouldn't be burned at stake if she's been freed
ADD_STATE_TRIGGER ~VICG1~ 7 ~!Global("ViconiaFree","AR1000",1)~

 

The Mimic in the Umar Hills cave was not immune to its own Mimic Glue so would entrap itself - All of the WK mimics have an item called wallpass which allows them to ignore collision detection. Does this also prevent them from being trapped in their glue or does it just mean it allows them to escape being on top of their chests? Is it something that should be added to the other mimics? At any rate, this will make all of them immune to their glue:

// mimics should be immune to their own glue
COPY_EXISTING ~gormim01.cre~ ~override~ // killer mimic
		  ~gormim02.cre~ ~override~ // killer mimic
		  ~gormim03.cre~ ~override~ // killer mimic
		  ~gormim04.cre~ ~override~ // killer mimic
		  ~jugmim01.cre~ ~override~ // killer mimic
		  ~mimic01.cre~  ~override~ // killer mimic
 PATCH_IF (SOURCE_SIZE > 0x2d3) BEGIN
READ_LONG   0x2c4 "fx_off"
READ_SHORT  0x2c8 "fx_num"
WRITE_SHORT 0x2c8 ("%fx_num%" + 1)
READ_BYTE   0x33 "fx_type"
INSERT_BYTES   ("%fx_off%"							  ) (0x30 + (0xd8 * "%fx_type%"))
  WRITE_SHORT  ("%fx_off%"		+ (0x08 * "%fx_type%")) 206		  // immunity to spell
  WRITE_LONG   ("%fx_off%" + 0x04 + (0x10 * "%fx_type%")) 0xffffffff   // mull string
  WRITE_BYTE   ("%fx_off%" + 0x0c + (0x10 * "%fx_type%")) 1			// instant/permanent
  WRITE_BYTE   ("%fx_off%" + 0x12 + (0x12 * "%fx_type%")) 100		  // probability
  WRITE_LONG   ("%fx_off%" + 0x14 + (0x14 * "%fx_type%")) ~spin914~	// mimic glue
// fix offsets
SET "inserted" = ((0x30 + (0xd8 * "%fx_type%")) * "%new_fx%")
READ_LONG 0x2a0 "known_off"
PATCH_IF ("%fx_off%" < "%known_off%") BEGIN
  WRITE_LONG 0x2a0 ("%known_off%" + "%inserted%")
END
READ_LONG 0x2a8 "mem_info"
PATCH_IF ("%fx_off%" < "%mem_info%") BEGIN
  WRITE_LONG 0x2a8 ("%mem_info%" + "%inserted%")
END
READ_LONG 0x2b0 "mem_off"
PATCH_IF ("%fx_off%" < "%mem_off%") BEGIN
  WRITE_LONG 0x2b0 ("%mem_off%" + "%inserted%")
END
READ_LONG 0x2b8 "slot_off"
PATCH_IF ("%fx_off%" < "%slot_off%") BEGIN
  WRITE_LONG 0x2b8 ("%slot_off%" + "%inserted%")
END
READ_LONG 0x2bc "itm_off"
PATCH_IF ("%fx_off%" < "%itm_off%") BEGIN
  WRITE_LONG 0x2bc ("%itm_off%" + "%inserted%")
END
 END
 BUT_ONLY_IF_IT_CHANGES

[CamDawg]

We lost the posts from Nythrun and devSin re: the mimic glue (and my question about wallpass.itm) and the Imoen exploit. Mimics do need immunity to their own glue as it can paralyze them. Adding wallpass.itm to the Umar Hills mimic should allow it to actually be inside its chest, if I understand correctly, instead of sitting right outside of it.

[devSin]

Both sound fine. I don't think the glue immunity is actually necessary, but it's not going to hurt anything. wallpass similarly doesn't matter, but there's no harm in adding it.

 

Die() works fine. You can't detect the DestroySelf() code run by DESTSELF, so it will just be an edge case.

 

EscapeArea() is already uninterruptible (both dialogue and script). Imoen was funking for some other reason (I don't know if I could ever reproduce this on a ToB install).

 

STATE_DISEASED should be STATE_DEACTIVATED. Conveniently, returns true if Deactivate()d and false if Activate()d. There's no way to track disease in a default install.

[devSin]

The offensive Cleric script casts Chaotic Commands at enemies, and the offensive Mage script at the caster

MostDamagedOf() is proper usage. This object always returns the most damaged PC.

 

The Mimic in the Umar Hills cave was not immune to its own Mimic Glue so would entrap itself

Mimic glue is a party target spell that doesn't use an AoE projectile? Mimics are *not* susceptible to it.

 

The Deva had only one memorized Globe Of Blades and Cure Serious Wounds, but the Fallen Deva had three of both

Note that ADD_MEMORIZED_SPELL is bugged in the current version of WeiDU (a fix exists, but you have to patch and recompile from source).

[CamDawg]

The offensive Cleric script casts Chaotic Commands at enemies, and the offensive Mage script at the caster

MostDamagedOf() is proper usage. This object always returns the most damaged PC.

Cheers.

 

The Mimic in the Umar Hills cave was not immune to its own Mimic Glue so would entrap itself

Mimic glue is a party target spell that doesn't use an AoE projectile? Mimics are *not* susceptible to it.

Check, filed for the Department of Redundancy Department.

 

The Deva had only one memorized Globe Of Blades and Cure Serious Wounds, but the Fallen Deva had three of both

Note that ADD_MEMORIZED_SPELL is bugged in the current version of WeiDU (a fix exists, but you have to patch and recompile from source).

What's the issue? It seems to be working when I tested it--spells were added, offsets seemed correct.

[devSin]

It isn't correctly handling the memorizable table. Shouldn't be a real issue for NPCs.

[devSin]

NPC dialogue with Bodhi does not reflect the fact that the player knows Gaelan's offer is reduced to 15K gold

I don't favor this. Bodhi herself makes the same mistake; I agree that it's a silly continuity issue, but I think it's along the lines of just poor design (or an after-effect of late plot changes) and not something we should worry about enforcing?