Possible bug of Anomen

[web2air]

I think I found minor bugs in anomen9, 10, 12.cre files

He should not be allowed to use Summon animals and Fire seeds in LV 6 Spells, but those anomens from character files above have access to the spells. Should be removed. That's all.

[CamDawg]

Conjure Animals and Animal Summoning (I-III) are allowed cleric spells, though Fire Seeds is a bug:

 

// anomen spellbook fix, remove fire seeds
COPY_EXISTING ~anomen9.cre~  ~override~
		  ~anomen10.cre~ ~override~
		  ~anomen12.cre~ ~override~
 PATCH_IF (SOURCE_SIZE > 0x2d3) THEN BEGIN // protects against invalid files
READ_LONG 0x2a0 "known_off"
READ_LONG 0x2a4 "known_num"
READ_LONG 0x2a8 "meminfo_off"
READ_LONG 0x2b0 "mem_off"
READ_LONG 0x2b4 "mem_num"
READ_LONG 0x2b8 "slot_off"
READ_LONG 0x2bc "item_off"
READ_LONG 0x2c4 "fx_off"
FOR (index2 = 0; index2 < mem_num; index2 = index2 + 1) BEGIN // spellbook adjustments
  READ_ASCII ("%mem_off%" + ("%index2%" * 0x0C)) "spell"
  PATCH_IF ("sppr606" STRING_COMPARE_CASE "%spell%" = 0) BEGIN
	WRITE_ASCII ("%mem_off%" + ("%index2%" * 0x0C)) ~foobar~ #8
  END
END
FOR (index = 0; index < known_num; index = index + 1) BEGIN // spellbook adjustments
  READ_ASCII ("%known_off%" + ("%index%" * 0x0C)) "spell"
  PATCH_IF ("sppr606" STRING_COMPARE_CASE "%spell%" = 0) BEGIN
	DELETE_BYTES ("%known_off%" + ("%index%" * 0x0C)) 0x0C
	SET "known_num" = ("%known_num%" - 1)
	SET "index" = ("%index%" - 1)
	PATCH_IF ("%meminfo_off%" >= "%known_off%") BEGIN
	  SET "meminfo_off" = ("%meminfo_off%" - 0x0C)
	END
	PATCH_IF ("%mem_off%" >= "%known_off%") BEGIN
	  SET "mem_off" = ("%mem_off%" - 0x0C)
	END
	PATCH_IF ("%slot_off%" >= "%known_off%") BEGIN
	  SET "slot_off" = ("%slot_off%" - 0x0C)
	END
	PATCH_IF ("%item_off%" >= "%known_off%") BEGIN
	  SET "item_off" = ("%item_off%" - 0x0C)
	END
	PATCH_IF ("%fx_off%" >= "%known_off%") BEGIN
	  SET "fx_off" = ("%fx_off%" - 0x0C)
	END
  END
END
WRITE_LONG 0x2a4 "%known_num%"
WRITE_LONG 0x2a8 "%meminfo_off%"
WRITE_LONG 0x2b0 "%mem_off%"
WRITE_LONG 0x2b8 "%slot_off%"
WRITE_LONG 0x2bc "%item_off%"
WRITE_LONG 0x2c4 "%fx_off%"
 END
 BUT_ONLY_IF_IT_CHANGES

[Guest Guest]

Conjure Animals and Animal Summoning (I-III) are allowed cleric spells, though Fire Seeds is a bug:

 

I compared Anomen to Aeries or my other cleric PCs, and they do not have those spells that Anomen have in the files I mentioned. That's why I thought this would be a bug. If Anomen can access extra spells which my normal cleric cannot, then I do not know which one is right and wrong.

 

Can you confirm me what should be? I could be wrong.

Thank you for your great work Again