Gorf, Bodhi never show up

[devSin]

In AR0400.BCS, this will block the latter half of the script:

IF
 GlobalTimerExpired("FindShagbag","GLOBAL")
THEN
 RESPONSE #100
   ActionOverride("korshag",DestroySelf())
   ActionOverride("korcrazy",DestroySelf())
   ActionOverride("korscroo",DestroySelf())
   ActionOverride("korgoo01",DestroySelf())
   ActionOverride("korgoo02",DestroySelf())
END

 

In AR0800.BCS, this will cause Bodhi to never appear (need to check if this is supposed to go in AR0900.BCS):

IF
 Global("GarrickSpeak","GLOBAL",1)
 GlobalTimerExpired("Garrick","GLOBAL")
THEN
 RESPONSE #100
   ActionOverride("Cyrando",JumpToPoint([2963.3624]))
   ActionOverride("Irlana",JumpToPoint([2989.3604]))
   ActionOverride("Cyrando",Face(14))
   ActionOverride("Irlana",Face(14))
END

[SimDing0]

Was this fixed?

[CamDawg]

ar0400 fixed:

 

// welther can spawn infinitely, Shagbag's always-true block disables half the area script
COPY_EXISTING ~ar0400.BCS~ ~override~
 DECOMPILE_BCS_TO_BAF
   REPLACE_TEXTUALLY ~Global("ElgeaGone","GLOBAL",0)~
                     ~Global("ElgeaGone","GLOBAL",0)
                      Global("ElgeaFree","GLOBAL",0)~
   REPLACE_TEXTUALLY ~\bGlobalTimerExpired("FindShagbag","GLOBAL")~
                     ~False()~
 COMPILE_BAF_TO_BCS
EXTEND_BOTTOM ~ar0400.bcs~ ~bg2fixpack/baf/ar0400.baf~

 

where ar0400 is:

 

IF
 GlobalTimerExpired("FindShagbag","GLOBAL")
 Global("CDShagbagHogsScript","LOCALS",0)
THEN
 RESPONSE #100
   SetGlobal("CDShagbagHogsScript","LOCALS",1)
   ActionOverride("korshag",DestroySelf())
   ActionOverride("korcrazy",DestroySelf())
   ActionOverride("korscroo",DestroySelf())
   ActionOverride("korgoo01",DestroySelf())
   ActionOverride("korgoo02",DestroySelf())
END

 

Garrick's block is disabled from ar0800:

 

COPY_EXISTING ~ar0800.BCS~ ~override~
 DECOMPILE_BCS_TO_BAF
   REPLACE_TEXTUALLY ~Global("GarrickSpeak","GLOBAL",1)~
                     ~False()~
 COMPILE_BAF_TO_BCS

 

I took a peek into ar0900.bcs, but didn't see if it was supposed to go there or not. I can't remember any reports of weirdness/bugs from Garrick-Cyrando, so for now I'm leaving it out of ar0900.bcs.