Cam's Playthrough bugs

[CamDawg]

Oh yeah. Kids, don't mod on cold medicine.

 

// wong-fei using wrong regen icon
COPY_EXISTING ~helm34.itm~  ~override~
 READ_LONG  0x6a "fx_off" ELSE 0
 READ_SHORT 0x70 "fx_num" ELSE 0
 FOR (index = 0; index < fx_num; index = index + 1) BEGIN // searches through global effects
READ_SHORT ("%fx_off%" +		("%index%" * 0x30)) "opcode"
READ_LONG  ("%fx_off%" + 0x08 + ("%index%" * 0x30)) "icon"
PATCH_IF (("%opcode%" = 142) AND ("%icon%" = 56)) BEGIN // display regeneration icon
  WRITE_LONG  ("%fx_off%" + 0x08 + ("%index%" * 0x30)) 87 // change to regenerating
END
 END
 BUT_ONLY_IF_IT_CHANGES

[CamDawg]

...and done. Next up is tracking down some non-removed journal entries: #15760, #11686, and #11661 from entering the Asylum and #10837 from the Underdark illithid lair.

 

I also have one more from Flydian telling me to save Trademeet from animals after I already had completed all of the Trademeet tasks. He really should go away once Trademeet is saved, rather than remaining at the gates handing out quests that are already completed.

[CamDawg]

The three asylum journal entries all have EraseJournalEntry calls attached to them, which makes me suspect it's an interrupted action queue issue. As for the illithid door journal entries, if you open the door fast enough, the journal entry gets set after the door opens. Adding a check for the open door prior to setting the journal entry should suffice.

 

// prevent journal entry for already-openeed UD illithid doors
COPY_EXISTING ~uddoor2.bcs~ ~override~
		  ~uddoor3.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~Global("thrallDoorMes","AR2400",0)~  ~Global("thrallDoorMes","AR2400",0) Global("thrallDoorOpen","AR2400",0)~
REPLACE_TEXTUALLY ~Global("thrallDoorMes2","AR2400",0)~ ~Global("thrallDoorMes2","AR2400",0) Global("thrallDoorOpen2","AR2400",0)~
 COMPILE_BAF_TO_BCS
 BUT_ONLY_IF_IT_CHANGES

 

For Flydian, a quick extension to the bottom of the City Gates script should do:

 

IF
 Dead("cefald01")
 InMyArea("messen")
THEN
 RESPONSE #100
ActionOverride("messen",DestroySelf())
END