Making changes to existing game data

[St_Vitruvius]

I've tried to make the changes to SUELLE2.DLG. This is the first 7 states from the original .dlg:

 

BEGIN ~SUELLE2~

IF ~NumTimesTalkedTo(0)~ THEN BEGIN 0 // from:
 SAY #55236 /* ~Ah... I see that you have finally come to.  I almost did not believe it when the priestesses told me that your body was showing signs of life once again.~ [ELLESI19] */
 IF ~~ THEN GOTO 1
END

IF ~~ THEN BEGIN 1 // from: 0.0
 SAY #55237 /* ~We resurrected who we could, but it seemed nothing would draw your spirit back.  We were about to give up when you began to stir this morning.~ */
 IF ~~ THEN REPLY #55238 /* ~H-how... how long was I...?~ */ GOTO 2
END

IF ~~ THEN BEGIN 2 // from: 1.0
 SAY #55239 /* ~Dead?  A couple of days, no more.  However you managed to find your way back, it is good that you have done so.~ */
 IF ~ReputationLT(Player1,10)~ THEN GOTO 3
 IF ~ReputationGT(Player1,9)~ THEN GOTO 6
END

IF ~~ THEN BEGIN 3 // from: 2.0
 SAY #55240 /* ~Despite your reputation, you have done a great service for the elves and Suldanessellar, and to lose you to death after all that has occurred would be a terrible thing.~ */
 IF ~~ THEN GOTO 4
END

IF ~~ THEN BEGIN 4 // from: 3.0
 SAY #55241 /* ~I have planned a small ceremony to reward you for your actions, and to show our gratitude despite what your motives might have been.~ */
 IF ~~ THEN GOTO 5
END

IF ~~ THEN BEGIN 5 // from: 4.0
 SAY #55242 /* ~You should rest, now, and regain your strength.  I will send a priestess to awaken you when it is time.~ */
 IF ~~ THEN DO ~ClearAllActions()
StartCutSceneMode()
StartCutScene("cut59b")~ EXIT
END

IF ~~ THEN BEGIN 6 // from: 2.1
 SAY #55243 /* ~You have done a great service for Suldanessellar. You saved the Tree of Life and myself, ending Irenicus' threat. To lose you would have been tragic.~ */
 IF ~~ THEN GOTO 7
END

 

This is what I wrote in my .tp2:

//Editing of Ellesimes Dialogue file: SUELLE2.DLG
COPY_EXISTING SUELLE2.DLG

ADD_TRANS_TRIGGER SUELLE2.DLG 4 False() [DO 0] ///////WeiDu Error-message
EXTEND_BOTTOM SUELLE2.DLG 4 IF ~~ THEN GOTO Mod1

APPEND SUELLE2.DLG

IF ~~ THEN BEGIN Mod1 // From: 4.0
  SAY @17 /* ~You should rest, now, and regain your strength. Feel free to walk about in the city as you like. Go to se Rhistel at the gates to the palace. But do come and see me, when you are ready to leave the city.~ */
   IF ~~ THEN EXIT
END

IF ~NumTimesTalkedToGT(0)~ THEN BEGIN Mod2 // From:
  SAY @18 /* ~Hello <CHARNAME>, are you prepared to depart our fair city and resume your travels?~ */
   IF ~~ THEN REPLY @19 GOTO Mod3 /* ~Yes, I'm.~ */
   IF ~~ THEN REPLY @20 GOTO Mod4 /* ~No, not quite yet..~ */
END

IF ~~ THEN BEGIN Mod3 // From: Mod2.1
  SAY @21 /* ~Then I shall assemble the people.~ */
   IF ~~ THEN DO ~ClearAllActions()
   StartCutSceneMode()
   StartCutScene("cut59b")~ EXIT
END

IF ~~ THEN BEGIN Mod4 // From: Mod2.2
  SAY @22 /* ~Then I will wait untill you are ready..~ */
   IF ~~ THEN EXIT
END

END

 

When installing weidu tells me somethings is wrong at the indicated line in my tp2 (4th line).. What did I do wrong?

[Rabain]

Add trans trigger should be:

 

ADD_TRANS_TRIGGER SUELLE2 4 ~False()~

 

When quoting dialogs etc don't use the file extension. Same goes for your Extend on the line underneath.

 

Strings should be inside tildes ~~ .

[St_Vitruvius]

So what about the EXTEND_BOTTOM? it gives me another error message on that line when using this:

 

//Editing of Ellesimes Dialogue file: SUELLE2.DLG
COPY_EXISTING SUELLE2.DLG

ADD_TRANS_TRIGGER SUELLE2 4 ~False()~ DO 0
EXTEND_BOTTOM SUELLE2 4 ~IF ~~ THEN GOTO Mod1~

APPEND SUELLE2.DLG

 

It worked for ADD_TRANS_TRIGGER, but in the latter I use ~IF ~~ THEN GOTO Mod1~

[Rabain]

Yeah you get used to the formats pretty quickly:

 

EXTEND_BOTTOM SUELLE2 4 IF ~~ THEN GOTO Mod1

END (you need the END to tell weidu to stop Extending at this point)

 

There are examples for most of these in the weidu readme:

 

http://www.weidu.org/~thebigg/README-WeiDU.html

 

Just search for the command you are looking for, it might be the second, third, fourth result etc. There is a table explaining the command but further down there may be a tutorial on how to use it!

 

The other option is to download an npc mod and take a look at its files, most mods will contain examples of these.

 

Also I noticed your Append at the bottom which should take the format:

 

APPEND SUELLE2

IF ~~ THEN BEGIN Mod1

SAY ~I love Elves!~

IF ~~ THEN REPLY ~Yeah so what!~ EXIT (or GOTO or whatever)

IF ~~ THEN REPLY ~So do I!~ EXIT

END

END (you want an END at the bottom of your APPEND so that weidu will know when to stop appending, this is separate to the END just above it which is telling the game to END the state here.)

[St_Vitruvius]

It is still giving me an error message on EXTEND_BOTTOM:

 

[SETUP-ELVEN_PACK.TP2] PARSE ERROR at line 977 column 1-13
Near Text: EXTEND_BOTTOM
syntax error

[SETUP-ELVEN_PACK.TP2]  ERROR at line 977 column 1-13
Near Text: EXTEND_BOTTOM
Parsing.Parse_error
ERROR: parsing [SETUP-ELVEN_PACK.TP2]: Parsing.Parse_error
ERROR: problem parsing TP file [SETUP-ELVEN_PACK.TP2]: Parsing.Parse_error

FATAL ERROR: Parsing.Parse_error

 

I've uploaded the whole tp2 here.

 

I've tried to make it as close to the example in the readme, so now I've got this:

 

//Editing of Ellesimes Dialogue file: SUELLE2.DLG
COPY_EXISTING SUELLE2.DLG

ADD_TRANS_TRIGGER SUELLE2 4 ~False()~ DO 0
EXTEND_BOTTOM SUELLE2 4 
  IF ~~ THEN GOTO Mod1
END

[St_Vitruvius]

I've found out it must be some error in the syntax of my tp2.. I've tried overwriting the existing dialogue file and that works fine. But I cannot find my mistake in the tp2. If I'm not able to find it I'll stick to overwriting the file untill someone points at the mistake and bashes me in the head..

 

The next problem I've run into is how I make changes to existing area scripts.. I'll use extend for the scripts too, but how do I "remove" all the dead, panicked hostile characters from Suldanessellar?

[Mike1072]

It is still giving me an error message on EXTEND_BOTTOM:

//Editing of Ellesimes Dialogue file: SUELLE2.DLG
COPY_EXISTING SUELLE2.DLG

ADD_TRANS_TRIGGER SUELLE2 4 ~False()~ DO 0
EXTEND_BOTTOM SUELLE2 4 
  IF ~~ THEN GOTO Mod1
END

I had looked at this before and looked up the syntax for EXTEND_BOTTOM and ADD_TRANS_TRIGGER and couldn't see anything wrong with it. I suspected it wasn't directly related to the EXTEND_BOTTOM though, as error messages often just indicate the general area of a problem. Looking at it again, I'm thinking your problem is with the COPY_EXISTING. See if this fixes it:

 

COPY_EXISTING ~SUELLE2.DLG~ ~override~

I'm still forgetting the majority of these things when making my tiny little .tp2 files so don't feel like you're the only one.

[St_Vitruvius]

Hmm.. That did change something.. Now it's complaining about the IF ~~ THEN GOTO Mod1:

 

Near Text: IF
syntax error

[SETUP-ELVEN_PACK.TP2]  ERROR at line 979 column 4-5
Near Text: IF
Parsing.Parse_error
ERROR: parsing [SETUP-ELVEN_PACK.TP2]: Parsing.Parse_error
ERROR: problem parsing TP file [SETUP-ELVEN_PACK.TP2]: Parsing.Parse_error

 

Do I need to put some form of identifiers, like ~, around the line?

[Mike1072]

Hmm.. That did change something.. Now it's complaining about the IF ~~ THEN GOTO Mod1:

 

Near Text: IF
syntax error

[SETUP-ELVEN_PACK.TP2]  ERROR at line 979 column 4-5
Near Text: IF
Parsing.Parse_error
ERROR: parsing [SETUP-ELVEN_PACK.TP2]: Parsing.Parse_error
ERROR: problem parsing TP file [SETUP-ELVEN_PACK.TP2]: Parsing.Parse_error

 

Do I need to put some form of identifiers, like ~, around the line?

Try putting quotes around the filename like this:

EXTEND_BOTTOM ~SUELLE2~ 4
  IF ~~ THEN GOTO Mod1
END

[St_Vitruvius]

No change.. Still the same error message...

[cmorgan]

what is the DO 0?

 

Most A_T_A and E_B stuff works

 

 

Hey - hold on...

 

you do know that these actions are supposed to be in the COMPILE ~myDialogue.D~ format and file, right?

 

The .tp2 line:

 

COMPILE ~myModDialogue.D~

 

the contents of the independent file to be compiled:

filename myModDialogue.D:

/*  never used this myself, so i don't know - I E_B and divert to a new state completely, to avoid complications... but it is a D action, not a tp2 action :) 
ADD_TRANS_TRIGGER filename stateNumber transTriggerString [ moreStateNumbers list ] [ DO transNumber list ] */

ADD_TRANS_TRIGGER ~SUELLE2~ 4 ~False()~  DO 0 
/* so this will add ~False()~  to the first transition in state 4, I believe... */

EXTEND_BOTTOM ~SUELLE2~ 4 
IF ~~ THEN GOTO Mod1
END

/* add into existing SUELLE2.DLG via compiled D */
APPEND ~SUELLE2~

IF ~~ THEN BEGIN Mod1
SAY  ~You should rest, now, and regain your strength. Feel free to walk about in the city as you like. Go to se Rhistel at the gates to the palace. But do come and see me, when you are ready to leave the city.~
IF ~~ THEN EXIT
END

IF ~NumTimesTalkedToGT(0)~ THEN BEGIN Mod2	
SAY ~Hello <CHARNAME>, are you prepared to depart our fair city and resume your travels?~		
IF ~~ THEN REPLY @19 GOTO Mod3 /* ~Yes, I'm.~
IF ~~ THEN REPLY @20 GOTO Mod4
END

IF ~~ THEN BEGIN Mod3 
SAY ~Then I shall assemble the people.~
IF ~~ THEN DO ~ClearAllActions()
   StartCutSceneMode()
   StartCutScene("cut59b")~ EXIT
END

IF ~~ THEN BEGIN Mod4	
SAY @22 /* ~Then I will wait untill you are ready..~ */
IF ~~ THEN EXIT
END

END

 

Unless you do inlined D files, which right now don't work quite completely (see plainab's notes to the bigg on PPG's WeiDU forum).

 

Your .D file needs a separate .tra file, too, or can be linked the way you have earlier in the tp2 using USING.

 

so, quick recap, I think what is happening is you are using D actions in your tp2. Your tp2 needs to COMPILE ~myFile.D~ and it will put all the materials where they are supposed to go (or where you tell it!).

 

You do not need to copy the .DLG or D file or anything. The D file actions are what tells WeiDU how to manipulate the .DLG.

[Mike1072]

Unless you do inlined D files, which right now don't work quite completely (see plainab's notes to the bigg on PPG's WeiDU forum).

I just looked this up, as I hadn't heard of it. To summarize it: name your inlined .D files in uppercase or else you might get an error when using certain commands.

 

So, you can either move your current code to a new .D file as cmorgan illustrated and add a COMPILE statement, or change what you've got now in the .tp2 to the following, which will (hopefully) make this work with a minimum amount of effort.

 

//Editing of Ellesimes Dialogue file: SUELLE2.DLG
//COPY_EXISTING ~SUELLE2.DLG~ ~override~ // remove this line, the COMPILE will take care of it
<<<<<<<< .../ELVEN_PACK_INLINED/ELLE2DLG.D // went overboard on the caps to make sure it worked
ADD_TRANS_TRIGGER ~SUELLE2~ 4 ~False()~ DO 0
......
etc...
......
IF ~~ THEN BEGIN Mod4 // From: Mod2.2
  SAY @22 /* ~Then I will wait untill you are ready..~ */
   IF ~~ THEN EXIT
END

END
>>>>>>>>

COMPILE ~.../ELVEN_PACK_INLINED/ELLE2DLG.D~
USING ~elven_pack/languages/english/ELLE2DLG.TRA~

 

And make sure you've added the little quotes around all the SUELLE2s, heh.

[St_Vitruvius]

@cmorgan: No, I wasn't aware of that.. I've tried doing it now, and it works like a charm... Thanks a lot..

 

@Mike1072: What does the caps do? If I've understood it right, you tell weidu that there is a file called ELLE2DLG.D containing that text?

[Mike1072]

@cmorgan: No, I wasn't aware of that.. I've tried doing it now, and it works like a charm... Thanks a lot..

 

@Mike1072: What does the caps do? If I've understood it right, you tell weidu that there is a file called ELLE2DLG.D containing that text?

The >>>>>>> becomes the contents of this "inlined file". For a better description, you should probably go here Since it's almost 6:00am I'm probably not be coming across very clearly.

 

Anyways, I stressed the name of the inlined file being in caps as I followed up on cmorgan's mention of oddities with inlined .D files on the PPG forum, where there were problems discovered with ADD_TRANS_ACTION and another command when declaring them using this method, but the errors could be avoided by not using lowercase letters in the filename.

 

To be clear, this method and the one cmorgan described are pretty much the same, the text is just in different spots. I kind of regret posting my last post now as I seem to have muddled things up a bit.