Jump to content

Miscellaneous script fixes


CamDawg

Recommended Posts

Trying to clean up some of the script error messages reported by NI.

 

Tran0303a and Tran0329 don't exist:

// fixing transition calls
COPY_EXISTING ~ar0300.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~\(TriggerActivation("Tran0329\)\(",[A-Z]+)\)~ ~\1a\2 \1b\2~
REPLACE_TEXTUALLY ~Tran0303a~ ~Tran0303~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

The spirit Mairyn never leaves the (restored) temple ruins due to a typo in the DV:

 

// spirit doesn't escape area due to bad DV call
COPY_EXISTING ~ar1400.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~ActionOverride("rspirit1"~ ~ActionOverride("rspirit01"~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

Additional shadow fiends should spawn at the temple ruins but don't due to a DV typo:

 

// more shadow fiends don't spawn due to DV typo
COPY_EXISTING ~ar1404.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~"shdafi01"~ ~"shadfi01"~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

Link to comment

And a few more. AFAICT, the other 550 or so warnings reported by Near Infinity are either BG leftovers or NI being unable to recognize the flag in area files that forces creatures to use their file name as a DV.

 

An anal-retentive fix; NI reports an invalid script change. Doesn't matter as the following action is to kill the creatures, but... :suspect:

 

// tries to remove override scripts for knights before killing them
COPY_EXISTING ~ar3020.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~ChangeAIScript("one",OVERRIDE))~ ~ChangeAIScript("",OVERRIDE))~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

OilDoor doesn't exist.

// removing call to nonexistent trigger
COPY_EXISTING ~ar3021.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~TriggerActivation("OilDoor",FALSE)~ ~~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

Made an additional change in the script that weakens Bodhi--she has a call to destroy vampreg3.itm, which doesn't exist. She is equipped with vampreg2.itm, though, so I altered the script to destroy that instead.

 

Cadril is checking for Cyrando and Irlana, but with the wrong DVs:

// cadril's script using wrong DVs for Cyrando and Irlana
COPY_EXISTING ~cadril.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~"tcyrando"~ ~"cyrando"~
REPLACE_TEXTUALLY ~"tirlana"~ ~"irlana"~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

The "DRUID OFFENSIVE/DEFENSIVE (cleric):" AI script has a check for being outside that is broken:

 

// check to see if outside is broken
COPY ~scripts/cleric3.bs~ ~scripts/cleric3.bs~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~AreaCheck("UTDOOR)")~ ~AreaType(OUTDOOR)~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

The "SPELLCASTER DEFEND (fighter, ranger, paladin)" AI script has a broken Dead trigger. Not only is it malformed, but Dead() checks can't take object references; changing to a StateCheck.

 

// yet another broken Dead() trigger
COPY ~scripts/fighter4.bs~ ~scripts/fighter4.bs~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~!Dead("astAttackerOf(LastSeenBy(Myself)))")~ ~!StateCheck(LastAttackerOf(LastSeenBy(Myself)),STATE_REALLY_DEAD)~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

Mazzy checks for both gorf and gorf03 DVs, but gorf03.cre uses gorf as a DV anyway. Need a bit more cleaning here as this results in silly triggers like OR(2) Dead("gorf") Dead("gorf").

 

// Mazzy checking for gorf03, but gorf03 = gorf
COPY_EXISTING ~mazzy.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~"gorf03"~ ~"gorf"~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

The mugger victims in the Slums are checking incorect DVs.

 

// slum victims not checking proper mugger DVs
COPY_EXISTING ~slumvic.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~"SlumsMugger3"~ ~"mugger3"~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

At certain XP levels, a pair of rakshasas and three ogres are supposed to be created in Suldenessalar. Only the rakshasas were being spawned due to bad resrefs.

 

// Rakshasas in Suld not properly spawning ogres
COPY_EXISTING ~spwnrak.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~"dogre01"~ ~"ogre01"~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

Something for the UB gang: pipe04.bcs is apparently supposed to play a sound (prhaps a pipe organ?) when acquiring Lilarcor. ppshad0[1-6].bcs also all have missing sound references, but I have no idea what they might be.

 

A few more possible errors I'm investigating: cut218b.bcs appears to be fine but NI is reporting a warning on using SPIMPPT; cut31q.bcs is trying to create bdcoun04.cre, a possible second bodyguard for the council member, but the cre file doesn't exist.

Link to comment

I thought we already fixed all this stuff?

 

Tran0303a and Tran0329 don't exist:
Are you sure 0329 doesn't exist? Also, check to make sure it's not Tra0303a (no "n"), which BioWare sometimes used.

 

Made an additional change in the script that weakens Bodhi--she has a call to destroy vampreg3.itm, which doesn't exist. She is equipped with vampreg2.itm, though, so I altered the script to destroy that instead.
Yeah. I'm pretty sure I gave her reg3 so she's kicks more butt.

 

The mugger victims in the Slums are checking incorect DVs.
Unused.

 

At certain XP levels, a pair of rakshasas and three ogres are supposed to be created in Suldenessalar. Only the rakshasas were being spawned due to bad resrefs.
Believe it or not... unused.

 

ppshad0[1-6].bcs also all have missing sound references, but I have no idea what they might be.
Unused. Control was moved back into the cutscene to handle them.

 

A few more possible errors I'm investigating: cut218b.bcs appears to be fine but NI is reporting a warning on using SPIMPPT;
NI doesn't check BAM refs. SPIMPPT is the "ground opening up" part of the Implosion animation; works fine.
Link to comment
Tran0303a and Tran0329 don't exist:
Are you sure 0329 doesn't exist? Also, check to make sure it's not Tra0303a (no "n"), which BioWare sometimes used.

Script calls for Tran0329 and Tran0303a; actual transitions are Tran0329a, Tran0329b and Tran0303.

 

A few more possible errors I'm investigating: cut218b.bcs appears to be fine but NI is reporting a warning on using SPIMPPT;
NI doesn't check BAM refs. SPIMPPT is the "ground opening up" part of the Implosion animation; works fine.

That's what I thought--if you didnt' reply with the answer I was actually going to have to open the game and look. :suspect:

 

I'll clear out the unused stuff.

Link to comment

Updated Mazzy fix, thanks to bigg's \n emulation:

 

// Mazzy checking for gorf03, but gorf03 = gorf
COPY_EXISTING ~mazzy.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~OR(2)[ %lnl%%mnl%%wnl%]+Dead("gorf")[ %lnl%%mnl%%wnl%]+Dead("gorf03")~ ~Dead("gorf")~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

Added to beta 2, moving to archives.

Link to comment

The bdcoun04 seems to be more UB. Code for Fixpack:

 

// removes call to nonexistent cre file
COPY_EXISTING ~cut31q.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF 
REPLACE_TEXTUALLY ~CreateCreature("bdcoun04",\[592\.825\],10)~ ~~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

Code to restore to be reposted for UB folks (will work with or without Fixpack installed):

 

COPY_EXISTING ~bdcoun03.cre~ ~override/bdcoun04.cre~
 WRITE_EVALUATED_ASCII 0x280 ~%DEST_RES%~ #8
 WRITE_EVALUATED_ASCII 0x2cc ~%DEST_RES%~ #8
 BUT_ONLY_IF_IT_CHANGES

COPY_EXISTING ~cut31q.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~CreateCreature("bdcoun03",\[510\.671\],10)~
  ~CreateCreature("bdcoun03",[510.671],10) CreateCreature("bdcoun04",[592.825],10)~
 COMPILE_BAF_TO_BCS
 UNLESS ~bdcoun04~
 BUT_ONLY_IF_IT_CHANGES

COPY_EXISTING ~cut31u.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~ActionOverride("bdcoun03",EscapeArea())~
  ~ActionOverride("bdcoun03",EscapeArea())
   ActionOverride("bdcoun04",EscapeArea())~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

Link to comment

Archived

This topic is now archived and is closed to further replies.

×
×
  • Create New...