Jump to content

Cleanup of a DreamScripted talk and followup


cmorgan

Recommended Posts

This talk is a mini-micro-quest, setup to leverage Aran's skills for a reward in a way that makes in-game sense.

 

The original interlude is set using C-ARAND.BCS, the "dreamscript" that is checked at rest, so if the player avoids resting in the Keep after attaining it, they don't get it. It has checks for romantic Encounters' Chanelle in the .bcs, and is set up so it could make sense for visits other than the first time (though it stretches it a bit. I am banking on player behavior being to rest when a party member is wounded or when they get to a destination/leave one).

 

The follow up shpws up only if the player pursues gain; you gotta love having a corporate raider do some dirty work, for those evil players out there. The mini-micro quest manipulates the revolt value from vanilla.

 

Notes to self: the .bcs block needs compatability check/adjustment for D'Arnese (Jcompton, PPG) and states a2208 and a2209 need an evil response. I thought the

 

+ ~!Class("c-aran",PALADIN_ALL)~ + ~[PC] You would do that? Cheat these people?~ + a2210

+ ~Class("c-aran",PALADIN_ALL)~ + ~[PC] You would do that? Cheat these people?~ + a2211

 

was enough, but I think it is too subtle for the players who would go "wtf, give me an option where I can suggest that is EXACTLY what I want, right up front! Subtlety is for people who have not figured out everything can be solved by the suitable application of blunt force trauma!"

 

 

Cleanup and integration of materials from http://forums.gibberlings3.net/index.php?s...st&p=166974

 

/* Stone Walls, Stone Hearts, Stone Heads : Dream Script, De'Arnise Keep (Stronghold) Dialog */
/* Set from  C-ARAND after keep is owned */
IF ~Global("c-arandreamstone","GLOBAL",1) TimeOfDay(DAY)~ a2194
 SAY ~[ARAN] There you are. I thought you might be off tryin' to get some sleep. Hells, there be a shortage o' candles in this place, eh? It be daylight outside, but in here it be gloomier than a one legged man at a dancin' contest. Anyways, I needed to bend your ear a mite.~
 IF ~~ THEN DO ~SetGlobal("c-arandreamstone","GLOBAL",2)~ GOTO a2196
END

IF ~Global("c-arandreamstone","GLOBAL",1) TimeOfDay(NIGHT)~ a2195
 SAY ~[ARAN] There you are. I thought you might be off tryin' to get some sleep. Hells, there be a shortage o' candles in this place, eh? It be night outside so you'd think they would run out some good lanterns or a spell or two an' brighten th' place up, but in here it be gloomier than a one legged man at a dancin' contest. Anyways, I needed to bend your ear a mite.~
 IF ~~ THEN DO ~SetGlobal("c-arandreamstone","GLOBAL",2)~ GOTO a2196  
END  

IF ~~ a2196  
 SAY ~[ARAN] Now that you have a solid defensible position, mayhap you want to gather an army, an' get settled a mite before takin' on th' rest of the world, eh? Not that you have to listen to me, tryin' to tell you what to do. I just keep these lips flappin' way too much.~
 + ~Gender(Player1,FEMALE)~ + ~[PC] Actually, I had some other ideas for those lips of yours. I think I need a respite from all this heavy responsibility.~ + a2202
 + ~Gender(Player1,FEMALE)~ + ~[PC] I agreed to help Nalia because it was in my best interests. We will wait for as long as it takes me to figure out how to best profit from all of this.~ + a2208
 ++ ~[PC] We have to make sure that the Keep is secured, and things are settled. But we need to move on as quickly as we can, too. I am debating whether to take Nalia along, or leave her here to make sure things get reorganized.~ + a2214
 ++ ~[PC] You have no idea what you are talking about, and even if you did, what makes you think I want to hear it from you?~ + a2199  
 ++ ~[PC] Aran. Shut up. Go away. Now.~ + c-aranshutup39
 + ~!HPPercentLT(Player1,30)~ + ~[PC] I think we had better move on quickly. I do not think we can afford to wait.~ + a2200
 + ~HPPercentLT(Player1,30)~ + ~[PC] I think we had better move on quickly. I do not think we can afford to wait.~ + a2201
 + ~Gender(Player1,MALE)~ + ~[PC] I agreed to help Nalia because it was in my best interests. We will wait for as long as it takes me to figure out how to best profit from all of this.~ + a2209  
 + ~Gender(Player1,MALE) Global("RE_ChanelleFlirt","GLOBAL",1) !Global("RE_ChanelleSex","GLOBAL",1)~ + ~[PC] Actually, I was thinking of taking a bath. I think there is a set of washtubs in the master suite.~ + a2198
 + ~Gender(Player1,MALE) !Global("RE_ChanelleFlirt","GLOBAL",1) Global("RE_ChanelleSex","GLOBAL",1)~ + ~[PC] Actually, I was thinking of taking a bath. I think there is a set of washtubs in the master suite.~ + a2198  
 + ~Gender(Player1,MALE) !Global("RE_ChanelleFlirt","GLOBAL",1) !Global("RE_ChanelleSex","GLOBAL",1)~ + ~[PC] Actually, I was thinking of taking a bath. I think there is a set of washtubs in the master suite.~ + a2197
END

IF ~~ a2197
 SAY ~[ARAN] That sounds like a right nice idea. Just so you know, though, one o' th' maids was askin' about you, for some odd chore or somethin'. I'd duck in an' out o' there right quick, so you don't get no more things to handle tonight. But about my questions, do you have some time, or not?~
 IF ~~ THEN GOTO a2205
END  

IF ~~ a2198
 SAY ~[ARAN] Riiiight. A bath. Got it. Just be a mite bit more careful when you get in that water, eh? There were a powerful lot o' screamin' an' laughin' last time, an' I think some o' th' servants are beginnin' to talk. But before you go dippin' your various parts into various things, do you have that mite bit o' time?~
 IF ~~ THEN GOTO a2205
END

IF ~~ a2199 /* 7 replies possible, down to 5 if non-edwin/minsc */
 SAY ~[ARAN] What are you blighted well talkin' about? This be my forte, eh? I thought you'd be wantin' some help gettin' this place in order.~
 ++ ~[PC] I can handle things myself. Just go get some sleep, and I'll give you orders in the morning.~ + a2217
 + ~InParty("edwin") !InParty("minsc") !Global("c-aranrom","GLOBAL",1) !Global("c-aranrom","GLOBAL",2)~ + ~[PC] If I wanted some unwashed idiot spouting orders about how to do things, I would have asked Edwin to run things for me. Even he would give better advice than you.~ + a2217
 + ~!InParty("edwin") InParty("minsc") !Global("c-aranrom","GLOBAL",1) !Global("c-aranrom","GLOBAL",2)~ + ~[PC] If I wanted some unwashed idiot spouting orders about how to do things, I would have asked Minsc to run things for me. Even he would give better advice than you.~ + a2217
 + ~InParty("edwin") InParty("minsc") !Global("c-aranrom","GLOBAL",1) !Global("c-aranrom","GLOBAL",2)~ + ~[PC] If I wanted some unwashed idiot spouting orders about how to do things, I would have asked Minsc or Edwin to run things for me. Both would give better advice than you.~ + a2217
 ++ ~[PC] I appreciate the input, but I have too much on my hands right now. How about we have a good night's sleep, and then you draft up some plans on how you would go about defending this place. We can have a meeting some other time to go over it, ok?~ + a2225
 + ~InParty("edwin") !InParty("minsc") OR(2) Global("c-aranrom","GLOBAL",1) Global("c-aranrom","GLOBAL",2)~ + ~[PC] If I wanted some unwashed idiot spouting orders about how to do things, I would have asked Edwin to run things for me. Even he would give better advice than you.~ + a2218
 + ~!InParty("edwin") InParty("minsc") OR(2) Global("c-aranrom","GLOBAL",1) Global("c-aranrom","GLOBAL",2)~ + ~[PC] If I wanted some unwashed idiot spouting orders about how to do things, I would have asked Minsc to run things for me. Even he would give better advice than you.~ + a2218
 + ~InParty("edwin") InParty("minsc") OR(2) Global("c-aranrom","GLOBAL",1) Global("c-aranrom","GLOBAL",2)~ + ~[PC] If I wanted some unwashed idiot spouting orders about how to do things, I would have asked Minsc or Edwin to run things for me. Both would give better advice than you.~ + a2218
 + ~Gender(Player1,FEMALE)~ + ~[PC] Hey, don't get upset. You get all cute and kissable when you are upset, and I might be too tired to resist your charms.~ + a2202
 + ~Gender(Player1,MALE)~ + ~[PC] Hey, don't get upset. I am just too tired to think about this right now. We are all heroes, here - why don't you go relax by flirting with one of the cute chambermaids? They probably won't be able to resist your charms.~ + a2225
 ++ ~[PC] Well, talk, then. But make it quick.~ + a2205
 ++ ~[PC] I'm sorry. That was a little short. Blame it on the lack of sleep, and this whole "save the world every day" thing we seem to have going.~ + a2205
END

IF ~~ a2200
 SAY ~[ARAN] Well fine. But there be some good tactical thought behind stayin' put for awhile. These lands have had th' crap kicked out o' 'em, and mayhap seein' you around a couple more times will give them a morale boost. Plus, give us a mite bit o' a rest to build up some scrolls an' supplies before movin' on.~
 IF ~~ THEN GOTO a2205
END

IF ~~ a2201
 SAY ~[ARAN] Bloody hells, <CHARNAME>... look at you! There be half an inch o' you what hasn't been ripped, torn, or otherwise mauled. You need a good solid rest, some magical healin', an' mayhap an armorsmith to put th' party gear back in operation. An' there be some good tactical thought behind stayin' put for awhile. These lands have had th' crap kicked out o' 'em, and mayhap seein' you around a couple more times will give them a morale boost. Plus, give us a mite bit o' a rest to build up some scrolls an' supplies before movin' on.~  
 IF ~~ THEN GOTO a2205
END

IF ~~ a2202 /* only attainable by Gender(Player1,FEMALE) */
 SAY ~[ARAN] Now, hold on one second. Do you think I be so easy you can just have your way wi' me any time you want?~
 ++ ~[PC] Well, seeing as you are not really complaining while I am currently wrapping my arms around your neck and brushing your cheek with my eyelashes, yes.~ + a2204
 ++ ~[PC] Judging by how close you are holding me, and how your lips keep grazing my ear, yes.~ + a2204
 ++ ~[PC] Look, all that grabbing at my waist with your hands is very much unwanted. Go find someone else, because I am just not interested.~ + a2205
 ++ ~[PC] On second thought, I don't know if this is the time and place, Aran. I'm not even sure I want this kind of attention from you.~ + a2203  
 + ~Global("c-aranflirtstop","GLOBAL",0)~ + ~[PC] I let you flirt because it keeps you in line, but I am very much in love with someone else. I am not sure we should be sneaking around, even if it is fun.~ + a2203
 + ~Global("c-aranflirtstop","GLOBAL",1)~ + ~[PC] You are so easy to tease. Forget it, Aran. I told you I did not want you to flirt with me. I just wanted to see what you would say.~ + a2203
 ++ ~[PC] Yes.~ + a2203
END

IF ~~ a2203
 SAY ~[ARAN] Now, I'm not rightly goin' to argue wi' you. A little kissin' never hurt nobody, an' there be naught else we can do in just a stolen moment, eh? So do you want to kiss, or not?~
 ++ ~[PC] Judging by how close you are holding me, and how your lips keep grazing my ear, yes.~ + a2204
 ++ ~[PC] Well, seeing as you are not really complaining while I am currently wrapping my arms around your neck and brushing your cheek with my eyelashes, yes.~ + a2204
 ++ ~[PC] Nope. Tactical distraction. Works every time. Now, why don't you say what it is you were trying to say?~ + a2205
 ++ ~[PC] I was joking, Aran. The thought of kissing you actually is quite disgusting. What is it you are annoying me with now?~ + a2205
 ++ ~[PC] You are easily misdirected with the mere offer of affection. That is a tactical weakness that I do so enjoy exploiting. One day, it will kill you.~ + a2205
END

IF ~~ a2204
 SAY ~[ARAN] Well, I did have me some ideas for th' security an' defense o' this place, but I have naught in th' way o' resistance to your womanly wiles, eh?~
 IF ~~ THEN GOTO a2215
END

IF ~~ a2205
 SAY ~[ARAN] I was just offerin' some help, is all. I done found some o' th' architectural drawin's, an' land levies for militia service. I wanted to get a word in wi' you on how to proceed.~
 + ~HPPercentLT(Player1,40) Gender(Player1,MALE)~ + ~[PC] No time like the present, though I wish I could have rested first. I think I will drip blood all over this parchment. Let's see... yes. Go ahead and call up these militia for at least one tenday service, until we can get everything covered with professionals.~ + a2225
 + ~HPPercentLT(Player1,40) Gender(Player1,MALE)~ + ~[PC] I think I will sit down for a minute, seeing as most of my body hurts.  Let's see... yes. Go ahead and pull what you need from manpower and supplies to block off that section. Less to defend means more attention on rebuilding.~ + a2225
 + ~!HPPercentLT(Player1,40)~ + ~[PC] Hmmm. Yes, this makes sense. Go ahead and pull what you need from manpower and supplies to block off that section. Less to defend means more attention on rebuilding.~ + a2225  
 + ~!HPPercentLT(Player1,40)~ + ~[PC] No time like the present, though I wish I could have rested first. Let's see... yes. Go ahead and call up these militia for at least one tenday service, until we can get everything covered with professionals.~ + a2225
 + ~HPPercentLT(Player1,40) !Gender(Player1,MALE)~ + ~[PC] No time like the present, though I wish I could have rested first. I think I will drip blood all over this parchment. Let's see... yes. Go ahead and call up these militia for at least one tenday service, until we can get everything covered with professionals.~ + a2216
 + ~HPPercentLT(Player1,40) !Gender(Player1,MALE)~ + ~[PC] I think I will sit down for a minute, seeing as most of my body hurts.  Let's see... yes. Go ahead and pull what you need from manpower and supplies to block off that section. Less to defend means more attention on rebuilding.~ + a2216
 ++ ~[PC] I will take a look at this information tomorrow, Aran. But if you are all fired up about working, you could go over the tax levies, and draw up a short list of those we could extort for more money.~ + a2206
 ++ ~[PC] Why are you bothering me with all of this? I want your skills focused on finding how much there is left in the treasury, and how much we have to help with the rebuilding.~ + a2206
 ++ ~[PC] Why are you bothering me with all of this? I want your skills focused on finding how much there is left in the treasury, and how much we can raise taxes.~ + a2206  
 + ~Class(Player1,FIGHTER_ALL)~ + ~[PC] I am well versed in fighting. All we need is the strength to hold this place for awhile. You are too interested in the details.~ + a2224  
 + ~Class(Player1,MAGE_ALL)~ + ~[PC] If you think it will help, go bother with all that petty detail. All I am really interested is wandering the library, and checking for spell components.~ + a2224  
 + ~OR(2) Class(Player1,CLERIC_ALL) Class(Player1,PALADIN_ALL)~ + ~[PC] I am sure you mean well, but I don't have time to concentrate on the details. What I really need is time to pray to my god and gather my strength.~ + a2224  
 + ~Class(Player1,THIEF_ALL)~ + ~[PC All we need is the illusion of strength to hold this place for awhile. Being pinned down to a fortress is not my idea of being subtle. Do I really need to be bothered with all these details?~ + a2224  
 + ~Class(Player1,BARD_ALL)~ + ~[PC] I am more interested in the stories, songs, and poetry that our conquest of this place will inspire. I need some time and space to sit down and concentrate. Do I really need to be bothered with all these details?~ + a2224  
END

IF ~~ a2206
 SAY ~[ARAN] Sure thing. Inventory, check what be left o' th' raided treasury an' what can be built back up, check into th' land leases, th' whole audit.~
 ++ ~[PC] And Aran... find every single way you can to get us more coin.~ + a2208
 + ~Gender(Player1,FEMALE) Global("c-aranrom","GLOBAL",2)~ + ~And Aran... don't you dare leave this room without kissing me.~ + a2207
 ++ ~[PC] And Aran... send me some food up from the kitchen. No dogmeat. Just real food.~ + a2219
 ++ ~[PC] You have your orders, so now will you please just let me go to sleep?~ + a2220
END

IF ~~ a2207
 SAY ~[ARAN] Now that be an order I can't rightly refuse. An' why would I want to, anyhow?~
 IF ~~ THEN GOTO a2215
END

IF ~~ a2208
 SAY ~[ARAN] Whoa, now, I misread you right solid, I did. If this be a hostile takeover, you'd better let me know right quick, so I can set up a second set o' books.~
 + ~!Class("c-aran",PALADIN_ALL)~ + ~[PC] You would do that? Cheat these people?~ + a2210  
 + ~Class("c-aran",PALADIN_ALL)~ + ~[PC] You would do that? Cheat these people?~ + a2211
 ++ ~[PC] That's right, make a joke about these poor people and what they have sufered through. Do you really think I want you to do that?~ + a2211
 ++ ~[PC] Look, forget I said anything. I am tired and short-tempered. I just want to be left alone so I can go to sleep.~ + a2220
END

IF ~~ a2209
 SAY ~[ARAN] Whoa, now, I misread you right solid, I did. I thought you were givin' her a hand on account o' she be quite easy on th' eyes, an' everyone knows a hero has more of a chance with beddin' th' fair maid. If this be a hostile takeover, you'd better let me know right quick, so I can set up a second set o' books.~
 + ~!Class("c-aran",PALADIN_ALL)~ + ~[PC] You would do that? Cheat these people?~ + a2210  
 + ~Class("c-aran",PALADIN_ALL)~ + ~[PC] You would do that? Cheat these people?~ + a2211
 ++ ~[PC] That's right, make a joke about these poor people and what they have sufered through. Do you really think I want you to do that?~ + a2211
 ++ ~[PC] Look, forget I said anything. I am tired and short-tempered. I just want to be left alone so I can go to sleep.~ + a2220
END

IF ~~ a2211
 SAY ~[ARAN] Me? Hells, no. Just wanted to see your face when I said it, eh? I guess it weren't that funny.~
 IF ~~ THEN GOTO a2205
END

IF ~~ a2210
 SAY ~[ARAN] Me? Hells, no. I'd be out gettin' these people on th' road to recovery, an' mayhap makin' it less likely that they get cheated out o' their hard work. But I work for you. An' I have done things what would curdle th' blood in th' name o' "good". So it would be you doin' th' cheatin', not me.~
 ++ ~[PC] You are spineless, aren't you.~ + a2212
 ++ ~[PC] With that attitude, you will serve me very well.~ + a2213
 ++ ~[PC] Perhaps one day I will have to test the limits of your loyalty. just how far would you go to serve me?~ + a2221
END

IF ~~ a2212
 SAY ~[ARAN] Not spineless. Just blighted flexible when it comes to absolute morality. You have a mission, an' when there be a priority mission, normal rules don't rightly apply. Neverwinter has some great readin' materials on this, if you ever visit up there. Sometimes th' ends justify th' means.~
 ++ ~[PC] The ends never justify the means. There is an absolute good, and an absolute bad. So no more talk about cheating these people.~ + a2225
 ++ ~[PC] Well said. The ends sometimes do justify the means. But in this case, I think we can afford to help these people.~ + a2225
 ++ ~[PC] You almost had it right, Aran. My goals are attained by any means necessary. Go do whatever you have to do to get me coin.~ + a2222
END

IF ~~ a2213
 SAY ~[ARAN] Well, given th' powers you have, it be a matter o' percentages, eh? I'm not spineless, just blighted flexible when it comes to absolute morality. You have a mission, an' when there be a priority mission, normal rules don't rightly apply. Neverwinter has some great readin' materials on this, if you ever visit up there. Sometimes th' ends justify th' means.~
 ++ ~[PC] The ends never justify the means. There is an absolute good, and an absolute bad. So no more talk about cheating these people.~ + a2225
 ++ ~[PC] Well said. The ends sometimes do justify the means. But in this case, I think we can afford to help these people.~ + a2225
 ++ ~[PC] You almost had it right, Aran. My goals are attained by any means necessary. Go do whatever you have to do to get me coin.~ + a2222
END

IF ~~ a2214
 SAY ~[ARAN] On that point, I know better than to give no opinion. She could be a right passible party member, but she were born wi' a silver spoon in her mouth. Might be trouble. I'm right glad you have to make that decision, not me. Now, do you have a bit o' time, or should I go make myself useful elsewhere?~
 ++ ~[PC] Sure. What is it you want?~ + a2205  
 ++ ~[PC] All people do is wander up and talk to me all day and night. They prod me, poke me, question me... so no. Go away, and let me have a moment of peace and quiet all to myself.~ + a2220
END

IF ~~ a2215
 SAY ~[ARAN] (His kisses are ferocious, demanding yours with rising passion. His hands hold your face, cupping you to his lips like a man driven by desperate thirst.)~
 = ~[ARAN] (Only the gentle knocking on the door reminds you that you have duties and appointments waiting before you can sleep, and you hastily compose yourself before Aran slips out of the door. The Captain of the Guard raises one eyebrow while requesting orders, but he is far too professional to inquire. When you catch a glimpse in the mirror, you see that your cheeks and lips are not quite as calm and composed as the Protector of the Keep might be expected to be.)~
 IF ~~ THEN DO ~RealSetGlobalTimer("RE_DreamTimer","GLOBAL",100) RestParty()~ EXIT
END

/* HPPercentLT(Player1,30) , Female */
IF ~~ a2216
 SAY ~[ARAN]  Now, that be a nice image, there. I can see why I know you will be a great leader. An' why I might just be fallin' for you, too.~
 IF ~~ THEN DO ~RealSetGlobalTimer("RE_DreamTimer","GLOBAL",100) RestParty()~ EXIT
END

IF ~~ a2217 /* males */
 SAY ~[ARAN] By Th' Red Knight's Sword, you are a sorry pain in th' arse. I thought I know where I stood wi' you. I guess I was wrong. Apparently, I stand somewhere south o' th' dungheap out by th' Keep's privy.~
 IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ a2218 /* females  */
 SAY ~[ARAN] By Th' Red Knight's Sword, you are a sorry pain in th' arse. I thought I know where I stood wi' you. I guess I was wrong. Apparently, I stand somewhere south o' th' dungheap out by th' Keep's privy.~
 IF ~~ THEN DO ~SetGlobalTimer("c-aranismad","GLOBAL",ONE_DAY) RealSetGlobalTimer("RE_DreamTimer","GLOBAL",100) RestParty()~ EXIT
END

IF ~~ a2219
 SAY ~[ARAN] Aye, then. No curry... err... Right. I'll be sendin' somethin' up quick as a flash.~
 IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ a2220
 SAY ~[ARAN] Right, then. I'll be leavin' you alone. Have a good night.~
 IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ a2221
 SAY ~[ARAN] I don't rightly know. Slavery, now, that be a deal killer. But short o' that, I guess we just have to see.~
 ++ ~[PC] And what will you do if I ever cross that unknown line?~ + a2223
 ++ ~[PC] That is what I like about you. Always so vague and indecisive, and easy to manipulate.~ + a2220
 ++ ~[PC] That is what I hate about you. You keep letting me push you around.~ + a2220
 ++ ~[PC] Sorry.  should not have asked that question. I am in a foul mood tonight. I had better get some rest.~ + a2220
END

IF ~~ a2222
 SAY ~[ARAN] Right. I'll let you get on wi' your work, an' mayhap I can come up wi' some extra coin somewhere. It might take a few days, mayhap even a tenday. I'll be lettin' you know.~
 IF ~~ THEN DO ~SetGlobal("c-aranextort","LOCALS",1) SetGlobalTimer("c-aranextorttalk","GLOBAL",TEN_DAYS) RestParty()~ EXIT /* ten game days for research */
END

IF ~~ a2223
 SAY ~[ARAN] I don't rightly know. I never did run out on no contract. But I suppose we all have a breakin' point somewhere, eh? Probably just leave. Mayhap fight you, mayhap just kill you. Fair warnin', an' all. But I suspect you will know long before I do. No sense thinkin' about it until it happens, on account o' I'm not blighted well likely to survive th' experience, eh?~
 IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ a2224
 SAY ~[ARAN] Details matter. It be a labor o' love what creates a solid foundation, an' th' details be what shows you are doin' more than just th' work o' a hired sword. They be what shows you really care about th' people in your charge, an' provides 'em a sense o' your leadership. But I can see you be busy, so mayhap I will come bother you some other time.~
 IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ a2225
 SAY ~[ARAN] Now, that be a nice idea, there. I can see why I think you will be a great leader, someday. Well, mayhap already.~
 IF ~~ THEN DO ~RealSetGlobalTimer("RE_DreamTimer","GLOBAL",100) RestParty()~ EXIT
END

/* from  C-ARAN.BCS */
IF ~Global("c-aranextort","LOCALS",2)~ THEN BEGIN a2226
 SAY ~[ARAN] Hey, I found some way o' gainin' a mite bit o' extra coin out o' that Keep, just like you asked. There be some options open. You just tell me which one to chose, an' I can get it done right quick.~
 = ~[ARAN] First off, there be some outstandin' debts on th' part o' th' Merchant's Guild, on account o' we provide some protection. We could force collection, makin' them pay for "protection" on a regular basis, instead o' just when they need it, an' get a tidy sum. But turnin' th Guild against you means some serious penalties... merchants talk to everyone, an' a little bad blood can get to be a problem right quick.~
 = ~[ARAN] Second off, we could sell off some o' th' land what's able to be repossessed. It be a matter o' movin' families off farms they been workin' for generations, but th' law be th' law. Might piss people off a mite bit, though.~
 = ~[ARAN] Third, we could cut a deal wi' th' Trade Guild. Right now, there be two representatives vyin' for th' rights. Th' sorry bastard what's tryin' to get th' concession be a right mean bastard, but he has coin to spend, an' he'll give us some to approve him as th' representative next season.~
 = ~[ARAN] So, you want to collect on th' Guild, sell some land, or take a bribe for th' representative choice? Or none o' these?~
 ++ ~[PC] I don't like any of these options.~ DO ~SetSetGlobal("c-aranextort","GLOBAL",3)~ + a2227
 ++ ~[PC] Do all three.~ DO ~SetSetGlobal("c-aranextort","GLOBAL",3)~ + a2228
 ++ ~[PC] Force the Guild, and take the bribe. Then our "representative" can clean things up for us over time.~ DO ~SetSetGlobal("c-aranextort","GLOBAL",3)~ + a2231
 ++ ~[PC] I don't want to mess with the Guild directly. There could be problems. So just kick those families off my land, and sell it.~  DO ~SetSetGlobal("c-aranextort","GLOBAL",3)~ + a2232
 ++ ~[PC] I don't want to mess with the Guild directly, and I don't need disgruntled tenants causing trouble. Just take the bribe. If the "representative" doesn't serve us well, then we can always make adjustments later.~ DO ~SetSetGlobal("c-aranextort","GLOBAL",3)~ + a2232
 ++ ~[PC] Force the Guild, and throw those people off of my land. But don't bother with taking the bribe. We can probably do better with an honest representative. They tend to actually follow rules, which puts them at a disadvantage.~ DO ~SetSetGlobal("c-aranextort","GLOBAL",3)~ + a2231
END

IF ~~ a2227
 SAY ~[ARAN] Look, th' truth be there is naught in th' way o' new coin to be had just by squeezin' th' books. I don't rightly recommend doin' any o' these things, but if you want th' coin, that's what I was able to find. Personally, I say give th' whole blighted idea up, an' let's go find somethin' to kill an' loot. Except for dragons. No dragons. They are a pain in th' arse.~
 = ~[ARAN] So, what be your orders?~
 ++ ~[PC] Forget the whole thing. It is just not worth it.~ + a2233
 ++ ~[PC] Do all three.~ + a2228
 ++ ~[PC] Force the Guild, and take the bribe. Then our "representative" can clean things up for us over time.~ + a2231
 ++ ~[PC] I don't want to mess with the Guild directly. There could be problems. So just kick those families off my land, and sell it.~ + a2232
 ++ ~[PC] I don't want to mess with the Guild directly, and I don't need disgruntled tenants causing trouble. Just take the bribe. If the "representative" doesn't serve us well, then we can always make adjustments later.~ + a2232
END

IF ~~ a2228
 SAY ~[ARAN] Grumbar's Clay Fist, do you want a blighted revolt on your head? That might get us 3000 gold, but you would be askin' for a revolt. You sure you want to do that?~
 ++ ~[PC] Yes. We need the money. And revolts can be put down. What are they going to do, talk me to death?~ + a2230
 ++ ~[PC] No. Forget the whole idea.~ + a2233
 ++ ~[PC] What are my options again?~ + a2227
 ++ ~[PC] You are so unimaginative. What about falsifying documents and having people driven of their land so I can sell it? What about adding a tax for anyone who speaks Chondathan in public? I expected more out of you, Aran.~ + a2229
END

IF ~~ a2229
 SAY ~[ARAN] Cyric's Black Balls, there be limits. Corruption, kickin' out people on th' street, an' shakin' down th' guild for "protection" didn't go far enough for you? Forget it. I'm bloody well destroyin' this right now, an' to th' nine hells wi' you. Go find your own way o' dealin' wi' this. I got my limits.~
 IF ~~ THEN EXIT
END

IF ~~ a2230
 SAY ~[ARAN] Xvim's Spit, you be... right. Just a job. Consider it done. An' me, I will go lookin' for somethin' to shield th' spittle that folks will send our direction every time they see us.~
 IF ~~ THEN DO ~GiveGoldForce(3000) IncrementGlobal("KPRevolt","GLOBAL",-4)~ EXIT
END

IF ~~ a2231
 SAY ~[ARAN] That I can do. Not exactly th' nicest thing in th' world, but it works. It means there will be some disgruntled people, but you don't make no omlette wi' out breakin' eggs.~
 IF ~~ THEN DO ~GiveGoldForce(2000) IncrementGlobal("KPRevolt","GLOBAL",-2)~ EXIT
END

IF ~~ a2232
 SAY ~[ARAN] That I can do. Not exactly th' nicest thing in th' world, but it works. It means there will be some disgruntled people, but you don't make no omlette wi' out breakin' eggs.~
 IF ~~ THEN DO ~GiveGoldForce(1000) IncrementGlobal("KPRevolt","GLOBAL",-1)~ EXIT
END

IF ~~ a2233
 SAY ~[ARAN] Good idea. Sometimes, th' best thing to do is to let well enough alone, eh? We'll get th' gold some other way.~
 IF ~~ THEN EXIT
END

Link to comment

Archived

This topic is now archived and is closed to further replies.

×
×
  • Create New...