Jump to content

Can this .d file be fixed?


ericp07

Recommended Posts

Hello,

 

Every attempt to install a mod called Azure (a joinable NPC "Azure" and a druid kit "Nature's Ally") fails on my system, and contacting the author has gotten me no response. So, I'm wondering if anyone can tell what's wrong with this .d, and what's needed to correct it so that the mod might install properly. If necessary, I'll try installing again so I can copy the error message. I took the liberty of correcting some spelling and grammar issues, but there might still be some present in the lines of dialog.

 

BEGIN ~AZUREJ~

 

IF WEIGHT #1

~!Global("SharoHuntDay","GLOBAL",0)

!Global("SharoHuntDay","GLOBAL",5)

!Global("SharoHuntDay","GLOBAL",6)

OR(4)

Global("AzureInParty","GLOBAL",1)

Global("AzureInParty","GLOBAL",2)

Global("AzureInParty","GLOBAL",3)

Global("AzureInParty","GLOBAL",4)~ THEN BEGIN 0

SAY ~We still haven't found Sharo. Please, we have to hurry. He is probably worried, about me.~

IF ~~ THEN EXIT

END

 

IF WEIGHT #2

~Global("AzureInParty","GLOBAL",1)

Global("SharoHuntDay","GLOBAL",5)~ THEN BEGIN 1

SAY ~This is pointless. I cannot waste more time with you, <CHARNAME>. It is obvious you have no intention to look for Sharo.~

IF ~~ THEN REPLY ~This is not true, Azure. Just give us more time, I am sure we'll find him.~ GOTO 2

IF ~~ THEN REPLY ~I am sorry, Azure. I don't have time to look for you lost pet. Probably you should go on your own.~ GOTO 3

END

 

IF ~~ THEN BEGIN 2

SAY ~I give you one more day. If we haven't found Sharo by then, I will deprive myself of your company.~

IF ~~ THEN DO ~SetGlobalTimer("AzureLookForSharo","GLOBAL",ONE_DAY)~ EXIT

END

 

IF ~~ THEN BEGIN 3

SAY ~Al right, then. I doubt we shall see each other again. I wish you well, regardless.~

IF ~~ THEN DO ~SetGlobal("AzureKickedOut","GLOBAL",1)

SetGlobal("AzureInParty","GLOBAL",0)

EscapeArea()~ EXIT

END

 

IF WEIGHT #3

~Global("SharoHuntDay","GLOBAL",6)~ THEN BEGIN 4

SAY ~The time I gave you is over and Sharo is yet separated from me. I cannot continue with you. Fare thee well.~

IF ~~ THEN DO ~SetGlobal("AzureKickedOut","GLOBAL",1)

SetGlobal("AzureInParty","GLOBAL",0)

EscapeArea()~ EXIT

END

 

IF WEIGHT #4

~Global("SharoMet","GLOBAL",0)

Global("SharoInParty","GLOBAL",1)

!Global("AzureMatch","GLOBAL",1)~ THEN BEGIN 5

SAY ~There you are, Sharo. Did you miss me (patting him on the head), boy? Don't you ever run away from me again!~

IF ~~ THEN DO ~SetGlobal("SharoMet","GLOBAL",1)

SetGlobal("SharoJumpOn","GLOBAL",1)~ EXIT

END

 

IF WEIGHT #5

~Global("SharoMet","GLOBAL",0)

Global("SharoInParty","GLOBAL",1)

Global("AzureMatch","GLOBAL",1)~ THEN BEGIN 6

SAY ~There you are, Sharo. Did you miss me (patting him on the head), boy? Don't you ever run away from me again!~

IF ~~ THEN DO ~SetGlobal("SharoMet","GLOBAL",1)

SetGlobal("SharoJumpOn","GLOBAL",1)

SetGlobal("AzureRomanceActive","GLOBAL",1)

RealSetGlobalTimer("AzureRomance","GLOBAL",1500)~ EXIT

END

 

//Romance talks

IF WEIGHT #6

~Global("AzureLoveTalk","GLOBAL",1)~ THEN BEGIN 7

SAY ~Come to think of it, I never thanked you for helping me find Sharo. Know that I haven't forgotten and that I appreciate what you did.~

IF ~~ THEN REPLY ~You don't have to thank me. It was really nothing. After all, the point of traveling together is to help and support each other. Just the way Sharo and you do.~ GOTO 8

IF ~~ THEN REPLY ~Don't mention it. I'd do it for anyone. I just have this urge to aid distressed folks.~ GOTO 9

IF ~~ THEN REPLY ~I only did it to keep you in the group. Don't make such racket because of it.~ GOTO 10

END

 

IF ~~ THEN BEGIN 8

SAY ~There is merit in your words. But you have my gratitude, regardless. I don't think I could have dealt with loosing Sharo. We've been through a lot together.~

IF ~~ THEN REPLY ~When we first met, you said that Sharo "chose" you. What did you mean?~ GOTO 12

END

 

IF ~~ THEN BEGIN 9

SAY ~Well, I thank you anyway. I don't think I could have dealt with loosing Sharo. We've been through a lot together.~

IF ~~ THEN REPLY ~When we first met, you said that Sharo "chose" you. What did you mean?~ GOTO 12

END

 

IF ~~ THEN BEGIN 10

SAY ~I expected a kinder response, but I thank you anyway. In the end, regardless of your motivation, stands the fact that you helped me. I don't think I could have dealt with loosing Sharo. We've been through a lot together.~

IF ~~ THEN REPLY ~All right, all right. Look, Azure. I really don't want to talk about it. Can you just keep it to yourself?~ GOTO 11

IF ~~ THEN REPLY ~When we first met, you said that Sharo "chose" you. What did you mean?~ GOTO 12

END

 

IF ~~ THEN BEGIN 11

SAY ~(Azure looks at you disappointedly.) I'm sorry. I won't bother you again. But I'm sure there are more polite ways to say that you don't want to speak with me.~

IF ~~ THEN DO ~SetGlobal("AzureRomanceActive","GLOBAL",2)~ EXIT

END

 

IF ~~ THEN BEGIN 12

SAY ~Sharo is one of the first memories I have from Amn. Four years ago, I was... resuscitated by his voice. Or at least what I thought to be his voice.~

=

~There was this voice. It told me to open my eyes, and so I did.~

=

~I was in the middle of a forest I didn't know of. I was lying on the cold ground, naked. I had only this medallion with me (she shows you the wolf amulet). I still don't know how it got into my possession.~

=

~And there was Sharo. He was sitting not but fifteen feet away from me. He rose, approached me, and licked my nose. He's followed me since. I decided to call him Sharo, as it is a popular name for a dog, where I once lived.~

IF ~~ THEN DO ~RealSetGlobalTimer("AzureRomance","GLOBAL",1000)~ EXIT

END

 

 

IF WEIGHT #7

~Global("AzureLoveTalk","GLOBAL",2)~ THEN BEGIN 13

SAY ~I think Sharo likes you~

IF ~~ THEN REPLY ~What makes you say that?~ GOTO 14

END

 

IF ~~ THEN BEGIN 14

SAY ~Well, he's jumping around you, waving his tail, keeps staring at your hands. You must have given him some food, haven't you?~

IF ~~ THEN REPLY ~You caught me red-handed. I gave him a couple of brownies this morning, while you were still sleeping.~ GOTO 15

IF ~~ THEN REPLY ~(Playing dumb) I don't know what you are talking about. He just likes me. In fact all animals do. They become so joyful at my sight.~ GOTO 16

END

 

IF ~~ THEN BEGIN 15

SAY ~I knew it! I knew it! He's acting like a child who ate too much sugar beet. For future reference, don't give Sharo, or any other animal, nourishment containing sugar or cocoa. He can get very sick, even his teeth might fall.~

IF ~~ THEN DO ~RealSetGlobalTimer("AzureRomance","GLOBAL",1100)~ EXIT

END

 

IF ~~ THEN BEGIN 16

SAY ~(CHUCKLE)All right, Mr. Animal Friend. I know you did something naughty. Be careful from now on! I have my eye on you.~

IF ~~ THEN DO ~RealSetGlobalTimer("AzureRomance","GLOBAL",1100)~ EXIT

END

 

IF WEIGHT #8

~Global("AzureLoveTalk","GLOBAL",3)~ THEN BEGIN 17

SAY ~<CHARNAME>, do you want to hear what happened after I woke up in the forest?~

IF ~~ THEN REPLY ~What makes you think I want to know anything about you? Just keep your mouth shut and move your flat druid backside.~ GOTO 18

IF ~~ THEN REPLY ~Sure. Do tell, please!~ GOTO 19

END

 

IF ~~ THEN BEGIN 18

SAY ~How can you be so rude!?! Don't you have any feelings? You're heart is as cold as the taint it bears. I will never speak to you again! That I promise.~

IF ~~ THEN DO ~SetGlobal("AzureRomanceActive","GLOBAL",2)~ EXIT

END

 

IF ~~ THEN BEGIN 19

SAY ~As soon as I was able to pull myself together, I began to search for a path within the trees or a stream, which would lead me to a village of some sort.~

=

~Apparently, the forest was very large, because I wandered for three days with no sign of human or any other intelligent life. I didn't starve as there were plenty of blackberry and raspberry bushes to be found. Once Sharo brought me a dead rat, which he probably strangled. It was a welcome addition to my diet.~

=

~In the end I came upon a group of elves, who were hunting. They were very kind to me. One of them gave me his cloak and I quickly wrapped myself with it.~

=

~They told me I was in the forest of Tethir, which I had never heard of before. I spent the next two days with them, as they promised to take me to a nearby druid hut as soon as they had enough game. They told me that the wolf that was following me was no ordinary animal.~

=

~Kiral, who was a cleric by trade and calling, said that he could see a halo about Sharo. As if he had a godly blessing upon him, but much stronger than usual.~

=

~When their hunt was over, they kept their promise and took me to the druids.~

IF ~~ THEN REPLY ~What happened then?~ GOTO 20

IF ~~ THEN REPLY ~You were lucky to find the elves. Tethir is a vast forest. You could have wandered for much longer than just three days.~ GOTO 20

END

 

IF ~~ THEN BEGIN 20

SAY ~The druids welcomed me with open arms. They taught me of their ways, about the nature and the importance of balance. I was far away from my home, of which the druids had no knowledge, and I had little else to do but to become one of them. Not that I had anything against it. They treated me fairly, which was more than what I was used to.~

=

~I was sixteen back then.~

IF ~~ THEN REPLY ~You were young and innocent.~ GOTO 21

END

 

IF ~~ THEN BEGIN 21

SAY ~Not that innocent.~

=

~But enough talking. Come, <CHARNAME>! We should get moving.~

IF ~~ THEN DO ~RealSetGlobalTimer("AzureRomance","GLOBAL",ONE_DAY)~ EXIT

END

 

IF WEIGHT #9

~Global("AzureLoveTalk","GLOBAL",4)~ THEN BEGIN 22

SAY ~<CHARNAME>, I was wondering about something?~

IF ~~ THEN REPLY ~Wondering about what?~ GOTO 23

END

 

IF ~~ THEN BEGIN 23

SAY ~How did you become what you are? I mean, why did you leave home, if you had any, and start travelling the world?~

IF ~~ THEN REPLY ~I don't have the time for this, Azure. You can ask me some other time, perhaps.~ GOTO 24

IF ~~ THEN REPLY ~It didn't happen that long time ago. I used to live in Candlekeep with my stepfather, Gorion. One day, without much explanation, he told me to pack my belongings, becase we had to leave the place. The same day, we were attacked, as I found out later, by my half-brother Sarevok. He killed Gorion, who was apparently trying to protect me.~ GOTO 25

END

 

IF ~~ THEN BEGIN 24

SAY ~All right, <CHARNAME>. I just wanted to know what made you an adventurer. To see if your fortune was similar to mine.~

IF ~~ THEN DO ~RealSetGlobalTimer("AzureRomance","GLOBAL",ONE_DAY)~ EXIT

END

 

IF ~~ THEN BEGIN 25

SAY ~I am sorry you lost your father. I'm sure he was a good man.~

IF ~~ THEN REPLY ~Yes, the best.~ DO ~RealSetGlobalTimer("AzureRomance","GLOBAL",ONE_DAY)~ EXIT

IF ~~ THEN REPLY ~And a fool, too. Let's get going~ DO ~RealSetGlobalTimer("AzureRomance","GLOBAL",ONE_DAY)~ EXIT

END

 

IF WEIGHT #10

~Global("AzureLoveTalk","GLOBAL",5)~ THEN BEGIN 26

SAY ~Yes? Do you want to say something?~

IF ~~ THEN REPLY ~Why would I want to say anything to you? We don't have anything in common. Just leave me alone.~ GOTO 27

IF ~~ THEN REPLY ~I was thinking about the last time we talked. What was your motivation for leaving your fellow-druids?~ GOTO 28

END

 

IF ~~ THEN BEGIN 27

SAY ~For someone meeting as many people as you do, you seem to be an ill-trained conversationalist. All you do is spit insults and affront the others. I will never speak to you again! That I promise.~

IF ~~ THEN DO ~SetGlobal("AzureRomanceActive","GLOBAL",2)~ EXIT

END

 

IF ~~ THEN BEGIN 28

SAY ~I didn't do it willingly. Something happened, and after that there was not much to stay for.~

=

~I don't really want to talk about it now. Maybe tomorrow.~

IF ~~ THEN DO ~RealSetGlobalTimer("AzureRomance","GLOBAL",ONE_DAY)~ EXIT

END

 

IF WEIGHT #11

~Global("AzureLoveTalk","GLOBAL",5)~ THEN BEGIN 29

SAY ~Do you still want to hear what made me leave Tethir?~

IF ~~ THEN REPLY ~Yes, sure.~ GOTO 30

END

 

IF ~~ THEN BEGIN 30

SAY ~Our community wasn't big. There were three small shacks inhabited by seven of us. The number changed about two and a half years ago, when another lost man was brought to us by the elves.~

=

~His name was Trajan. He said he came into Tethir because he didn't have taste for civilization, which was meddling with nature. He said he wanted to become one of us. To protect nature.~

=

~Our leader welcomed him. Said that he could stay with us. That was the biggest mistake he'd ever make. Trajan was a coward. He valued his own skin more than anything.~

=

~One night he and another one of us were sent patrolling the forest. Unfortunately, they were caught by a drow raiding party.~

=

~I presume they wanted to know where our camp was. You see, our friends, the elves, had put a spell on our encampment, so that no-one out of place would be able to find it.~

=

~The drow could only suspect there were druids around, but could not see them. When they caught Trajan and Simian--that was the name of the other druid--their suspicions were confirmed.~

=

~They probably tortured them. Killed Simian. It appears that Trajan traded our location for his life. He showed into the camp with the drow while we were spleeping.~

=

~They slaughtered everyone in their sleep. I survived in the strangest of fashions. Sharo lay next to me and started howling. He somehow made both of us invisible to the eyes of the drow.~

=

~I couldn't move. I couldn't do anything to help my people. Tears were running down my face. I cried aloud, but the drow didn't seem to hear me.~

=

~Now I know that what Sharo did saved my life. The drow were many. I wouldn't stand a chance.~

IF ~~ THEN REPLY ~What happened was terrible. But I am glad you lived.~ GOTO 31

END

 

IF ~~ THEN BEGIN 31

SAY ~When the drow were finally gone, Sharo barked and I was able to move again. Two of my friends were lying next to me in the shack.~

=

~One of them had been cut in half. The other was petrified and broken into pieces.~

=

~I exited the shack. Trajan was there, his head separated from his body. I checked the other two shacks. All were killed. I was the only survivor.~

IF ~~ THEN REPLY ~What did you do?~ GOTO 32

END

 

IF ~~ THEN BEGIN 32

SAY ~I went to see the elves. They had had a skirmish with the drow that night. Managed to drive them away. They told me where they found Simian. I asked if I could go with them to their city, as I had nowhere to go to, but they refused me. They didn't want outsiders. They could not risk the safety of their home. I guess what happened that night frightend them too much. They did not wish to trust human nature. But I don't blame them. They did what they thought was best for their kin.~

=

~I bade them farewell, and hit the road. I wanted to get as fars as possible from Tethir. I had heard there was a druid grove near Trademeet. I was going to ask the druids there to join them, but Faldorn chased me away.~

=

~Despite of that I decided to stay in the forest. I avoided meeting the other druid when possible and I guess my presence didn't bother them that much, because they weren't very consistent in chasing me.~

=

~I lived like that for a year. Then you came.~

IF ~~ THEN REPLY ~I'm happy I met you, Azure. You are more then just a worthy party member. You are a friend.~ Do ~IncrementGlobal("AzureAffection","GLOBAL",1)~ GOTO 33

IF ~~ THEN REPLY ~And rescued you from the boredom.~ GOTO 34

END

 

IF ~~ THEN BEGIN 33

SAY ~Thank you, <CHARNAME>! I count you as a friend, too. Maybe even more than a friend.~

IF ~~ THEN DO ~RealSetGlobalTimer("AzureRomance","GLOBAL",TWO_DAYS)~ EXIT

END

 

IF ~~ THEN BEGIN 34

SAY ~I'll take that as a joke.~

IF ~~ THEN DO ~RealSetGlobalTimer("AzureRomance","GLOBAL",TWO_DAYS)~ EXIT

END

 

I can provide any other information from the mod, if needed. Really hoping this can be fixed, as the Nature's Ally kit installs, but the NPC does not, and I'd like to get her into the game.

 

Thanks,

Eric

Link to comment
IF ~~ THEN REPLY ~I'm happy I met you, Azure. You are more then just a worthy party member. You are a friend.~ Do ~IncrementGlobal("AzureAffection","GLOBAL",1)~ GOTO 33

IF ~~ THEN REPLY ~And rescued you from the boredom.~ GOTO 34

END

A simple typo.

Do → DO should fix this.

Link to comment

IF ~~ THEN REPLY ~I'm happy I met you, Azure. You are more then just a worthy party member. You are a friend.~ Do ~IncrementGlobal("AzureAffection","GLOBAL",1)~ GOTO 33

IF ~~ THEN REPLY ~And rescued you from the boredom.~ GOTO 34

END

A simple typo.

Do → DO should fix this.

 

And it did. Thanks! :) I'll keep an eye out for capitalized commands from now on.

 

Good catch!

- E

Link to comment

Archived

This topic is now archived and is closed to further replies.

×
×
  • Create New...