Bodhi fight: wrong Drizzt DV reference in bcs

[jastey]

I noticed something while woking with Drizzt files. If the PC goes to face Bodhi to retrieve the Lanthorpe, he/she can ask for help in the Order, from the shadow thieves and from Drizzt.

 

In the knight's and the thief's script, there is a check whether PC got charmed and whether the fight is over, including checks for Drizzt:

 

C6ARKAN.bcs:

IF
StateCheck(Player1,STATE_CHARMED)
Global("C6Player1Charmed","GLOBAL",0)
OR(2)
	!See("c6drizz")
	Dead("c6drizz") // Drizzt
OR(2)
	!See("c6eric")
	Dead("c6eric") // Eric Vanstraaten
THEN
RESPONSE #100
	SetGlobal("C6Player1Charmed","GLOBAL",1)
	DisplayStringHead(Myself,55525) // Der Vampir hat <CHARNAME> unter seiner Kontrolle! <PRO_HESHE> greift an!
END

IF
Dead("c6bodhi") // Bodhi
Global("C6BodhiDead","AR0809",0)
See([PC])
OR(2)
	!See("c6drizz")
	Dead("c6drizz") // Drizzt
OR(2)
	!See("c6eric")
	Dead("c6eric") // Eric Vanstraaten
CombatCounter(0)
THEN
RESPONSE #100
	SetGlobal("C6BodhiDead","AR0809",1)
	DisplayStringHead(Myself,55914) // Es ist vollbracht, <CHARNAME>. Ich werde zu Aran gehen und ihm von unserem Erfolg berichten.
END

 

C6ERIC.bcs:

 

IF
StateCheck(Player1,STATE_CHARMED)
Global("C6Player1Charmed","GLOBAL",0)
OR(2)
	!See("c6drizz")
	Dead("c6drizz") // Drizzt
THEN
RESPONSE #100
	SetGlobal("C6Player1Charmed","GLOBAL",1)
	DisplayStringHead(Myself,55525) // Der Vampir hat <CHARNAME> unter seiner Kontrolle! <PRO_HESHE> greift an!
END

IF
Dead("c6bodhi") // Bodhi
CombatCounter(0)
Global("C6BodhiDead","AR0809",0)
See([PC])
OR(2)
	!See("c6drizz")
	Dead("c6drizz") // Drizzt
THEN
RESPONSE #100
	SetGlobal("C6BodhiDead","AR0809",1)
	DisplayStringHead(Myself,55918) // Es war ein großartiger Kampf. Ich muss jetzt anderswo wieder meinen Pflichten nachkommen. Ich bin stolz darauf, dieses Böse mit Euch bekämpft zu haben.
END

 

Problem is, the correct DC for Drizzt in Bodhi's lair would be "c6drizz2".

[CamDawg]

Nice catch. It looks like they're supposed to defer those lines to Drizzt if he's present; instead get two characters chiming in with identical lines. Fixed:

 

// ch 6 allies check wrong drizzt DV
COPY_EXISTING ~c6arkan.bcs~ ~override~
		  ~c6eric.bcs~  ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~("c6drizz")~ ~("c6drizz2")~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES