I messed up my savegame...

[LordTerror]

I edited MixMod to give enemies 4x as much life with +4 to everything. I have had no problems with this mod until I got to Durlag's Tower. When I went to do the "Durlag's Pride" puzzle, I found out that I couldn't complete it because the "Durlag's Pride" unit (a nearly invisible unit that is on top of a sword statue) was missing. I reloaded from a save when I entered the labyrinth, and went to see if I it was there. What I saw was that the "Durlag's Pride" unit was dead. This made me think that it was the extra health that caused the problem (by rolling over to a negative number). I uninstalled that mod, reloaded an old save, went to Durlag's Tower, and found "Durlag's Pride" unit alive. So I found the problem, but unfortunately my only save that hasn't been to the Durlag's Tower labyrinth is many days old. So here are my questions:

 

1) Is there an easy way to reset the labyrinth so that the "Durlag's Pride" unit will be there?

 

2) Is there an easy way to find out what the "Durlag's Pride" unit's file is so that I can spawn it using the CLUAConsole?

 

3) How can I edit this script to prevent HP from rolling over?...

 

BEGIN ~4x/+4~
SUBCOMPONENT ~Difficulty~
COPY_EXISTING_REGEXP GLOB ~.*\.cre~ ~override~
PATCH_IF SOURCE_SIZE > 0x70 THEN
BEGIN
READ_LONG 0x1CC "biography"
READ_BYTE 0x270 "Ally"
PATCH_IF (NOT ("%biography%" > 0) AND NOT ("%Ally%" = 1) AND NOT ("%Ally%" = 2) AND NOT ("%Ally%" = 3) AND NOT ("%Ally%" = 4) AND NOT ("%Ally%" = 5) AND NOT ("%Ally%" = 20) AND NOT ("%Ally%" = 30)) THEN
BEGIN

	READ_SHORT 0x24 "currenthp"
	READ_SHORT 0x26 "maxhp"
	READ_SHORT 0x46 "naturalac"
	READ_SHORT 0x48 "effectiveac"
	READ_BYTE 0x52 "thac0"

	WRITE_SHORT 0x24 (("%currenthp%" * 400) / 100)
	WRITE_SHORT 0x26 (("%maxhp%" * 400) / 100)
	WRITE_SHORT 0x46 ("%naturalac%" - 4)
	WRITE_SHORT 0x48 ("%effectiveac%" - 4)
	WRITE_BYTE 0x52 ("%thac0%" - 4)
END
END

[Wisp]

1) Is there an easy way to reset the labyrinth so that the "Durlag's Pride" unit will be there?

I'm afraid not.

2) Is there an easy way to find out what the "Durlag's Pride" unit's file is so that I can spawn it using the CLUAConsole?

Its creature code is dursword, or _ursword if you are on Tutu.

3) How can I edit this script to prevent HP from rolling over?...

The Duralg's sword creature has 10000 HP, so we know this is a safe number. Since you probably don't want HPs higher than 10000, you can simply use this number as your max.

Also, you want something higher than 0x70 for your SOURCE_SIZE check.

BEGIN ~4x/+4~
SUBCOMPONENT ~Difficulty~
COPY_EXISTING_REGEXP GLOB ~.*\.cre~ ~override~
PATCH_IF SOURCE_SIZE > 0x2d3 THEN
BEGIN
READ_LONG 0x1CC "biography"
READ_BYTE 0x270 "Ally"
PATCH_IF (NOT ("%biography%" > 0) AND NOT ("%Ally%" = 1) AND NOT ("%Ally%" = 2) AND NOT ("%Ally%" = 3) AND NOT ("%Ally%" = 4) AND NOT ("%Ally%" = 5) AND NOT ("%Ally%" = 20) AND NOT ("%Ally%" = 30)) THEN
BEGIN

	READ_SHORT 0x24 "currenthp"
	READ_SHORT 0x26 "maxhp"
	READ_SHORT 0x46 "naturalac"
	READ_SHORT 0x48 "effectiveac"
	READ_BYTE 0x52 "thac0"

	WRITE_SHORT 0x24 currenthp * 4 < 10000 ? currenthp * 4 : 10000
	WRITE_SHORT 0x26 maxhp * 4 < 10000 ? maxhp * 4 : 10000
	WRITE_SHORT 0x46 ("%naturalac%" - 4)
	WRITE_SHORT 0x48 ("%effectiveac%" - 4)
	WRITE_BYTE 0x52 ("%thac0%" - 4)
END
END

[LordTerror]

This fixed my current game AND fixed the bug I was having with the script.

 

THANK YOU!