BGII:EE Neera and Aran, SoA and ToB

[cmorgan]

Two sketches for the eventual BG2EE Neera if and/or when she appears, with or without other wild mages/sorcerors:

 

 

 

/* Neera and Aran :A rose by any other name... */

 

~[NEERA] So. Aran. Hmmm. Is that your real name?~

~[ARAN] Aye.~

~[NEERA] Do you like it?~

~[ARAN] I suppose I do. Never did give it much thought.~

~[NEERA] It seems so... ordinary.~

~[NEERA] Wouldn't you rather be named Alphonse Redhand?~

~[ARAN] No.~

~[NEERA] What about Arnold of the Strong Hands?~

~[ARAN] No, that has naught in th' way o' interest for me, either.~

~[NEERA] I would just think that 'Whitehand' is more like a girl's name. You know, 'Snowlips', 'Gentlehand'...~

~[ARAN] So, do you be thinkin' your name should be 'Slenderwaist'?~

~[NEERA] No.~

~[ARAN] How about 'Smallbreast'?~

~[NEERA] You do know I can kill you with a thought, right?~

 

/* Aran and Neera (and/or Taisha and/or Kelsey if present) : Wild magic */

 

~[ARAN] Now, most o' th' magic I see, it be a controlled, purposeful thing. Planned power, applied like a duelist or an assassin, prepared an' set into motion..~

 

any or all inParty:

~[NEERA] Not with me. Sure, I can plan, but then things just happen. Usually not what I was planning.~

~[TASHIA] Powerful, yes. Planned? Not really.~

~[KELSEY] Sorcery is not like setting up accounts. It is more inspiration and less of a measured enactment.~

 

~[ARAN] So, can it be interrupted? I mean, there be a small measure o' time where a mage can lose an entire spell, on account o' a small thing distractin' 'em.~

 

any or all inParty:

~[TASHIA] Sometimes I can get distracted.~

~[NEERA] If I get distracted, some... some very strange things can happen.~

~[KELSEY] It hapens to all of us, I am sure.~

 

~[ARAN] Mayhap somethin' distractin' like...~

 

alone inParty TASHIA

~[TASHIA] OH!~

 

alone inParty NEERA

~[NEERA] OH!~

 

alone inParty KELSEY

~[KELSEY] Making faces and grimacing at me is not going to stop a spell. And if you are not careful, I might be tempted to have your face freeze like that.~

 

inParty KELSEY and {NEERA or TASHIA}

~[KELSEY] I don't think you should have done that, Aran. She looks a little angry.~

 

~[ARAN] Hey, now, I were just playin' about... A little pinch between friends, eh?~

 

inParty TASHIA not inParty NEERA

~[ARAN] Tashia, now, your eyebrows be a mite bit more frownin', an'... that shimmerin' around your hands...~

 

inParty NEERA

~[ARAN] Neera, now, your eyebrows be a mite bit more frownin', an'... that shimmerin' around your hands...~

 

~[ARAN] Gond's Gears! I were just havin' some harmless fun!~

[MissBehave]

~[ARAN] I suppose I so. Never did give it much thought.~ Do?

 

Progress. We do love progress. Happy to see you're still at it. Any more thoughts on fluffing out the romance track in terms of timered talks?

[cmorgan]

Got it - revising sketch.

 

I have a set of "chapter talks" I am working through right now, to extend/delay the friendship side; on the additional lovetalks, I may need to wait a bit (trying hard to get a release together - in the middle of cleanup of files by traifying everything, searching out the "exact same line but has a space or a period or a misspelling that makes it appear as if it is a different line", and working on bg2:ee-ification when I can.

[jastey]

searching out the "exact same line but has a space or a period or a misspelling that makes it appear as if it is a different line"

A very, very, very big thank you for that in the name of all translators out there. I didn't do that for Ajantis and it was a huge mistake. Because translating the same line 5 times in one tra s*cks, no matter it's just copy and paste.

[cmorgan]

Heh - I hear you, Jastey. I have watched lots of translators work through that in BG1NPC, BG:EE, et al - and the incredibly tough job the "string cleanup" folks do to get things like the GTU and GTU-Lite Fixpack components. I am trying to corral everything into one big .tra which means actually only one line of transtations for each line - and since they come as

 

@#### + ~[COMMENT] text~

 

a translation team can do a rexep removal of everything between and including the @ and ~ , then sort, and all the speaker's lines can be laid along side each other for comparison ("voicing"). So

[ARAN] Funny thing is, <CHARNAME>, you got strange ways o' showin' it, but I do believe you.~
[ARAN] Funny thing is, I done looked at you in that Drow getup, an' said to myself, 'that be Drow. Filthy, ugly, blighted enemy... kill it'. Yet, I still couldn't stay away, still couldn't stop bein' close to you, even if I tried.~
[ARAN] Funny, boyo, real funny. I bet you practiced that in front o' a mirror.~
[ARAN] Funny, funny - I handle my weapon quite well, m'<PRO_GIRLBOY>. I just like it better when some fair maiden handles it for me!~
[ARAN] Funny, funny, funny. Don't trouble yourself none... I will find somethin' to break even there, by Tymora's Bright Coin. But I still think we could do better than usin' our feet.~
[ARAN] Funny, there. On account o' you had me run up two sets o' books for you, an' get that contract work all squared away. But you'd forget your arse, if it weren't stuck right on your face permanent-like.~
[ARAN] Funny. Do you be sure he was talkin' to you? On account o' you are not th' sharpest straw in th' bale, you know. After all, you be drinkin' wi' me.~
[ARAN] Funny. Right funny, there. You should look into gettin' a job tellin' jokes at th' Low Lantern. I bet you could make it work, if you stripped down to almost bare nekkid.~

 

Plus, my ability to myst.. musty... m i s s t y p e thigs is bordering on legendary. I love it when i copy and paste and yet still have

 

hey there.~

hey there~

hay there.~

ehy there.~

ehy there~

 

...

[jastey]

Misstype "thigs" ? :)

 

Yes, I am about to start to value one big tra file, too. BG:EE's way of handling journal titles is one thing that makes me wish I had done it from the start.

[Kaeloree]

Looks good

[cmorgan]

In honor of the Official Release of BGII:EE - Neera/Aran banters Cleanup. integration and testing tomorrow.

 

///////////////////////////////////////////////////////////////////////////
// Aran Whitehand BGII:EE SoA and ToB Dialog File - cmorgan - untraified //
///////////////////////////////////////////////////////////////////////////

/* SoA: Neera > Aran : A rose by any other name... */
CHAIN IF ~CombatCounter(0) !Detect([ENEMY]) Global("c-neerasoaaran","GLOBAL",0)
InParty("c-aran") InMyArea("c-aran") !StateCheck("c-aran",CD_STATE_NOTVALID)
InParty(Myself) !StateCheck(Myself,CD_STATE_NOTVALID)~ THEN BNEERA a5102
~[NEERA] So. Aran. Hmmm. Is that your real name?~
DO ~SetGlobal("c-neerasoaaran","GLOBAL",1)~
== C-ARANB ~[ARAN] Aye.~
== BNEERA ~[NEERA] Do you like it?~
== C-ARANB ~[ARAN] I suppose I do. Never did give it much thought.~
== BNEERA ~[NEERA] It seems so... ordinary.~
== BNEERA ~[NEERA] Wouldn't you rather be named Alphonse Redhand?~
== C-ARANB ~[ARAN] No.~
== BNEERA ~[NEERA] What about Arnold of the Strong Hands?~
== C-ARANB ~[ARAN] No, that has naught in th' way o' interest for me, neither.~
== BNEERA ~[NEERA] I would just think that 'Whitehand' is more like a girl's name. You know, 'Snowlips', 'Gentlehand'...~
== C-ARANB ~[ARAN] So, do you be thinkin' your name should be 'Slenderwaist'?~
== BNEERA ~[NEERA] No.~
== C-ARANB ~[ARAN] How about 'Smallbreast'?~
== BNEERA ~[NEERA] You do know I can kill you with a thought, right?~
EXIT

 

/* SoA: Aran > Neera : Wild magic */
CHAIN IF ~CombatCounter(0) !Detect([ENEMY]) Global("c-aransoaneera","GLOBAL",0)
InParty("Neera") InMyArea("Neera") !StateCheck("Neera",CD_STATE_NOTVALID)
InParty(Myself) !StateCheck(Myself,CD_STATE_NOTVALID)~ THEN C-ARANB a5101
~[ARAN] Now, most o' th' magic I see, it be a controlled, purposeful thing. Planned power, applied like a duellist or an assassin, prepared an' set into motion.~
DO ~SetGlobal("c-aransoaneera","GLOBAL",1)~
== BNEERA ~[NEERA] Not with me. Sure, I can plan, but then things just happen. Usually not what I was planning.~
== C-ARANB ~[ARAN] So, can it be interrupted? I mean, there be a small measure o' time where a mage can lose an entire spell, on account o' a small thing distractin' 'em.~
== BNEERA ~[NEERA] If I get distracted, some... some very strange things can happen.~
== C-ARANB ~[ARAN] Mayhap somethin' distractin' like...~
== BNEERA ~[NEERA] OH!~
== C-ARANB ~[ARAN] Hey, now, I were just playin' about... A little pinch between friends, eh?~
== C-ARANB ~[ARAN] Neera, now, your eyebrows be a mite bit more frownin', an'... that shimmerin' around your hands...~
== C-ARANB ~[ARAN] Gond's Gears! I were just havin' some harmless fun!~
EXIT

 

/* ToB: Aran > Neera : Potted Plants */
CHAIN IF ~CombatCounter(0) !Detect([ENEMY]) Global("c-arantobneera","GLOBAL",0)
InParty("Neera") InMyArea("Neera") !StateCheck("Neera",CD_STATE_NOTVALID)
InParty(Myself) !StateCheck(Myself,CD_STATE_NOTVALID)~ THEN C-ARN25B a5095
~[ARAN] Now you look right pensive, you do.~
DO ~SetGlobal("c-arantobneera","GLOBAL",1)~
== BNEERA25 ~[NEERA] Pensive? Oh. No, not really. I just keep having troubles with this one little thing.~
== C-ARN25B ~[ARAN] Mayhap I can help, eh?~
== BNEERA25 ~[NEERA] Well... I suppose you could. I mean, yes, you could.~
== C-ARN25B ~[ARAN] So what needs be done?~
== BNEERA25 ~[NEERA] If you just stand there, really, really still... no, quit moving. Stand there really still, and I will just try this ONE more time...~
== C-ARN25B ~[ARAN] Awww hells. It be that damned 'Polymorph Other' spell you be tryin'. Last time, I done got turned into a potted plant.~
EXIT

 

APPEND BNEERA25
/* ToB: Neera > Aran : Flirting on the Wild Side  */
IF ~CombatCounter(0) !Detect([ENEMY]) Global("c-neeratobaran","GLOBAL",0) InParty("c-aran") InMyArea("c-aran") !StateCheck("c-aran",CD_STATE_NOTVALID) InParty(Myself) !StateCheck(Myself,CD_STATE_NOTVALID)~ THEN BEGIN a5096
 SAY ~[NEERA] So, why haven't you flirted with me lately?~
 IF ~!Global("NeeraRomanceActive","GLOBAL",2) !Global("c-aranrom","GLOBAL",2)~ DO ~SetGlobal("c-neeratobaran","GLOBAL",1)~ EXTERN C-ARN25B a5097
 IF ~Global("NeeraRomanceActive","GLOBAL",2) !Global("c-aranrom","GLOBAL",2)~ DO ~SetGlobal("c-neeratobaran","GLOBAL",1)~ EXTERN C-ARN25B a5098
 IF ~!Global("NeeraRomanceActive","GLOBAL",2) Global("c-aranrom","GLOBAL",2)~ DO ~SetGlobal("c-neeratobaran","GLOBAL",1)~ EXTERN C-ARN25B a5099
 IF ~Global("NeeraRomanceActive","GLOBAL",2) Global("c-aranrom","GLOBAL",2)~ DO ~SetGlobal("c-neeratobaran","GLOBAL",1)~ EXTERN BNEERA25 a5100
END

END // of append

/* no romances with Neera or Aran */
CHAIN C-ARN25B a5097
~[ARAN] I have been. You just seem right oblivious.~
== BNEERA25 ~[NEERA] I don't think giving me extra helpings of curry is flirting.~
== C-ARN25B ~[ARAN] An' why not?~
== BNEERA25 ~[NEERA] For one thing, it leads to indigestion. There is nothing romantic about passing gas.~
== C-ARN25B ~[ARAN] Serves me right for learnin' basic courtin' etiquette from a blighted half-orc.~
EXIT
/* PC romance with Neera */
CHAIN C-ARN25B a5098
~[ARAN] Now why in Sune Firehair's name would I be flirtin' wi' you, when you an' <CHARNAME> are quite th' item?~
== BNEERA25 ~[NEERA] Well... sometimes, it helps to have a little jealousy. Make <PRO_HIMHER> realize what <PRO_HESHE> has.~
== C-ARN25B ~[ARAN] Neera... look at <PRO_HIMHER>. Now look at me. Do you think there be any profit in' stressin' exactly how little I have to offer in comparison, save loyalty?~
== BNEERA25 ~[NEERA] That's the point. I don't want any actual jealousy. I just want <PRO_HIMHER> to remember. I mean, how could anyone see you as a SERIOUS romatic threat?~
== C-ARN25B ~[ARAN] Way to make a lad feel two inches tall. Wi' friends like you, who needs enemies?~
EXIT
/* PC romance with Aran */
CHAIN C-ARN25B a5099
~[ARAN] You know how I feel about <CHARNAME>.~
== BNEERA25 ~[NEERA] Well... sometimes, it helps to have a little jealousy. Make <PRO_HIMHER> realize what <PRO_HESHE> has.~
== C-ARN25B ~[ARAN] Neera... look at <PRO_HIMHER>. Now look at me. Do you think there be any profit in' stressin' exactly how little I have to offer in comparison, save loyalty?~
== BNEERA25 ~[NEERA] Oh, I don't know. Sometimes loyal and faithful ends up being dull and boring. Perhaps you need to spice things up a bit.~
== C-ARN25B ~[ARAN] Mayhap, mayhap not. But seein' as how one wild surge could wipe me off o' Toril, I think I'd be better off not leadin' you on, eh? I can be persuasive. Mayhap you fall head over cute little bottom for me, an' go weepin' an' pinin' away...~
== BNEERA25 ~[NEERA] Sheesh. Like THAT is going to happen.~
EXIT
/* Aran and Neera concurrent romances with PC */
CHAIN BNEERA25 a5100
~[NEERA] Do you think <PRO_HESHE> knows?~
== C-ARN25B ~[ARAN] Blighted hells, girl.. I don't rightly know what <PRO_HESHE> knows. I know <PRO_HESHE> seems right interested in both o' us, an' that be th' truth.~
== BNEERA25 ~[NEERA] You don't suppose <PRO_HESHE>... <PRO_HESHE>... well, YOU know... both of us...~
== C-ARN25B ~[ARAN] Well, all I know is if that particular combination o' personages were to happen, I'd be a right happy man, right up until your wild side chimed in an' blasted half o' Toril off o' th' map.~
EXIT