The Tree of Life

[cmorgan]

/* Tree of Life Extension */

/* Add the extension to the bottom of the stack */
EXTEND_BOTTOM ~PLAYER1~ 33
 IF ~InParty("c-aran") InMyArea("c-aran") !StateCheck("c-aran",CD_STATE_NOTVALID) Global("c-arantreelife","GLOBAL",0)~ EXTERN ~PLAYER1~ c-arantree
END

/* Add the initiating state */
APPEND ~PLAYER1~

IF ~~ c-arantree
 SAY ~[ARAN] You see Aran Whitehand, sword and scribe. His jaw is as hard as granite, and he keeps flexing his hands. He looks up, his eyes meeting yours.~
 IF ~~ THEN DO ~SetGlobal("c-arantreelife","GLOBAL",1)~ EXTERN ~C-ARANJ~ c-arantreeoflife
END

END

/* add the Tree of Life Talk */
CHAIN ~C-ARANJ~ c-arantreeoflife
~[ARAN] So, what's th' word?~
== ~C-ARANJ~ IF ~!Global("c-aranromance","GLOBAL",2)~ THEN ~[ARAN] Things look a mite grim, don't they?~
== ~C-ARANJ~ IF ~Global("c-aranromance","GLOBAL",2)~ THEN ~[ARAN] Looks like we might not have time for sparkin'. I was hopin' more for a "happy ever after" endin', an' all.~
END
++ ~[PC] Aran, I have no right to throw your life into this battle. You have served well. It might be time for you to move on.~ EXTERN ~C-ARANJ~ c-arantreemove
++ ~[PC] Are you with me, Aran? This is bigger than anything we have ever faced before.~ EXTERN ~C-ARANJ~ c-arantreebigger
+ ~!Global("c-aranromance","GLOBAL",2)~ + ~[PC] Aran, it is time you left. There is nothing to be gained by throwing away your very existence.~ EXTERN ~C-ARANJ~ c-arantreeexist
+ ~!Global("c-aranromance","GLOBAL",2)~ + ~[PC] What is your evaluation, Aran. Is this unwinnable?~ EXTERN ~C-ARANJ~ c-arantreeunwinnable2
+ ~Global("c-aranromance","GLOBAL",2)~ + ~[PC] I love you, Aran. I need your counsel. Do you think this is unwinnable?~ EXTERN ~C-ARANJ~ c-arantreeunwinnable
+ ~Global("c-aranromance","GLOBAL",2)~ + ~[PC] Just hold me for a moment.~ EXTERN ~C-ARANJ~ c-arantreehold
++ ~[PC] Where is all your faith, Aran?~ EXTERN ~C-ARANJ~ c-arantreefinal
++ ~[PC] So, sellsword. Are you man enough to follow me to your doom?~ EXTERN ~C-ARANJ~ c-arantreeexist

APPEND ~C-ARANJ~

IF ~~ c-arantreemove
 SAY ~[ARAN] Bugger that. You bloody well know I'm not goin' nowhere if I get a say.~
 IF ~~ THEN GOTO c-arantreefinal
END

IF ~~ c-arantreebigger
 SAY ~[ARAN] Sune's... You are right. We are facin' more than anyone should.~
 IF ~~ THEN GOTO c-arantreefinal
END

IF ~~ c-arantreeexist
 SAY ~[ARAN] I have backed your play for a good time now, an' I think you know where I stand.~
 IF ~~ THEN GOTO c-arantreefinal
END

IF ~~ c-arantreeunwinnable
 SAY ~[ARAN] Unwinnable? My heart's unwinnable, but you have it solid an' for keeps. There ain't nothin' unwinnable. It's just a matter o' what you are willin' to pay.~
 IF ~~ THEN GOTO c-arantreefinal
END

IF ~~ c-arantreeunwinnable2
 SAY ~[ARAN] Unwinnable? There ain't nothin' unwinnable. It's just a matter o' what you are willin' to pay.~
 IF ~~ THEN GOTO c-arantreefinal
END

IF ~~ c-arantreehold
 SAY ~[ARAN] Aye.~
 = ~[ARAN] (His arms encircle you in a crushing grip, and your body is pressed deeply into his.)~
 = ~[ARAN] (He pulls away suddenly, holding you at arms length, eyes ablaze with inner fire, his voice whispering huskily in your ears.)~
 IF ~~ THEN GOTO c-arantreefinal
END

END

/* Tie the talk back into the original dialog */
CHAIN ~C-ARAN~ c-arantreefinal
~[ARAN] You know, I swear by plenty o' gods, <CHARNAME>. And make no mistake, I'm right scared.~
== ~C-ARANJ~ IF ~!Class("c-aran",CLERIC_ALL)~ THEN ~[ARAN] But I got more faith that you will prevail than in th' entire pantheon. If you leave it to me, I'll choose to be where I belong, backin' your play, no matter th' odds.~
== ~C-ARANJ~ IF ~Class("c-aran",CLERIC_ALL)~ THEN ~[ARAN] Besides my own god, I hold no other bein' before you. If it is  all right wi' you, I'll stay where I belong - backin' your play, no matter th' odds.~
END
COPY_TRANS ~PLAYER1~ 33

 

Am I missing something a PC would want to say to Aran? I sometimes don't leave enough ambiguity to ensure that lines can be read within eveil character as well as good/neutral.

[Icendoan]

No, but you seem to have too identical stateNames (c-arantreeunwinnable) where it should be c-arantreeunwinnable2.

 

Icen

[cmorgan]

Got it - thanks!