Imoen's banter in Beregost

[Guest Lord Byron]

Hi,

i'm sorry if this is an old topic, but i tried to look the forum and i didn't find anything. I have installed all baldur's saga ( 11 cd) with all the patches, tutu (no easy), tutufix, npc project and some minor tweaks from baldur'tweaks tutumod ( also imoen's speech bug fixes, i was unsure about that but i tried).

 

I started a new game, it seemeed everything ok, Imoen is pretty talkative and also others, until ... Berengost.

 

There, Imoen starts a banter ( how ya doing? and then you have the dialogue about your current mood) and repeat it over and over so quickly that i have almost no time to kick her out the party or reload the game.

 

I tried everything, reloading, cleaning the cache, levelling her up, entering from different side, nothing: when she pops out in Berengost she starts that loop's banter.

 

I can parking her outside Berengost but she miss all the exp.

 

---

 

Another thing, i'm not sure, i have to play more, but after that bug the npc (all) seem less talkative, no discussion between Ajantis and Khalid, Janehria and so on ... ( i tried to play another character for little before the current one)

 

Thanks

[Kulyok]

( also imoen's speech bug fixes, i was unsure about that but i tried).

 

Could you please post the contents of your Weidu.log file? It is in your TUTU directory, and it can be opened with Notepad.

[Guest Guest]

( also imoen's speech bug fixes, i was unsure about that but i tried).

 

Could you please post the contents of your Weidu.log file? It is in your TUTU directory, and it can be opened with Notepad.

 

// Log of Currently Installed WeiDU Mods

// The top of the file is the 'oldest' mod

// ~TP2_File~ #language_number #component_number // [subcomponent Name -> ] Component Name

~SETUP-TUTUFIX.TP2~ #0 #0 // Core Bugfixes

~SETUP-TUTUFIX.TP2~ #0 #1 // Organised Journal Entries

~SETUP-TUTUFIX.TP2~ #0 #2 // Restored BG1 Loadscreens

~SETUP-TUTUFIX.TP2~ #0 #3 // BG2 Ammo Stacks

~SETUP-TUTUFIX.TP2~ #0 #4 // Totemic Druid Spirit Summons are Balanced

~SETUP-TUTUFIX.TP2~ #0 #5 // BG1 Summoning Spells

~SETUP-TUTUFIX.TP2~ #0 #7 // Walking Speeds

~SETUP-TUTUFIX.TP2~ #0 #12 // Journal Entry Titles

~SETUP-TUTUGUI.TP2~ #0 #0 // Baldurs Gate I GUI for Tutu

~BG1NPC.TP2~ #0 #0 // The BG1 NPC Project: Required Modifications for v12

~BG1NPC.TP2~ #0 #1 // The BG1 NPC Project: Banters, Quests, and Interjections

~BG1NPC.TP2~ #0 #7 // The BG1 NPC Project: Add Non-Joinable NPC portraits to quests and dialogues

~BG1NPC.TP2~ #0 #8 // The BG1 NPC Project: Coran's Romance Core (adult content)

~BG1NPC.TP2~ #0 #9 // The BG1 NPC Project: Dynaheir's Romance Core (teen content)

~BG1NPC.TP2~ #0 #10 // The BG1 NPC Project: Shar-Teel Relationship Core (adult content)

~BG1NPC.TP2~ #0 #11 // The BG1 NPC Project: Branwen's Romance Core (teen content)

~BG1NPC.TP2~ #0 #12 // The BG1 NPC Project: Xan's Romance Core (teen content)

~BG1NPC.TP2~ #0 #13 // The BG1 NPC Project: Ajantis Romance Core (teen content)

~BG1NPC.TP2~ #0 #14 // The BG1 NPC Project: Female Romance Challenges, Ajantis vs Xan vs Coran

~BG1NPC.TP2~ #0 #15 // Romance Timers -> Coran's Romance Speed (standard: 1 hour)

~BG1NPC.TP2~ #0 #20 // Romance Timers -> Dynaheir's Romance Speed (standard: 1 hour)

~BG1NPC.TP2~ #0 #25 // Romance Timers -> Xan's Romance Speed (standard: 1 hour)

~BG1NPC.TP2~ #0 #30 // Romance Timers -> Shar-Teel's Relationship Speed (standard: 1 hour)

~BG1NPC.TP2~ #0 #35 // Romance Timers -> Branwen's Romance Speed (standard: 1 hour)

~BG1NPC.TP2~ #0 #40 // Romance Timers -> Ajantis' Romance Speed (standard: 1 hour)

~BG1NPC.TP2~ #0 #45 // The BG1 NPC Project: NPCs can be sent to wait in an inn.

~BG1NPC.TP2~ #0 #46 // The BG1 NPC Project: Alora's Starting Location. -> Alora Starts in the Hall of Wonders.

~BG1NPC.TP2~ #0 #48 // The BG1 NPC Project: Eldoth's Starting Location. -> Eldoth Starts in the Cloakwood Forest.

~BG1NPC.TP2~ #0 #50 // The BG1 NPC Project: Quayle's Starting Location. -> Quayle Starts at the Wyrm's Crossing.

~BG1NPC.TP2~ #0 #52 // The BG1 NPC Project: Tiax's Starting Location. -> Tiax Starts in Baldur's Gate.

~BG1NPC.TP2~ #0 #54 // Jason Compton's Accelerated Banter Script.

~BG1NPC.TP2~ #0 #55 // The BG1 NPC Project: Make Shar-Teel Unkillable until In Party

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #90 // Disable Portrait Icons Added by Equipped Items

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #130 // Force All Dialogue to Pause Game

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #1080 // Add Bags of Holding

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #1100 // Reveal City Maps When Entering Area

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #1110 // Add Map Notes

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #1150 // Shapeshifter Rebalancing

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #1190 // Romance Bug Fixes

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #2090 // Change Experience Point Cap -> Remove Experience Cap

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #2210 // True Grand Mastery (Baldurdash)

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #2230 // Make +x/+y Weapons Consistent

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #2231 // Description Updates for Make +x/+y Weapons Consistent Component

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #3000 // Higher HP on Level Up -> Maximum

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #3190 // Rest Anywhere (Japheth)

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #4000 // Adjust Evil joinable NPC reaction rolls

~BG2_TWEAKS/SETUP-BG2_TWEAKS.TP2~ #0 #4020 // ToB-Style NPCs

[Kulyok]

Okay, your mod order seems fine to me - though maybe Domi or cmorgan can say more.

 

( also imoen's speech bug fixes, i was unsure about that but i tried).)

 

Could you please tell more of this? What are these bug fixes, and how did you install them? Your weidu.log file does not say about those.

[berelinde]

I see two Tweaks components not intended for Tutu.

 

BG2 Tweaks ToB-style NPCs used to cause trouble with Imoen, but it made her a mage. I think it was fixed.

 

BG2 Tweaks Romance fixes doesn't do a darned thing for Tutu. That's for BG2.

 

I don't think either will break your game.

 

I've had that happen with Imoen myself, after reinstalling a whole mess of mods.

 

Did you reinstall anything?

[Kulyok]

Okay, it seems to be a bug in BG1 NPC, after all. I can see what happened: the top banter ("How are ya doin'?") did not trigger before Beregost. That means that IMPC3 will remain 0, and the top banter will trigger again and again for as long as Imoen is in Beregost.

 

Most probably, PC and Imoen went via High Hedge, to get Kivan or something(FW3200). In any case, my suggestion is changing the code for ImFriendTalk 0 and 2, and set the variables to 1 and 3 respectively, and set the timers in the friend talks themselves.

 

 

 

 

Lord Byron: for the time being, you'll have to leave Imoen outside Beregost, I'm afraid.

[berelinde]

Right. I'll look into it at home, 5 hours from now.

[Kulyok]

I've posted above what I think to be the case.

[cmorgan]

In D:\BG1NPCpro5-3\BG1NPC\Phase1\BAF\X#IMOEN1.BAF

IF
InParty(Myself)
CombatCounter(0)
!See([ENEMY])
!StateCheck(Player1,STATE_SLEEPING)
RealGlobalTimerExpired("ImFriendTalkTime","GLOBAL")
See(Player1)
CombatCounter(0)
OR(4)
AreaCheck("FW2700")
AreaCheck("FW2800")
AreaCheck("FW3800")
AreaCheck("FW4300")
GlobalLT("Chapter","GLOBAL",3)
OR(2)
Global("ImFriendTalk","GLOBAL",0)
Global("ImFriendTalk","GLOBAL",2)
THEN
RESPONSE #100
PlaySong(0)
PlaySound("imoen99")
IncrementGlobal("ImFriendTalk","GLOBAL",1)
RealSetGlobalTimer("ImFriendlyTalkTime","GLOBAL",5)
StartDialogueNoSet(Player1)
END

IF
InParty(Myself)
CombatCounter(0)
!See([ENEMY])
RealGlobalTimerExpired("ImFriendlyTalkTime","GLOBAL")
OR(2)
Global("ImFriendTalk","GLOBAL",1)
Global("ImFriendTalk","GLOBAL",3)
THEN
RESPONSE #100
RealSetGlobalTimer("ImFriendTalkTime","GLOBAL",1800)
IncrementGlobal("ImFriendTalk","GLOBAL",1)
END

IF
InParty(Myself)
CombatCounter(0)
!See([ENEMY])
Global("ImoenBereg","GLOBAL",0)
Global("IMPC3","LOCALS",0)
AreaCheck("FW3300")
See(Player1)
THEN
RESPONSE #100
SetGlobal("ImoenBereg","GLOBAL",1)
END

IF
InParty(Myself)
CombatCounter(0)
!See([ENEMY])
Global("ImoenBereg","GLOBAL",1)
Global("IMPC3","LOCALS",0)
AreaCheck("FW3300")
See(Player1)
GlobalLT("Chapter","GLOBAL",3)
THEN
RESPONSE #100
PlaySong(0)
PlaySound("imoen99")
StartDialogueNoSet(Player1)
END

in D:\BG1NPCpro5-3\BG1NPC\Phase1\DLG\X#IMOEN.D

APPEND ~_IMOEN2~

IF WEIGHT #-2 ~
Global("ImFriendTalk","GLOBAL",1)~ THEN BEGIN IMPC1
SAY @0
IF ~~ THEN REPLY @1 GOTO IMPC1.1
IF ~~ THEN REPLY @2 GOTO IMPC1.1
IF ~~ THEN REPLY @3 GOTO IMPC1.2
++ @4 + IMPC1Gorion
END

IF ~~ IMPC1Gorion
SAY @5
= @6
IF ~~ THEN REPLY @7 GOTO IMPC1.3.1
IF ~~ THEN REPLY @8 GOTO IMPC1.3.1
IF ~~ THEN REPLY @9 GOTO IMPC1.3
END

IF ~~ THEN BEGIN IMPC1.1
SAY @10
IF ~~ THEN REPLY @7 GOTO IMPC1.3.1
IF ~~ THEN REPLY @11 GOTO IMPC1.3
IF ~~ THEN REPLY @9 GOTO IMPC1.3
END

IF ~~ THEN BEGIN IMPC1.2
SAY @12
IF ~~ THEN EXIT
END

IF ~~ THEN BEGIN IMPC1.3
SAY @13
= @14
= @15
IF ~~ THEN REPLY @16 GOTO IMPC1.4
IF ~~ THEN REPLY @17 GOTO IMPC1.5
END

IF ~~ THEN BEGIN IMPC1.3.1
SAY @18
= @14
= @15
IF ~~ THEN REPLY @16 GOTO IMPC1.4
IF ~~ THEN REPLY @17 GOTO IMPC1.5
END

IF ~~ THEN BEGIN IMPC1.4
SAY @19
IF ~~ THEN GOTO IMPC1.5
END

IF ~~ THEN BEGIN IMPC1.5
SAY @20
IF ~~ THEN GOTO IMPC1.6
END

IF ~~ THEN BEGIN IMPC1.6
SAY @21
IF ~~ THEN EXIT
END

IF WEIGHT #-2 ~Global("ImFriendTalk","GLOBAL",3)~ THEN BEGIN IMPC2
SAY @22
IF ~~ THEN REPLY @23 GOTO IMPC2.1
IF ~~ THEN REPLY @24 GOTO IMPC2.2
IF ~~ THEN REPLY @25 GOTO IMPC2.3
IF ~~ THEN REPLY @26 GOTO IMPC2.4
END

 

I am not sure where we are getting stuck... but let me try. We are saying that for some reason,

 

[ Global("ImFriendTalk","GLOBAL",0) ] did not fire in this game, and since it now is concurrent with [ Global("ImoenBereg","GLOBAL",1) Global("IMPC3","LOCALS",0) ] the ImoenBereg block fires but gets [ Global("ImFriendTalk","GLOBAL",0) ]. Since the timer was not reset, the shorttimer fails also, leaving the initial condition open.

 

If this is true/I have understood correctly, there is one thing that you might do to your game to test it - use CLUAConsole to set

Global("IMPC3","LOCALS",1) and see if it clears the conflict. Can you try that, so we can see if we have guessed correctly, please?

 

You could also debug this by starting from a save before Beregost, and using CLUAConsole to set

Global("ImFriendTalk","GLOBAL",0)

 

and hang around for a minute (60 seconds real time) and see if the friendship talk fires - if it does not, try adding SetGlobalTimer("ImFriendTalkTime","GLOBAL",1) and wait again.

 

Kulyok, have I followed your logic correctly?

[Kulyok]

Yep, absolutely. I'd add

 

OR(5)
AreaCheck("FW2700")
AreaCheck("FW2800")
AreaCheck("FW3200")
AreaCheck("FW3800")
AreaCheck("FW4300")

 

also.

[cmorgan]

Added High Hedge to build the OR(5), February 6, 2007 Tutu/BGT, pro5-3

 

Instead of rebuilding the friendtalk sequence, can we somehow force the friendtalk to fire earlier on all games, similar to weighting dialogues?

 

or,

 

I am thinking perhaps we should add the condition GlobalGT("ImFriendTalk","GLOBAL",1) to the Beregost trigger block.

 

Just trying to avoid rescripting all of these timers to a timer>dlg>timer sequence; everything except Ajantis uses the timered swinging door.

[Kulyok]

Or maybe just add

 

!AreaCheck("FW3300") in the first one.

 

If it was me, I'll recode it completely, but well. It might have been author's intention.

[berelinde]

Why can't we just lose the area check entirely? Or have it set for !AreaCheck("FW3300")? Does it make one bit of difference if Imoen asks you how you're holding up on the Coastway or if she's waits until you're in Feldpost's about to be assaulted by Marl? I don't think it does. Lose the area check, and a whole lot of problems just go away.

 

It would also be possible to just shorten the long timer, make the short timer go away, and close the variable in dialogue.

[berelinde]

How about this in X#IMOEN1.baf, lines 12 through 45:

 

IF
InParty(Myself)
CombatCounter(0)
!See([ENEMY])
Global("ImPCTimerStarted","GLOBAL",0)
Global("ImFriendTalk","GLOBAL",0)
THEN
RESPONSE #100
RealSetGlobalTimer("ImFriendTalkTime","GLOBAL",300)
SetGlobal("ImFriendTalk","GLOBAL",1)
SetGlobal("ImPCTimerStarted","GLOBAL",1)
END

IF
InParty(Myself)
CombatCounter(0)
!See([ENEMY])
!StateCheck(Player1,STATE_SLEEPING)
RealGlobalTimerExpired("ImFriendTalkTime","GLOBAL")
OR(2)
Global("ImFriendTalk","GLOBAL",1)
Global("ImFriendTalk","GLOBAL",3)
See(Player1)
CombatCounter(0)
!AreaCheck("FW3300")
GlobalLT("Chapter","GLOBAL",3)
THEN
RESPONSE #100
PlaySong(0)
PlaySound("imoen99")
IncrementGlobal("ImFriendTalk","GLOBAL",1)
RealSetGlobalTimer("ImFriendTalkTime","GLOBAL",1800)
StartDialogueNoSet(Player1)
END

 

The next script block, where her timer gets reset, goes away completely, so the next block is the Beregost talk.

 

X#IMOEN.D lines 3 through 10 become:

IF WEIGHT #-2 ~
Global("ImFriendTalk","GLOBAL",2)~ THEN BEGIN IMPC1
SAY @0
IF ~~ THEN REPLY @1 DO ~SetGlobal("ImFriendTalk","GLOBAL",3)~ GOTO IMPC1.1
IF ~~ THEN REPLY @2 DO ~SetGlobal("ImFriendTalk","GLOBAL",3)~ GOTO IMPC1.1
IF ~~ THEN REPLY @3 DO ~SetGlobal("ImFriendTalk","GLOBAL",3)~ GOTO IMPC1.2
++ @4 DO ~SetGlobal("ImFriendTalk","GLOBAL",3)~ + IMPC1Gorion
END

 

Lines 63 through 69 become:

 

IF WEIGHT #-2 ~Global("ImFriendTalk","GLOBAL",4)~ THEN BEGIN IMPC2
SAY @22
IF ~~ THEN REPLY @23 DO ~SetGlobal("ImFriendTalk","GLOBAL",5)~ GOTO IMPC2.1
IF ~~ THEN REPLY @24 DO ~SetGlobal("ImFriendTalk","GLOBAL",5)~ GOTO IMPC2.2
IF ~~ THEN REPLY @25 DO ~SetGlobal("ImFriendTalk","GLOBAL",5)~ GOTO IMPC2.3
IF ~~ THEN REPLY @26 DO ~SetGlobal("ImFriendTalk","GLOBAL",5)~ GOTO IMPC2.4
END

 

She's only got the two friend talks. This doesn't have to be hard.

[cmorgan]

This makes sense to me -- input from other Project folks?