BGII:EE Dorn and Aran, SoA and ToB

[cmorgan]

In Honor of the Official Release of BGII:EE, Dorn and Aran.

 

 

 

/* SoA: Dorn > Aran : A House Divided */
CHAIN IF ~CombatCounter(0) !Detect([ENEMY]) Global("c-dornsoaaran","GLOBAL",0)
InParty("c-aran") InMyArea("c-aran") !StateCheck("c-aran",CD_STATE_NOTVALID)
InParty(Myself) !StateCheck(Myself,CD_STATE_NOTVALID)~ THEN BDORN a5106
~[DORN] You are weak.~
DO ~SetGlobal("c-dornsoaaran","GLOBAL",1)~
== C-ARANB ~[ARAN] I'm blighted not. I can carry my fair share, an' then some.~
== BDORN ~[DORN] But you are divided.~
== C-ARANB ~[ARAN] What in th' hells do you be talkin' about?~
== BDORN ~[DORN] You fly between the gods like a frightened child, mouthing their names.~
== C-ARANB ~[ARAN] Apparently, you have naught in th' way o' understandin' th' relationship between catharsis an' swearin'.~
== BDORN ~[DORN] I do not. But I understand the power a single purpose can serve.~
== C-ARANB ~[ARAN] Dividin' some time betwixt an' between th' gods gives everyone a little taste, is all. But mayhap you be right. Mayhap it weakens when I be callin' on one in particular.~
== BDORN ~[DORN] When I find a being who is not strong enough to withstand my will... I divide them.~
EXIT

 

/* SoA: Aran > Dorn : Allies */
CHAIN
IF ~CombatCounter(0) !Detect([ENEMY]) Global("c-aransoadorn","GLOBAL",0)
InParty("Dorn") InMyArea("Dorn") !StateCheck("Dorn",CD_STATE_NOTVALID)
InParty(Myself) !StateCheck(Myself,CD_STATE_NOTVALID)~ THEN C-ARANB a5105
~[ARAN] You are one bloodthirsty bastard, eh?~
DO ~SetGlobal("c-aransoadorn","GLOBAL",1)~
== BDORN ~[DORN] Yes.~
== C-ARANB ~[ARAN] There be times when smashin' everythin' in sight means some collateral damage, you know.~
== BDORN ~[DORN] Mercy is weakness. Hesitation is death.~
== C-ARANB ~[ARAN] You have said that before. An' I still think you be wrong. Allies get built by showin' you can work together, an' that means waitin' to see if they be useful or not.~
== BDORN ~[DORN] If they are strong enough to stay alive, then they may be worthy allies.~
== C-ARANB ~[ARAN] An' if you give them naught in th' way o' a chance?~
== BDORN ~[DORN] Then they would not be allies. They would be dead weight.~
== C-ARANB ~[ARAN] That be th' right word choice, I guess.~
EXIT

 

/* ToB: Dorn > Aran : Puppetry and the Common Faerunian */
IF ~CombatCounter(0) !Detect([ENEMY]) Global("c-dorntobaran","GLOBAL",0)
OR(2) Global("OHD_urgothoz_patron","GLOBAL",1) Global("OHD_azothet_patron","GLOBAL",1)
InParty("c-aran") InMyArea("c-aran") !StateCheck("c-aran",CD_STATE_NOTVALID)
InParty(Myself) !StateCheck(Myself,CD_STATE_NOTVALID)
~ THEN BDORN25 a5104
~[DORN] My patron hears you.~
DO ~SetGlobal("c-dorntobaran","GLOBAL",1)~
== C-ARN25B ~[ARAN] What in Bane's...~
== BDORN25 IF ~Global("OHD_urgothoz_patron","GLOBAL",1)~ THEN ~[DORN] Your mewling cries to the gods. Azothet could provide... direction.~
== BDORN25 IF ~Global("OHD_azothet_patron","GLOBAL",1)~ THEN  ~[DORN] Your mewling cries to the gods. Ur-Gothoz could provide... direction.~
== C-ARN25B ~[ARAN] Tell that patron o' yours to bugger off.~
== BDORN25 ~[DORN] You are too weak to stand without a patron. You have some power. You could be useful.~
== C-ARN25B ~[ARAN] It seems to me that if I were to submit to that sort o' arrangement, I'd be more like a puppet than a man, eh?~
== BDORN25 ~[DORN] You are a fool. You do not understand.~
== C-ARN25B ~[ARAN] Blighted straight. I think I be my own man, not a puppet, an that be th' gods' truth.~
== BDORN25 ~[DORN] That is what you do not understand.~
EXIT

 

/* ToB: Aran > Dorn : Patrons, Shmatrons. */
CHAIN
IF ~CombatCounter(0) !Detect([ENEMY])
Global("OHD_azothet_patron","GLOBAL",0)
Global("OHD_urgothoz_patron","GLOBAL",0)
Global("c-arantobdorn2","GLOBAL",0)
InParty("Dorn") InMyArea("Dorn") !StateCheck("Dorn",CD_STATE_NOTVALID)
InParty(Myself) !StateCheck(Myself,CD_STATE_NOTVALID)~ THEN C-ARN25B a5107
~[ARAN] So, no more patron.~
DO ~SetGlobal("c-arantobdorn2","GLOBAL",1)~
== BDORN25 ~[DORN] I have no need of one.~
== C-ARN25B ~[ARAN]An' what does that change, eh?~
== BDORN25 ~[DORN] It means I can revel in the glory, and share none of it.~
== C-ARN25B ~[ARAN] Do you be meanin' glory, or gore?~
== BDORN25 ~[DORN] What is the difference?~
EXIT

 

/* ToB: Aran > Dorn : Once an Alpha Male, Always an Alpha Male. */
CHAIN
IF ~CombatCounter(0) !Detect([ENEMY]) Global("c-arantobdorn","GLOBAL",0)
InParty("Dorn") InMyArea("Dorn") !StateCheck("Dorn",CD_STATE_NOTVALID)
InParty(Myself) !StateCheck(Myself,CD_STATE_NOTVALID)~ THEN C-ARN25B a5103
~[ARAN] So, when will you be makin' your move?~
DO ~SetGlobal("c-arantobdorn","GLOBAL",1)~
== BDORN25 ~[DORN] I am moving now.~
== C-ARN25B ~[ARAN] Cyric's Black Heart, Dorn. You know what I be meanin'.~
== BDORN25 ~[DORN] Enlighten me.~
== C-ARN25B ~[ARAN] You believe in bein' th' strongest, th' most powerful, mayhap th' most bloodiest bastard in all creation.~
== BDORN25 ~[DORN] You are correct.~
== C-ARN25B ~[ARAN] So there will come a time when th' only bigger an' more powerful creature left unconquered will be th' Bhaalspawn.~
== BDORN25 ~[DORN] That is likely.~
== C-ARN25B ~[ARAN] So when will you be makin' your move?~
== BDORN25 ~[DORN] Someday, perhaps. But not today.~
EXIT

[Rhaella]

== BDORN25 ~[DORN] Your mewling cries to the gods. He could provide... direction.~

 

Might want to separate the checks for Ur-gothoz and Azothet here, since the latter is a she, I believe.

[cmorgan]

Heh - missed that one - needs quest check.

[cmorgan]

Darn it - looks like Area vars for some outcomes rather than GLOBALs. Have to investigate fiurther. No problems on separating patrons - just problmes if the "third choice" is taken.

 

The question is

 

Global("OHD_ritual","OH5120",20)

[Kaeloree]

Global("OHD_azothet_patron","GLOBAL",0)

Global("OHD_urgothoz_patron","GLOBAL",0)

 

That'll do it.

[cmorgan]

Sweet!

[cmorgan]

OK, edits up and numbering in place - I'm going to have to recheck the "No Patron" condition in-game, so if anyone has some BGII:EE saves relevant, I'd be grateful. So much new content to explore, so little time...