One ToB Worldmap Issue

[CamDawg]

The travel time from Abizigal's Lair to Watcher's Keep is 28 hours, but the return journey is 36.

[DavidW]

The travel time from Abizigal's Lair to Watcher's Keep is 28 hours, but the return journey is 36.

 

Does that actually have to be a bug? Doesn't Abazigal live on a mountain-top? - climbing uphill is probably slower work.

[CamDawg]

The other three areas which link to Abizigal's lair on the worldmap have consistent times in both travel directions. Plus Marching Mountains should have the same travel bias, but don't.

[DavidW]

The other three areas which link to Abizigal's lair on the worldmap have consistent times in both travel directions. Plus Marching Mountains should have the same travel bias, but don't.

 

Sold.

[CamDawg]

// travel time fix for abazigal <--> WK
COPY_EXISTING ~worldm25.wmp~ ~override~
 READ_LONG 0x0c "mos_off"
 READ_LONG ("%mos_off%" + 0x20) "area_num"
 READ_LONG ("%mos_off%" + 0x24) "area_off"
 READ_LONG ("%mos_off%" + 0x28) "link_off"
 FOR (index = 0 ; index < area_num ; index = index + 1) BEGIN
   READ_ASCII ("%area_off%" + 0x08 + ("%index%" * 0xf0)) "area"
   PATCH_IF ("%area%" STRING_COMPARE_CASE "ar3000" = 0) BEGIN // wk
     SET "wk" = "%index%"
   END ELSE
   PATCH_IF ("%area%" STRING_COMPARE_CASE "ar6000" = 0) BEGIN // abazigal
     SET "abazigal" = "%index%"
   END
 END
 // read links
 FOR (index2 = 0 ; index2 < 4 ; index2 = index2 + 1) BEGIN
   READ_LONG ("%area_off%" + 0x50 + ("%index2%" * 0x08) + ("%wk%" * 0xf0)) "link_idx"
   READ_LONG ("%area_off%" + 0x54 + ("%index2%" * 0x08) + ("%wk%" * 0xf0)) "link_num"
   FOR (index3 = 0 ; index3 < link_num ; index3 = index3 + 1) BEGIN
     READ_LONG ("%link_off%" +        (("%link_idx%" + "%index3%") * 0xd8)) "target"
     PATCH_IF ("%target%" = "%abazigal%") BEGIN
       WRITE_LONG ("%link_off%" + 0x24 + (("%link_idx%" + "%index3%") * 0xd8)) 9 // travel time
     END
   END
 END
 BUT_ONLY_IF_IT_CHANGES