Jump to content

Paladin/rangers falling Hell Trials


CamDawg

Recommended Posts

Paladins and rangers should fall immediately when taking the evil path in the Hell trials. BD fixes this by amending the area scripts. ar2904 already ahs a check, but it uses area variables instead of a GLOBAL, so it's patchd while the rest are extended.

 

// script changes to ensure paladins/rangers fall in Hell tests
EXTEND_BOTTOM ~ar2901.bcs~ ~bg2fixpack/baf/ar2901.baf~
EXTEND_BOTTOM ~ar2902.bcs~ ~bg2fixpack/baf/ar2902.baf~
EXTEND_BOTTOM ~ar2903.bcs~ ~bg2fixpack/baf/ar2903.baf~
COPY_EXISTING ~ar2904.BCS~ ~override~
 DECOMPILE_BCS_TO_BAF
   REPLACE_TEXTUALLY ~Global("PaladinGone","AR2904"~
                     ~Global("AbyssPaladinGone","GLOBAL"~
   REPLACE_TEXTUALLY ~Global("RangerGone","AR2904"~
                     ~Global("AbyssRangerGone","GLOBAL"~
 COMPILE_BAF_TO_BCS
EXTEND_BOTTOM ~ar2905.bcs~ ~bg2fixpack/baf/ar2905.baf~

 

Where the extensions have the form:

 

IF
 Global("Player1Fear","GLOBAL",2)
 Global("AbyssPaladinGone","GLOBAL",0)
 Class(Player1,PALADIN_ALL)
THEN
 RESPONSE #100
   SetGlobal("AbyssPaladinGone","GLOBAL",1)
   ActionOverride(Player1,RemovePaladinHood())
END

IF
 Global("Player1Fear","GLOBAL",2)
 Global("AbyssRangerGone","GLOBAL",0)
 Class(Player1,RANGER_ALL)
THEN
 RESPONSE #100
   SetGlobal("AbyssRangerGone","GLOBAL",1)
   ActionOverride(Player1,RemoveRangerHood())
END

Link to comment

Archived

This topic is now archived and is closed to further replies.

×
×
  • Create New...