bug in fixed ar1600.bcs

[Ardanis]

I've seen this problem years ago with Baldurdash but didn't bother to investigate. Now, it happened with FP as well, so measures were taken.

 

// bynnlaw initial vamp fight should check for non-existence not dead
COPY_EXISTING ~ar1600.BCS~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~Dead("\(ppvalen\|ppparis\|ppdel\)")~
				  ~!Exists("\1")~
 COMPILE_BAF_TO_BCS

 

The block in question in reality is

IF
 Dead("ppvalen")  // ~Valen~
 Dead("ppparis")  // ~Parisa~
 Dead("ppdel")  // ~Del~
 OR(2)
Global("AsylumPlot","GLOBAL",3)
Global("AsylumPlot","GLOBAL",4)
THEN
 RESPONSE #100
SetGlobal("AsylumPlot","GLOBAL",5)
ActionOverride("uhostile",DestroySelf())
END

it becomes always true when siding with Bodhi - those vampires !exist because they didn't spawn in the first place. As a result, Saemon skips his speech near the tavern (after which he's supposed to get back to the ship) and keeps saying 'Having troubles?', remaining at the tavern along the way.

 

This global governs allegiance to either Aran or Bodhi - ThiefGroup. At 1 it's with Aran, at 2 it's with Bodhi.

 

Should fix the problem

// bynnlaw initial vamp fight should check for non-existence not dead - uglier
COPY_EXISTING ~ar1600.BCS~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~Dead("\(ppvalen\|ppparis\|ppdel\)")~
~Global("ThiefGroup","global",1)
 !Exists("\1")~
 COMPILE_BAF_TO_BCS

Or maybe

// bynnlaw initial vamp fight should check for non-existence not dead - longer
COPY_EXISTING ~ar1600.BCS~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~Dead("ppvalen")
 Dead("ppparis")
 Dead("ppdel")~
~Global("ThiefGroup","global",1)
 !Exists("ppvalen")
 !Exists("ppparis")
 !Exists("ppdel")~
 COMPILE_BAF_TO_BCS