Shouldn't firetooth have +1 attack in its bio

[TinyMage]

It gives +1 attack in both melee mode and ranged mode.

[Rastor]

I've never used this dagger, so I never saw that.

 

Yes, it should have the description in it's bio.

 

STRING_SET 39528 ~Dagger of Throwing +3 Firetooth
This throwing knife is imbued with magical fire, and was supposedly carved from an extracted red dragon tooth.  Tavern tales suggest that the beast is still alive, her anger fueling the enchantment within the weapon.  Though fanciful, the story is consistent, and it is said the dagger returns to the thrower "as though on wings."

STATISTICS:

Combat Abilities: dagger returns to the thrower
Special:  +1 Attack per Round
THAC0:  +3 bonus, 1D2 fire damage
Damage:  2D4 + 3
Damage type:  missile (piercing)
Weight: 1
Speed Factor: 1
Proficiency Type: Dagger
Type:  1-handed
Requires: 3 Strength
Not Usable By:
Cleric
Beast Master~

 

Fixed.

[Ghreyfain]

Don't all throwing daggers increase attacks by 1? Darts by 2?

[devSin]

Actually, they're all supposed to set (crossbows to 1, slings to 1, daggers to 2, darts to 3, bows to 2). I've always worked under the assumption that the increment done for these daggers was a bug (since they operate contrary to every other similar item in the game). I think the Boomerang dagger (or whatever the other never-run-out-o dagger is) is similarly affected.

[Drew]

Actually, they're all supposed to set (crossbows to 1, slings to 1, daggers to 2, darts to 3, bows to 2). I've always worked under the assumption that the increment done for these daggers was a bug (since they operate contrary to every other similar item in the game). I think the Boomerang dagger (or whatever the other never-run-out-o dagger is) is similarly affected.

<{POST_SNAPBACK}>

Ranged weapons don't set attacks ingame. A specialized warrior with the tuigan bow gets 4.5 apr if he's level 13 or above. He gets 3.5 with a standard shortbow or any other standard bow he's specialized in. He would only be limited in ApR with a ranged weapon if he isn't proficient with it.

 

I would say that the bug with the boomerang dagger and firetooth is that each weapon still grants the extra attack in melee. It should when thrown, but in melee it shouldn't. I think that could be fixed by adding the extra attack as an effect to the ranged aspect of the weapon instead of adding it to the weapon as a whole.

[devSin]

I don't know what to tell you. The Tuigan bow sets the wielder's attacks to 3/round. I've never cared at all to see how these actually work in-game, or how the attack bonuses (number of attacks, damage, and speed factor) all interoperate, but the fact remains that the majority of ranged items set the wielder's attack rate to a predetermined amount.

[Drew]

OK. Ranged weapons are also affected by any extra attacks gained from specialization and warrior levels. The "extra attack" for firetooth and the boomerang dagger is likely due to bioware being too lazy to diferentiate between the melee and thrown versions of the weapon.

[CamDawg]

Did some looking into this. All throwing daggers set APR to 2, except the two mixed-use daggers (Boomerang and Fire Tooth) which grant a +1 APR bonus instead. Melee-only daggers have no APR changes. I'm content taking no action for the core bugfixes since it seems the two mixed-use daggers have a hacky Bioware consistency. However, I do think a good optional-but-cool fix goes here: remove melee abilities from both (as they essentially get +1 APR melee bonus for no reason), change APR to match other throwing daggers (set to 2), and tone down Fire Tooth to a more reasonable 1d4 base damage instead of its current 2d4 (and adjust its description accordingly).

 

// removes melee abilities from Fire Tooth, Boomerang dagger; change APR to be consistent 
// with other throwing daggers; alters base Fire Tooth damage to 1d4
COPY_EXISTING ~dagg11.itm~ ~override~
             ~dagg12.itm~ ~override~
 READ_LONG   0x64 "abil_off"
 READ_SHORT  0x68 "abil_num"
 READ_LONG   0x6a "fx_off"
 READ_SHORT  0x70 "fx_num"
 SET "fx_delta" = 0
 FOR (index = 0; index < fx_num; index = index + 1) BEGIN
   READ_SHORT ("%fx_off%" +        ("%index%" * 0x30)) "opcode"
   PATCH_IF ("%opcode%" = 1) BEGIN  // attacks per round
     WRITE_LONG ("%fx_off%" + 0x04 + ("%index%" * 0x30)) 2 // number of attacks
     WRITE_LONG ("%fx_off%" + 0x08 + ("%index%" * 0x30)) 1 // set to value
   END
 END
 FOR (index = 0; index < abil_num; index = index + 1) BEGIN // looks for melee ability header
   READ_BYTE   ("%abil_off%" +        ("%index%" * 0x38)) "type"
   PATCH_IF ("%type%" = 1) BEGIN // melee ability check
    WRITE_BYTE   ("%abil_off%" +        ("%index%" * 0x38)) 0
     READ_SHORT  (0x1e + "%abil_off%" + ("%index%" * 0x38)) "abil_fx_num"
     READ_SHORT  (0x20 + "%abil_off%" + ("%index%" * 0x38)) "abil_fx_idx"
     DELETE_BYTES ("%fx_off%" + (0x30 * ("%abil_fx_idx%" - "%fx_delta%"))) (0x30 * "%abil_fx_num%") // deletes all associated effects
     DELETE_BYTES ("%abil_off%" + ("%index%" * 0x38)) 0x38                                          // deletes ability itself
     SET "fx_delta" = ("%fx_delta%" + "%abil_fx_num%")
     SET "abil_num" = ("%abil_num%" - 1)
     SET "index" = ("%index%" - 1)
     SET "fx_off" = ("%fx_off%" - 0x38)
   END ELSE BEGIN // if non-melee ability, need to adjust effect indices
     READ_SHORT  (0x20 + "%abil_off%" + ("%index%" * 0x38)) "abil_fx_idx"
     WRITE_SHORT (0x20 + "%abil_off%" + ("%index%" * 0x38)) ("%abil_fx_idx%" - "%fx_delta%")
     PATCH_IF (("%type%" = 2) AND ("%SOURCE_RES%" STRING_COMPARE_CASE "dagg12" = 0)) BEGIN // ranged damage adjustment for Fire Tooth
       WRITE_SHORT (0x18 + "%abil_off%" + ("%index%" * 0x38)) 1 // only 1d4, not 2d4
       SAY 0x54 @132 // adjusts description
     END
   END
 END
 WRITE_SHORT  0x68 "%abil_num%"
 WRITE_LONG   0x6a "%fx_off%"
 BUT_ONLY_IF_IT_CHANGES

 

While researching, I also found an error with the Shadow Thief dagger (Bodhi asks you to plant this as one of her quests against Aran). Though a melee-only dagger, it did have the standard ranged APR set effect which is now disabled. This is for core fixes.

 

// shadow thief dagger has ranged APR effect though a melee weapon
COPY_EXISTING ~dagg18.itm~ ~override~
 READ_LONG  0x6a "fx_off"
 READ_SHORT 0x70 "fx_num"
 FOR (index = 0; index < fx_num; index = index + 1) BEGIN
   READ_SHORT ("%fx_off%" +        (0x30 * "%index%")) "opcode"
   PATCH_IF ("%opcode%" = 1) BEGIN // set attacks per round
     WRITE_BYTE ("%fx_off%" + 0x12 + (0x30 * "%index%")) 0 // probability = 0
   END
 END
 BUT_ONLY_IF_IT_CHANGES

 

Added to the wiki.

[Idobek]

Can we have a keep-melee-and-ranged-abilities-but-remove-any-APR-settings and/or-bonuses-to-make-them-consistent-with-melee-daggers option please?

[Drew]

There is actually a canonical explanation for why the throwing daggers do 2d4 damage. Per the 2e DM's guide......... "A succesful hit when it is thrown will inflict twice normal dagger damage, plus the bonus provided by the blade......." That was probably what bioware was thinking about when they set the weapon's damage at 2d4.