Jump to content

Neb's Nasty Cutter Fixes


CamDawg

Recommended Posts

Neb's Nasty Cutter has some issues, only a few of which are addressed by Baldurdash. (Do I even need to mention that devSin fixes this correctly ? :bday: ) It's supposed to turn into a normal dagger when the poison charges expire, but it just disappears instead. This fix clones a dagger without the poison damage and adjusts the original dagger to turn into the new dagger once the charges expire. Both versions remove an extraneous Slow effect.

 

// cloning Neb's dagger to make a version with no effects
COPY_EXISTING ~nebdag.itm~ ~override/cdnebdag.itm~
 SAY DESC @106
 WRITE_SHORT 0x42 0 // sets lore to zero for instant ID
 READ_LONG   0x64 "abil_off"
 READ_SHORT  0x68 "abil_num"
 READ_LONG   0x6a "fx_off"
 WHILE ("%abil_num%" > 0) BEGIN // looks for melee ability header
   SET "abil_num" = ("%abil_num%" - 1)
   READ_BYTE   ("%abil_off%" +        ("%abil_num%" * 0x38)) "type"
   PATCH_IF ("%type%" = 1) BEGIN // melee ability check
     READ_SHORT  ("%abil_off%" + 0x1e + ("%abil_num%" * 0x38)) "abil_fx_num"
     READ_SHORT  ("%abil_off%" + 0x20 + ("%abil_num%" * 0x38)) "abil_fx_idx"
     WRITE_SHORT ("%abil_off%" + 0x22 + ("%abil_num%" * 0x38)) 0 // charges
     WHILE ("%abil_fx_num%" > 0) BEGIN // disables all melee effects
       SET "abil_fx_num" = ("%abil_fx_num%" - 1)
       WRITE_BYTE ("%fx_off%" + 0x12 + (("%abil_fx_idx%" + "%abil_fx_num%") * 0x30)) 0 // probability: 0
     END
   END
 END
 BUT_ONLY_IF_IT_CHANGES

// altering Neb's dagger to change to cdnebdag when charges run out
COPY_EXISTING ~nebdag.itm~ ~override~
 WRITE_ASCII 0x10 ~cdnebdag~
 READ_LONG   0x64 "abil_off"
 READ_SHORT  0x68 "abil_num"
 READ_LONG   0x6a "fx_off"
 WHILE ("%abil_num%" > 0) BEGIN // looks for melee ability header
   SET "abil_num" = ("%abil_num%" - 1)
   WRITE_BYTE  ("%abil_off%" + 0x24 + ("%abil_num%" * 0x38)) 2 // replace with used up when drained
   WRITE_BYTE  ("%abil_off%" + 0x27 + ("%abil_num%" * 0x38)) 1 // item does not recharge
   READ_BYTE   ("%abil_off%" +        ("%abil_num%" * 0x38)) "type"
   PATCH_IF ("%type%" = 1) BEGIN // melee ability check
     READ_SHORT  ("%abil_off%" + 0x1e + ("%abil_num%" * 0x38)) "abil_fx_num"
     READ_SHORT  ("%abil_off%" + 0x20 + ("%abil_num%" * 0x38)) "abil_fx_idx"
     WHILE ("%abil_fx_num%" > 0) BEGIN // searches through fx for slow effect
       SET "abil_fx_num" = ("%abil_fx_num%" - 1)
       READ_SHORT ("%fx_off%" +        (("%abil_fx_idx%" + "%abil_fx_num%") * 0x30)) "fx_type"
       PATCH_IF ("%fx_type%" = 40) BEGIN // slow effect
         WRITE_BYTE ("%fx_off%" + 0x12 + (("%abil_fx_idx%" + "%abil_fx_num%") * 0x30)) 0 // probability: 0
       END
     END
   END
 END
 BUT_ONLY_IF_IT_CHANGES

 

I've changed the description on the cloned dagger from the original description of

 

This is a vicious weapon used by Neb, covered with old blood and coated in a poison that is both quick-acting and extremely deadly.  Only the truly evil would dare to use this item on their own.  Once the poison is used up, however, Neb's Cutter will act as a normal enchanted dagger.

 

STATISTICS:

 

Combat Ability: Target must make a saving throw vs. poison or suffer 2 points of damage per second for 10 seconds.

THAC0:  +2 bonus

Damage:  1D4 + 2

Damage type:  piercing

Weight: 1

Speed Factor: 0

Proficiency Type: Dagger

Type:  1-handed

Not Usable By:

Cleric

Non-evil alignments

 

to this for the charge-less dagger:

 

@106 = ~This is a vicious weapon used by Neb is covered with old blood.  Only the truly evil would dare to use this item on their own.  The poison has been used up, and the dagger is now a normal enchanted dagger.

 

STATISTICS:

 

THAC0:  +2 bonus

Damage:  1D4 + 2

Damage type:  piercing

Weight: 1

Speed Factor: 0

Proficiency Type: Dagger

Type:  1-handed

Not Usable By:

Cleric

Non-evil alignments~

Link to comment
@106 = ~This is a vicious weapon used by Neb is covered with old blood.

That sentence's grammar isn't very good--for the smallest possible change it needs an "and" between "Neb" and the second "is," but I'd suggest,

@106 = ~This vicious weapon used by Neb is covered with old blood.  Though the poison that once coated the blade is gone, only the truly evil would dare to use this item on their own.

 

STATISTICS:

 

THAC0:  +2 bonus

Damage:  1D4 + 2

Damage type:  piercing

Weight: 1

Speed Factor: 0

Proficiency Type: Dagger

Type:  1-handed

Not Usable By:

Cleric

Non-evil alignments~

Link to comment

Archived

This topic is now archived and is closed to further replies.

×
×
  • Create New...