Odren dialogue fixes

[CamDawg]

From BD:

 

It resolves two bugs with his dialog. First, if the player chose to not read the Ritual Scroll given by Brother Pol, and sent Demogorgon back to the Abyss, if the player was still in the Shadows Of Amn component of Baldur's Gate II and any of Anomen, Imoen, Keldorn or Mazzy were in the group, on returning to Brother Odren, after the first line of dialog, "No valid replies or links" would be received and the player would be unable to progress. The cause of this was that the possible dialog threads that were not restricted to the Throne Of Bhaal areas were also disallowed from the four NPC's as well through incorrect triggers, so they would start to reply but then the chapter check would block them being able to. This is the state 44 fix - Cam

 

The second bug fixed was an exploit whereby after talking to Brother Odren and receiving the quest experience and reputation increase, he could be talked to as he was leaving, and would give the experience and reputation again, as many times as the player wanted.This is the state 41 fix - Cam

 

State 39 had a broken transition as well, but that was already fixed by the big dialogue patch.

 

// brother Odren dialogue fixes
REPLACE GORODR1
IF ~~ THEN BEGIN 41 // from: 40.0
 SAY #62564
 IF ~~ THEN DO ~EraseJournalEntry(62402)
EraseJournalEntry(62423)
EraseJournalEntry(62461)
EraseJournalEntry(62481)
EraseJournalEntry(62987)
EraseJournalEntry(63049)
EraseJournalEntry(63048)
EraseJournalEntry(63091)
AddXP2DA("PLOT01D")
Wait(1)
SetGlobal("CloseDemogorgonTemple","GLOBAL",2)
ActionOverride("shugar01",DialogueInterrupt(FALSE))
ActionOverride("shupol01",DialogueInterrupt(FALSE))
ActionOverride("shugfg01",DialogueInterrupt(FALSE))
ActionOverride("shugmg01",DialogueInterrupt(FALSE))
ActionOverride("shugpr01",DialogueInterrupt(FALSE))
DialogueInterrupt(FALSE)
ActionOverride("shugar01",EscapeArea())
ActionOverride("shupol01",EscapeArea())
ActionOverride("shugfg01",EscapeArea())
ActionOverride("shugmg01",EscapeArea())
ActionOverride("shugpr01",EscapeArea())
EscapeArea()~ SOLVED_JOURNAL #62581 EXIT
END


IF ~~ THEN BEGIN 44 // from: 33.2
 SAY #62583
 IF ~~ THEN REPLY #62584  GOTO 35
 IF ~~ THEN REPLY #62586  GOTO 35
 IF ~~ THEN REPLY #62589  GOTO 45
 IF ~IsValidForPartyDialog("Keldorn")
GlobalGT("Chapter","GLOBAL",7)
~ THEN EXTERN ~KELDO25J~ 9
 IF ~IsValidForPartyDialog("Mazzy")
GlobalGT("Chapter","GLOBAL",7)
~ THEN EXTERN ~MAZZY25J~ 6
 IF ~IsValidForPartyDialog("Imoen2")
GlobalGT("Chapter","GLOBAL",7)
~ THEN EXTERN ~IMOEN25J~ 29
 IF ~IsValidForPartyDialog("Anomen")
GlobalGT("Chapter","GLOBAL",7)
~ THEN EXTERN ~ANOME25J~ 29
END
END

[CamDawg]

Included in alpha 3.