Shar-Teel Romance Issue

[erebusant]

When Shar-Teel romance reaches the "FlirtLate" stage I get the flirt that corresponds to @1055 in X#SHROM.tra and then the random number selected links that response to @1076 in X#SHROM.tra where I get a NO VALID REPLIES OR LINKS indication. Looking at X#SHROM.D the @1076 response is missing the "IF ~~ THEN EXIT"

IF ~~ SHINFL52
SAY @1076
END

 

It should read:

IF ~~ SHINFL52
SAY @1076
IF ~~ THEN EXIT
END

[cmorgan]

Thank you!

 

I am taking a look through and seeing if we have any more of these, too.

[erebusant]

Thank you!

 

I am taking a look through and seeing if we have any more of these, too.

One other wierd occurence I had was when we finally made it into the Nashkel Mines. Shar-Teel had her "sulking" dreamtalk, and then upon completion of the rest period, the whole dreamtalk looped around and went through all the dialogs again, complete with resting for an additional 8 hours. After that the loop stopped and the game continued.

[cmorgan]

Which one is the "sulk" one?

[erebusant]

Which one is the "sulk" one?

I think it's "Interest 18" in the .d file. It covers @672-@699 in the .tra file. I don't know if it has anything to do with the RestParty() actions included the .d or not, since the RestParty() has already been commanded to begin the dreamtalk.

[cmorgan]

Strange.

 

I have

 

/* Interest 18 - At rest */
IF WEIGHT #-2 ~%BGT_VAR% Global("X#SharInterestTalk","GLOBAL",36)~ THEN BEGIN SHRO18
SAY @672
++ @673 DO ~IncrementGlobal("X#SharInterestTalk","GLOBAL",1) RealSetGlobalTimer("X#SharInterestTime","GLOBAL",SHROM_TIMER)~ + SHRO17.1
++ @674 DO ~IncrementGlobal("X#SharInterestTalk","GLOBAL",1) RealSetGlobalTimer("X#SharInterestTime","GLOBAL",SHROM_TIMER)~ + SHRO17.1
++ @675 DO ~IncrementGlobal("X#SharInterestTalk","GLOBAL",1) RealSetGlobalTimer("X#SharInterestTime","GLOBAL",SHROM_TIMER)~ + SHRO17.2
++ @676 DO ~IncrementGlobal("X#SharInterestTalk","GLOBAL",1) RealSetGlobalTimer("X#SharInterestTime","GLOBAL",SHROM_TIMER)~ + SHRO17.3
++ @677 + SHRO17.4
END

IF ~~ SHRO17.1
SAY @678
++ @675 + SHRO17.2
++ @679 + SHRO17.5
++ @680 + SHRO17.6
++ @681 + SHRO17.7
END

IF ~~ SHRO17.2
SAY @682
++ @683 + SHRO17.8
++ @684 + SHRO17.9
++ @685 + SHRO17.5
END

IF ~~ SHRO17.3
SAY @686
++ @675 + SHRO17.2
++ @679 + SHRO17.5
++ @677 + SHRO17.4
END

IF ~~ SHRO17.4
SAY @687
++ @688 + SHRO17.7
++ @689 + SHRO17.2
END

IF ~~ SHRO17.5
SAY @690
= @691
++ @692 + SHRO17.10
++ @693 + SHRO17.7
END

IF ~~ SHRO17.6
SAY @694
IF ~~ THEN GOTO SHRO17.5
END

IF ~~ SHRO17.7
SAY @695
IF ~~ THEN DO ~RestParty()~
EXIT
END

IF ~~ SHRO17.8
SAY @696
IF ~~ THEN DO ~RestParty()~
EXIT
END

IF ~~ SHRO17.9
SAY @697
++ @688 + SHRO17.7
++ @698 + SHRO17.5
END

IF ~~ SHRO17.10
SAY @699
IF ~~ THEN DO ~IncrementGlobal("X#SharKind","GLOBAL",1) RestParty()~
EXIT
END

 

and the next one is set up by .baf:

 

/* Interest Talk 20 */
IF %BGT_VAR%
Global("X#SharInterestTalk","GLOBAL",39)
InParty(Myself)
CombatCounter(0)
!See([ENEMY])
!StateCheck(Player1,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
Global("X#SharInterest","GLOBAL",2)
ReputationLT(Player1,11)
OR(4)
AreaCheck("%Candlekeep_Catacombs_L1Antechamber%")
AreaCheck("%Candlekeep_Catacombs_L1%")
AreaCheck("%Candlekeep_Catacombs_L2%")
AreaCheck("%CandlekeepCaves%")
THEN
RESPONSE #100
IncrementGlobal("X#SharInterestTalk","GLOBAL",1)
END

 

 

which then triggers the availability of the next talk...

 

we have those RestParty() materials all over the place and they test out in other situations.

 

Can you replictae it? I will try to this week as well.

[cmorgan]

erebusant, any replication of this? I can't get it to happen on my install...

[erebusant]

erebusant, any replication of this? I can't get it to happen on my install...

I haven't had any more occurences of this either. I'm over in Bonehill right now re-ordering dialogs and so far over there with a Rep of 10 all i'm getting are "late flirts".

[cmorgan]

blast

 

I will try again tomorrow night and see if I can figure out what might have happened, and see if we can prevent it reoccurring/ reooccuring - (dammit) Happening Again.