Jump to content

ToB LoveTalks: Aran Thinks Differently Than Anomen


cmorgan

Recommended Posts

Quote

/* Aran Romance vs Anomen Romance - Perspectives and Personalities */
/* ToB New LT 1 after summoning dialogue has run */
IF  ~Global()~ THEN BEGIN h100
  SAY ~[ARAN] Mayhap this be a bad time, but you know me... always talkin' out o' turn. I need to ask you, though... ~
  = ~[ARAN] Any regrets? I mean, so far, you done experienced more trouble than a thousand others what walk Toril.~
  ++ ~[PC] No regrets. In the end, I will get things accomplished my way.~ + h113
  ++ ~[PC] What's the matter, Aran? Are you having regrets about a life of neverending adventure?~ + h114
  ++ ~[PC] Only one regret, Aran... I regret that I have not had enough time to start building a family with you.~ + h101
  ++ ~[PC] My only regret is you. I should never have brought you here.~ + h106
  ++ ~[PC] Well, I always wanted to be an exotic Calishite dancer....~ + h107
END

IF ~~ h114
  SAY ~[ARAN] Well, mayhap I do. Accomplishin' great deeds an' becomin' the most known name in this part o' th' world, right up there wi' Elmister an' Blackstaff, that seemed like a great idea at the time, eh?~
  = ~[ARAN]But we have already done all that, an' received naught but more trouble for th' pain.  Even worse, it be your name alone what gets out there, really.~
  + ~CheckStatGT(Player1,12,WIS)~ + ~[PC] You do not really want that fame for yourself, Aran. You just said it was thankless pain. Does it really hurt you that I am more famous than you?~ + h110
  + ~CheckStatGT(Player1,15,INT)~ + ~[PC] So you feel that you are getting less fame than you deserve? Or do you feel I am getting too much credit?~ + h110
  ++ ~[PC] Fame, fortune, infamy, power, bard's tales and songs... I would give it all up if I could start life over as an exotic Calishite dancer.~ + h107
  + ~Alignment(Player1,MASK_GOOD)~ +  ~[PC] What is wrong with me being famous?~ + h103
  + ~!Alignment(Player1,MASK_GOOD)~ +  ~[PC] What is wrong with me being famous? Or infamous?~ + h104
  ++ ~[PC] Your name is out there as much as mine.~ + h102
  ++ ~[PC] I did not ask for this.~ + h102
  ++ ~[PC] I deserve every bit of fame. You are useful, but secondary.~ + h106
END

IF ~~ h101
  SAY ~[ARAN] Chauntea's Golden Arms. A child, hearth an' home, when you keep gettin' dragged into th' worst parts o' th' god's conflicts? That be an invitation to disaster, eh? But it be a nice dream.~
  IF ~~ THEN GOTO h102
END

IF ~~ h102
  SAY ~[ARAN] You always come out on top, but it be a sure bet that your life will never be what folks call 'ordinary'.~
  ++ ~[PC] Does that bother you?~ + h105
  ++ ~[PC] I like it on top. Actually, I like it on the bottom, and in several other very fun variants...~ + h114
  ++ ~[PC] Did you want things to be very different than they are now?~ + h105
  ++ ~[PC] I was never ordinary. You, on the other hand, are very ordinary. One of you on every streetcorner.~ + h106
  ++ ~[PC] I never wanted to be ordinary.~ + h113
END

IF ~~ h103
  SAY ~[ARAN] Doin' th' right thing by others seems to be more about th' harp edge o' th' sword an' less about talkin'. That do get a bit tirin' to th' spirit, is all.~
  IF ~~ THEN GOTO h110
END

IF ~~ h104
  SAY ~[ARAN] I mean, I know my place, an' you call th' targets. That be th' right o' it.~
  IF ~~ THEN GOTO h110
END

IF ~~ h105
  SAY ~[ARAN] Sometimes. I wish that the world would remake itself, an' leave you a mite bit o' space for yourself. You know, some o' those ordinary dreams we might be makin' together.~
  IF ~Alignment(Player1,MASK_GOOD)~ THEN GOTO h103
  IF ~!Alignment(Player1,MASK_GOOD)~ THEN GOTO h104
END

IF ~~ h106
  SAY ~[ARAN] Well hells, that be right cold o' you.~
  ++ ~[PC] Truth is cold. Power is cold. I am cold. I think it is about time you stop talking and warmed me up.~ + h114
  ++ ~[PC] You never really understand when I am teasing you. Perhaps if I said it with a pouty face, like a Calishite dancer?~ + h107
  ++ ~[PC] Try again. You can do better with your compliments. How do you feel when I am here with you?~ + h116
  ++ ~[PC] Truth is cold. Power is cold. Reality is reality, and we can do little to change it.~ + h117
  ++ ~[PC] I am sorry. You mean well. I am just a little on edge.~ + h110
END

IF ~~ h107
  SAY ~[ARAN] Now that be a mental image I am not likely to get out o' my head any time soon! I can just see it now - I'd be a right smart protector. Only I'd want all th' dancin' to be for me, eh?~
  ++ ~[PC] Seriously. I would give it all up. I never wanted to be the sharp edge of a blade gods wield about like crazed bandits. I would rather be a Calshite dancer. It amounts to the same thing... being continually used by others for their own pleasure and profit.~ + h111
  ++ ~[PC] And every dance would be for you. Maybe you would even dance for me. Or we could dance together...~ + h112
  + ~CheckStatGT(Player1,15,INT)~ + ~[PC] Ahha! I have successfully distracted you from your deep and dreary introspection! I shall follow up with some sharp satire, a witticism or two, followed by an intensive bought of kissing.~ + h108
  + ~CheckStatGT(Player1,12,WIS)~ + ~[PC] I know you had some important feelings to discuss, Aran, but I need more distraction and less thinking right now. So you have a woman with low willpower in need of a boost of self-esteem, standing right here, loosening her clothing a little...~ + h114
  ++ ~[PC] I was teasing you. Sometimes you are really slow.~ + h113
  ++ ~[PC] So tell me why I am worth all this trouble.~ + h116
END

IF ~~ h108
  SAY ~[ARAN] Hey, I be serious here! How is a man supposed to be a right good partner when...~
  ++ ~[PC] I know how you feel, Aran. You don't have to tell me all the time.~ + h109
  ++ ~[PC] You can be a good partner by assuring me that you will always be there for me.~ + h109
  ++ ~[PC] I thought we had settled all this long ago. Why does it bother you that you and I have different strengths?~ + h109
  ++ ~[PC] We have one area where we will always be equal. We both love each other very, very much.~ + h109  
  ++ ~[PC] You are still talking. You are wasting my time.~ + h111
END

IF ~~ h109
  SAY ~[ARAN] I... Melliki's Wild Whiskers. I think I be a bloody idiot. I didn't realize I was bein' such a fool. You be right, <CHARNAME>. An' the only measure o' accomplishment that I need, anyhow, be your comfort.~
  ++ ~[PC] Hey, is this deep conversation just another way of getting me into your bedroll?~ + h114
  ++ ~[PC] Blood, conflict, strife, murder, death, the end of the world as we know it, and I feel fine. Come on, it is exciting, isn't it?~ + h111
  ++ ~[PC] So tell me why I am worth all this trouble.~ + h116
  ++ ~[PC] I agree that you are an idiot.~ + h110
  ++ ~[PC] Well then, you had better get me a really nice set of boots. That would make me more comfortable.~ + h118
END


IF ~~ h113
  SAY ~[ARAN] I don't rightly know whether you be jokin'. Sometimes I feel like th' current sitution be what you love to do.~
  ++ ~[PC] Joking, of course. Things never work out quite the way I plan.~ + h110
  ++ ~[PC] Don't be silly. I am strong enough to bend Fate's pathways to my will. I have you, don't I?~ + h115
  ++ ~[PC] Blood, conflict, strife, murder, death, the end of the world as we know it, and I feel fine. Come on, it is exciting, isn't it?~ + h108
  ++ ~[PC] None of the above. But the Fates will not be denied. I am just glad that they included you along the way.~ + h115
  ++ ~[PC] Hey, is this deep conversation just another way of getting me into your bedroll?~ + h114  
END

IF ~~ h116
  SAY ~[ARAN] Now, you be a sight for sore eyes, an' just bein' by your side makes me feel like I be ten feet tall.~
  ++ ~[PC] So I damage your eyesight and make you puffed up to the size of a giant. Great. I suppose I also make you gassy?~ + h111
  ++ ~[PC] I think you are trying to compliment me... but it is missing the mark.~ + h110
  ++ ~[PC] I could compliment you as well, but it is silly. We have more important things to be focused on.~ + h111
  ++ ~[PC] And you make me feel practically invinceable, supported, and loved.~ + h114
  ++ ~[PC] I know. I have that effect on people.~ + h115
END

IF ~~ h110
  SAY ~[ARAN] Look... mayhap my words be all wrong for what I be tryin' to say. I want naught more fame, naught more fortune, as long as I can be wi' you. But...~
  ++ ~[PC] You don't have to talk to comfort me. You could take action.~ + h114
  ++ ~[PC] But. There is always a "but" with you. I thought you were completely mine.~ + h115
  ++ ~[PC] Your words were wrong, and you are making it worse.~ + h111
  ++ ~[PC] Your words are fine. Your actions are fine. Me, I am not fine.~ + h115
  ++ ~[PC] Dreary, boring, talk talk talk. We need to find something to kill, and quickly.~ + h114
END

IF ~~ THEN BEGIN h111
  SAY ~[ARAN] Aye, now, that be me. Always tryin' to cheer you up a mite bit, an' failin'.~
  ++ ~[PC] You succeeded. At least you distracted me for a little while, and I could pretend things were normal.~ + h112
  ++ ~[PC] You are right. Next time, you could try telling me a story, or acting out part of a play, or something.~ + h112
  ++ ~[PC] Next time you want to distract me, you could try something more physical...~ + h114
  ++ ~[PC] I am not sure the distraction worked, but I appreciate you trying.~ + h115
  ++ ~[PC] There are some situations where nothing you can do can provide comfort.~ + h115
END

IF ~~ h112
  SAY ~[ARAN]  Well, now, if we be play actin', the least I can do is play along, eh? I done heard o' plays where clothin' be optional, too. Mayhap that would be th' right kind o' distraction to cheer you up.~
  IF ~~ THEN EXIT
END

IF ~~ h114
  SAY ~[ARAN] Can we skip right to th' part where you tackle me an' start th' kissin'? When you talk like that to me, it gets me right excited, it does!~
  IF ~~ THEN EXIT
END

IF ~~ h117
  SAY ~[ARAN] I beleive some o' that, but not all.~
  IF ~~ THEN GOTO h115
END

IF ~~ h115
  SAY ~[ARAN] I done signed a contract wi' you in my heart a while back, <CHARNAME>. Good times an' bad times, I be your shield. Small comfort, but comfort to you, I hope.~
  IF ~~ THEN EXIT
END

IF ~~ h118
  SAY ~[ARAN] One decent pair o' boots? That could be done. I will keep a sharp eye out, eh?~
  IF ~~ THEN EXIT
END

 

Link to comment

Rechecked and expanded slightly,

test installed, and up on GitHub here

/* ToB Love Talk #2 : Aran Romance vs Anomen Romance - Perspectives and Personalities : Global("c-arantobrom","GLOBAL",3) --> Global("c-arantobrom","GLOBAL",4) */
IF ~Global("c-arantobrom","GLOBAL",3)~ THEN BEGIN a5266
  SAY  @13929 /* [ARAN] Mayhap this be a bad time, but you know me... always talkin' out o' turn. I need to ask you, though...  */
  = @13930 /* [ARAN] Any regrets? I mean, so far, you done experienced more trouble than a thousand others what walk Toril. */
  ++ @13931 /* [PC] No regrets. In the end, I will get things accomplished my way. */ DO ~SetGlobal("c-arantobrom","GLOBAL",4) RealSetGlobalTimer("c-aranromtimer","GLOBAL",%ARAN_LTT%)~ + a5267
  ++ @13932 /* [PC] What's the matter, Aran? Are you having regrets about a life of neverending adventure? */ DO ~SetGlobal("c-arantobrom","GLOBAL",4) RealSetGlobalTimer("c-aranromtimer","GLOBAL",%ARAN_LTT%)~ + a5268
  ++ @13933 /* [PC] Only one regret, Aran... I regret that I have not had enough time to start building a family with you. */ DO ~SetGlobal("c-arantobrom","GLOBAL",4) RealSetGlobalTimer("c-aranromtimer","GLOBAL",%ARAN_LTT%)~ + a5269
  ++ @13934 /* [PC] My only regret is you. I should never have brought you here. */ DO ~SetGlobal("c-arantobrom","GLOBAL",4) RealSetGlobalTimer("c-aranromtimer","GLOBAL",%ARAN_LTT%)~ + a5274
  ++ @13935 /* [PC] Well, I always wanted to be an exotic Calishite dancer.... */ DO ~SetGlobal("c-arantobrom","GLOBAL",4) RealSetGlobalTimer("c-aranromtimer","GLOBAL",%ARAN_LTT%)~ + a5275 
END
/* GOTO ToB Love Talk #2 : Perspectives and Personalities : replies */

/* ToB Love Talk #2 : Perspectives and Personalities : replies */
IF ~~ a5267
  SAY @13936 /* [ARAN] I don't rightly know whether you be jokin'. Sometimes I feel like th' current sitution be what you love to do. */
  ++ @13937 /* [PC] Joking, of course. Things never work out quite the way I plan. */ + a5278
  ++ @13938 /* [PC] Don't be silly. I am strong enough to bend Fate's pathways to my will. I have you, don't I? */ + a5285
  ++ @13939 /* [PC] Blood, conflict, strife, murder, death, the end of the world as we know it, and I feel fine. Come on, it is exciting, isn't it? */ + a5276
  ++ @13940 /* [PC] None of the above. But the Fates will not be denied. I am just glad that they included you along the way. */ + a5285
  ++ @13941 /* [PC] Hey, is this deep conversation just another way of getting me into your bedroll? */ + a5284  
END

IF ~~ a5268
  SAY @13942 /* [ARAN] Well, mayhap I do. Accomplishin' great deeds an' becomin' the most known name in this part o' th' world, right up there wi' Elmister an' Blackstaff, that seemed like a great idea at the time, eh? */
  = @13943 /* [ARAN]But we have already done all that, an' received naught but more trouble for th' pain.  Even worse, it be your name alone what gets out there, really. */
  + ~CheckStatGT(Player1,12,WIS)~ + @13944 /* [PC] You do not really want that fame for yourself, Aran. You just said it was thankless pain. Does it really hurt you that I am more famous than you? */ + a5278
  + ~CheckStatGT(Player1,15,INT)~ + @13945 /* [PC] So you feel that you are getting less fame than you deserve? Or do you feel I am getting too much credit? */ + a5278
  ++ @13946 /* [PC] Fame, fortune, infamy, power, bard's tales and songs... I would give it all up if I could start life over as an exotic Calishite dancer. */ + a5275 
  + ~Alignment(Player1,MASK_GOOD)~ +  @13947 /* [PC] What is wrong with me being famous? */ + a5271
  + ~!Alignment(Player1,MASK_GOOD)~ +  @13948 /* [PC] What is wrong with me being famous? Or infamous? */ + a5272
  ++ @13949 /* [PC] Your name is out there as much as mine. */ + a5270
  ++ @13950 /* [PC] I did not ask for this. */ + a5270
  ++ @13951 /* [PC] I deserve every bit of fame. You are useful, but secondary. */ + a5274
END

IF ~~ a5269
  SAY @13952 /* [ARAN] Chauntea's Golden Arms. A child, hearth an' home, when you keep gettin' dragged into th' worst parts o' th' god's conflicts? That be an invitation to disaster, eh? But it be a nice dream. */
  IF ~~ THEN GOTO a5270
END

IF ~~ a5270
  SAY @13953 /* [ARAN] You always come out on top, but it be a sure bet that your life will never be what folks call 'ordinary'. */
  ++ @13954 /* [PC] Does that bother you? */ + a5273
  ++ @13955 /* [PC] I like it on top. Actually, I like it on the bottom, and in several other very fun variants... */ + a5284
  ++ @13956 /* [PC] Did you want things to be very different than they are now? */ + a5273
  ++ @13957 /* [PC] I was never ordinary. You, on the other hand, are very ordinary. One of you on every streetcorner. */ + a5274
  ++ @13958 /* [PC] I never wanted to be ordinary. */ + a5267
END

IF ~~ a5271
  SAY @13959 /* [ARAN] Doin' th' right thing by others seems to be more about th' harp edge o' th' sword an' less about talkin'. That do get a bit tirin' to th' spirit, is all. */
  IF ~~ THEN GOTO a5278
END

IF ~~ a5272
  SAY @13960 /* [ARAN] I mean, I know my place, an' you call th' targets. That be th' right o' it. */
  IF ~~ THEN GOTO a5278
END

IF ~~ a5273
  SAY @13961 /* [ARAN] Sometimes. I wish that the world would remake itself, an' leave you a mite bit o' space for yourself. You know, some o' those ordinary dreams we might be makin' together. */
  IF ~Alignment(Player1,MASK_GOOD)~ THEN GOTO a5271
  IF ~!Alignment(Player1,MASK_GOOD)~ THEN GOTO a5272
END

IF ~~ a5274
  SAY @13962 /* [ARAN] Well hells, that be right cold o' you. */
  ++ @13963 /* [PC] Truth is cold. Power is cold. I am cold. I think it is about time you stop talking and warmed me up. */ + a5284
  ++ @13964 /* [PC] You never really understand when I am teasing you. Perhaps if I said it with a pouty face, like a Calishite dancer? */ + a5275
  ++ @13965 /* [PC] Try again. You can do better with your compliments. How do you feel when I am here with you? */ + a5281
  ++ @13966 /* [PC] Truth is cold. Power is cold. Reality is reality, and we can do little to change it. */ + a5282
  ++ @13967 /* [PC] I am sorry. You mean well. I am just a little on edge. */ + a5278
END

IF ~~ a5275 
  SAY @13968 /* [ARAN] Now that be a mental image I am not likely to get out o' my head any time soon! I can just see it now - I'd be a right smart protector. Only I'd want all th' dancin' to be for me, eh? */
  ++ @13969 /* [PC] Seriously. I would give it all up. I never wanted to be the sharp edge of a blade gods wield about like crazed bandits. I would rather be a Calshite dancer. It amounts to the same thing... being continually used by others for their own pleasure and profit. */ + a5279
  ++ @13970 /* [PC] And every dance would be for you. Maybe you would even dance for me. Or we could dance together... */ + a5280
  + ~CheckStatGT(Player1,15,INT)~ + @13971 /* [PC] Ahha! I have successfully distracted you from your deep and dreary introspection! I shall follow up with some sharp satire, a witticism or two, followed by an intensive bought of kissing. */ + a5276
  + ~CheckStatGT(Player1,12,WIS)~ + @13972 /* [PC] I know you had some important feelings to discuss, Aran, but I need more distraction and less thinking right now. So you have a woman with low willpower in need of a boost of self-esteem, standing right here, loosening her clothing a little... */ + a5284
  ++ @13973 /* [PC] I was teasing you. Sometimes you are really slow. */ + a5267
  ++ @13974 /* [PC] So tell me why I am worth all this trouble. */ + a5281
END

IF ~~ a5276
  SAY @13975 /* [ARAN] Hey, I be serious here! How is a man supposed to be a right good partner when... */
  ++ @13976 /* [PC] I know how you feel, Aran. You don't have to tell me all the time. */ + a5277
  ++ @13977 /* [PC] You can be a good partner by assuring me that you will always be there for me. */ + a5277
  ++ @13978 /* [PC] I thought we had settled all this long ago. Why does it bother you that you and I have different strengths? */ + a5277
  ++ @13979 /* [PC] We have one area where we will always be equal. We both love each other very, very much. */ + a5277  
  ++ @13980 /* [PC] You are still talking. You are wasting my time. */ + a5279
END

IF ~~ a5277
  SAY @13981 /* [ARAN] I... Melliki's Wild Whiskers. I think I be a bloody idiot. I didn't realize I was bein' such a fool. You be right, <CHARNAME>. An' the only measure o' accomplishment that I need, anyhow, be your comfort. */
  ++ @13941 /* [PC] Hey, is this deep conversation just another way of getting me into your bedroll? */ + a5284
  ++ @13939 /* [PC] Blood, conflict, strife, murder, death, the end of the world as we know it, and I feel fine. Come on, it is exciting, isn't it? */ + a5279
  ++ @13974 /* [PC] So tell me why I am worth all this trouble. */ + a5281
  ++ @13982 /* [PC] I agree that you are an idiot. */ + a5278
  ++ @13983 /* [PC] Well then, you had better get me a really nice set of boots. That would make me more comfortable. */ + a5283
END

IF ~~ a5278
  SAY @13984 /* [ARAN] Look... mayhap my words be all wrong for what I be tryin' to say. I want naught more fame, naught more fortune, as long as I can be wi' you. But... */
  ++ @13985 /* [PC] You don't have to talk to comfort me. You could take action. */ + a5284
  ++ @13986 /* [PC] But. There is always a "but" with you. I thought you were completely mine. */ + a5285
  ++ @13987 /* [PC] Your words were wrong, and you are making it worse. */ + a5279
  ++ @13988 /* [PC] Your words are fine. Your actions are fine. Me, I am not fine. */ + a5285
  ++ @13989 /* [PC] Dreary, boring, talk talk talk. We need to find something to kill, and quickly. */ + a5284
END

IF ~~ a5279
  SAY @13990 /* [ARAN] Aye, now, that be me. Always tryin' to cheer you up a mite bit, an' failin'. */
  ++ @13991 /* [PC] You succeeded. At least you distracted me for a little while, and I could pretend things were normal. */ + a5280
  ++ @13992 /* [PC] You are right. Next time, you could try telling me a story, or acting out part of a play, or something. */ + a5280
  ++ @13993 /* [PC] Next time you want to distract me, you could try something more physical... */ + a5284
  ++ @13994 /* [PC] I am not sure the distraction worked, but I appreciate you trying. */ + a5285
  ++ @13995 /* [PC] There are some situations where nothing you can do can provide comfort. */ + a5285
END

IF ~~ a5280
  SAY @13996 /* [ARAN]  Well, now, if we be play actin', the least I can do is play along, eh? I done heard o' plays where clothin' be optional, too. Mayhap that would be th' right kind o' distraction to cheer you up. */
  IF ~~ THEN EXIT
END

IF ~~ a5281
  SAY @13997 /* [ARAN] Now, you be a sight for sore eyes, an' just bein' by your side makes me feel like I be ten feet tall. */
  ++ @13998 /* [PC] So I damage your eyesight and make you puffed up to the size of a giant. Great. I suppose I also make you gassy? */ + a5279
  ++ @13999 /* [PC] I think you are trying to compliment me... but it is missing the mark. */ + a5278
  ++ @14000 /* [PC] I could compliment you as well, but it is silly. We have more important things to be focused on. */ + a5279
  ++ @14001 /* [PC] And you make me feel practically invinceable, supported, and loved. */ + a5284
  ++ @14002 /* [PC] I know. I have that effect on people. */ + a5285
END

IF ~~ a5282
  SAY @14003 /* [ARAN] I believe some o' that, but not all. */
  IF ~~ THEN GOTO a5285
END

IF ~~ a5283
  SAY @14004 /* [ARAN] One decent pair o' boots? That could be done. I will keep a sharp eye out, eh? */
  IF ~~ THEN EXIT
END

IF ~~ a5284
  SAY @14005 /* [ARAN] Can we skip right to th' part where you tackle me an' start th' kissin'? When you talk like that to me, it gets me right excited, it does! */
  IF ~~ THEN EXIT
END

IF ~~ a5285
  SAY @14006 /* [ARAN] I done signed a contract wi' you in my heart a while back, <CHARNAME>. Good times an' bad times, I be your shield. Small comfort, but comfort to you, I hope. */
  IF ~~ THEN EXIT
END

 

Link to comment

Join the conversation

You are posting as a guest. If you have an account, sign in now to post with your account.
Note: Your post will require moderator approval before it will be visible.

Guest
Reply to this topic...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

×
×
  • Create New...