tree of life dialog

[Guest Riane]

First of all, I want to say, that Amber is really cool and the way of getting her out of prison reminded me on Asterix finding Permit A-38...

But I got a little problem in suldanessalar when I went through SoA without her.

When it comes to the tol-dialog, I get this:

 

"Amber, the wilful tiefling you encountered in Athkatla has earned her place at your side many times over. Together you have seen many battles, but is she willing to follow you now, in the face of almost certain death?"

 

Then I can talk to Amber, but she isnt there and the dialog ends without talking to my existing party-members.

I deinstalled Amber and it worked, so it was not a real problem.

 

Thank you for this mod. Ciaoi!

[Darios]

First of all, I want to say, that Amber is really cool and the way of getting her out of prison reminded me on  Asterix finding Permit A-38...

But I got a little problem in suldanessalar when I went through SoA without her.

When it comes to the tol-dialog, I get this:

 

"Amber, the wilful tiefling you encountered in Athkatla has earned her place at your side many times over. Together you have seen many battles, but is she willing to follow you now, in the face of almost certain death?"

 

Then I can talk to Amber, but she isnt there and the dialog ends without talking to my existing party-members.

I deinstalled Amber and it worked, so it was not a real problem.

 

Thank you for this mod. Ciaoi!

<{POST_SNAPBACK}>

 

Just to clarify, do you mean that you got Amber's Tree of Life dialog segment even though Amber was not in your party (but the mod was installed). If this was the case, it is most strange. I will have to let Meira figure this one out, she's the one who coded the Tree of Life dialog and knows much more about it than me.

[Riane]

Just to clarify, do you mean that you got Amber's Tree of Life dialog segment even though Amber was not in your party (but the mod was installed). If this was the case, it is most strange. I will have to let Meira figure this one out, she's the one who coded the Tree of Life dialog and knows much more about it than me.

<{POST_SNAPBACK}>

 

Exactly. And yes, it is strange... When I got this, I first wondered how I could have been so blind not to see, that I had Amber with me... But she was not there.

[Grim Squeaker]

Okay I've had a look at the coding for you, and yeah there's no checks to see if Amber is actually in the party for the non-romance options.

 

INTERJECT PLAYER1 33 M#AmberTreeOfLifeRomance2
== PLAYER1 IF ~Global("M#AmberRomanceActive","GLOBAL",2)
	 Global("M#AmberMatch","GLOBAL",3)~ 
THEN ~Amber, the wilful tiefling that you encountered in Athkatla, has grown very close with <PLAYER2>, your ever faithful companion. Her affection for him is obvious, but will that bond be strong enough for Amber to follow you to the desperate battle against Irenicus?~
END
++ ~Are you ready, Amber? I need to be sure that I can trust you to stay by my side.~ EXTERN M#AMBERJ AmberTreeOfLifeD
++ ~You should not be here, Amber. This is not your fight, but mine alone.~ EXTERN M#AMBERJ AmberTreeOfLifeE
++ ~This is too dangerous, Amber. I don't want you risking you newfound happiness with <PLAYER2> for this.~ EXTERN M#AMBERJ AmberTreeOfLifeI

INTERJECT PLAYER1 33 M#AmberTreeOfLifeFriendship
== PLAYER1 IF ~Global("M#AmberFriend","GLOBAL",1)~ 
THEN ~Amber, the wilful tiefling you encountered in Athkatla has grown to be your trusted ally and a dear friend. The compassion she has shown has helped you survive the pain and emptiness caused by Irenicus stealing your soul.  Together you have seen many battles, but is she willing to follow you now, in the face of almost certain death?~
END
++ ~Are you ready, Amber? I need to be sure that I can trust you to stay by my side.~ EXTERN M#AMBERJ AmberTreeOfLifeG
++ ~You should not be here, Amber. This is not your fight, but mine alone.~ EXTERN M#AMBERJ AmberTreeOfLifeH
++ ~This is too dangerous, I don't want you risking yourself for my sake.~ EXTERN M#AMBERJ AmberTreeOfLifeJ

INTERJECT PLAYER1 33 M#AmberTreeOfLife
== PLAYER1 IF ~!Global("M#AmberFriend","GLOBAL",1)
	 !Global("M#AmberRomanceActive","GLOBAL",2)~ 
THEN ~Amber, the wilful tiefling you encountered in Athkatla has earned her place at your side many times over. Together you have seen many battles, but is she willing to follow you now, in the face of almost certain death?~
END
++ ~Are you ready, Amber? I need to be sure that I can trust you to stay by my side.~ EXTERN M#AMBERJ AmberTreeOfLifeA
++ ~You should not be here, Amber. This is not your fight, but mine alone.~ EXTERN M#AMBERJ AmberTreeOfLifeN
++ ~This is too dangerous even for someone as capable as you, Amber.~ EXTERN M#AMBERJ AmberTreeOfLifeK

 

All of those could use a InParty("m#amber") though you'll probably want the whole big load of checks as well:

 

See("M#Amber")
	 !StateCheck("M#Amber",STATE_SLEEPING)
	 !StateCheck("M#Amber",STATE_HELPLESS)
	 !StateCheck("M#Amber",STATE_STUNNED)
	 !StateCheck("M#Amber",STATE_SILENCED)
 InParty("m#amber")
 !Dead("m#amber")

 

Oh and something else I just noticed relating to the Tree of Life. If you follow BioWare ideas, then your romance tree of life interjection always comes before the rest of them. So in order to do that you need to EXTEND_TOP #1 instead of INTERJECTing for the Player1 romance option.

e.g.

 

EXTEND_TOP PLAYER1 33 #1
IF ~Global("M#AmberRomanceActive","GLOBAL",2)
	 Global("M#AmberMatch","GLOBAL",1)
	 See("M#Amber")
	 !StateCheck("M#Amber",STATE_SLEEPING)
	 !StateCheck("M#Amber",STATE_HELPLESS)
	 !StateCheck("M#Amber",STATE_STUNNED)
	 !StateCheck("M#Amber",STATE_SILENCED)
 InParty("m#amber")
 !Dead("m#amber")~ THEN EXTERN PLAYER1 SomeNewStateThatNeedsRenaming
END

APPEND PLAYER1

IF ~~ THEN BEGIN SomeNewStateThatNeedsRenaming
SAY ~Amber... the fiery tiefling's affection for you is both obvious and genuine. The compassion and love you have found under her abrupt demeanor have helped you survive the pain and emptiness that Irenicus has caused by stealing your soul.~
=  ~However, she is still ultimately a mystery to you, and sometimes it almost feels as if she was not quite there with you, but somewhere far away. Will the bond you have formed with her be strong enough for her to follow you to this desperate battle? ~
++ ~Amber... I - I...~ EXTERN M#AMBERJ AmberTreeOfLifeL
END

END

 

Oh and finally (a tiny, tiny thing): The BioWare romances all say ~Amber... I ---~ (as opposed to ~Amber... I - I...~). Yeah, it's quite an odd way of doing it, but oh well, it's up to you really.

[Meira]

 

This was already reported during the beta testing. I could have sworn that I added InParty and State checks for all retionship variations, but I'm seeing rather convincing evidence that I didn't. I'll try to make better job this time fixing that and implementing Grim's other suggestions...