Incompatability Note

[AnnabelleRose]

As far as I can tell the ToC Part One component "Keep All Items on Import" has issues with the BG2 Fixpack.

 

<CHARNAME> does not die, and Johnny does not show up.

 

I don't know how to fix this, but I wanted to let you cats know incase someone is blaming it on your mod (I am sure it is an error on my end).

 

I am working on a new version, and it will be labeled with a warning on the mod itself.

 

*Edit* does anyone else find it ironic that post #66 from me is "My mod crashes the game when paired with your mod"?

[CamDawg]

Replace this...

 

BEGIN ~Install Keep All BG1 Items On Imported Characters by Kevin
Dorner~
COPY_EXISTING ~ar0602.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~,14))
[^A]*ActionOverride(\"DuegarClanChief\",TakeItemListPartyNum(\"IMPORT01\",1)).*
[^A]*ActionOverride(\"Shelf1\",TakeItemListPartyNum(\"IMPORT03\",1)).*
[^S]*SmallWait(4).*
[^T]*TakePartyGold(2147483647).*
[^A]*ActionOverride(Player1,DestroyAllEquipment()).*
[^A]*ActionOverride(Player2,DestroyAllEquipment()).*
[^A]*ActionOverride(Player3,DestroyAllEquipment()).*
[^A]*ActionOverride(Player4,DestroyAllEquipment()).*
[^A]*ActionOverride(Player5,DestroyAllEquipment()).*
[^A]*ActionOverride(Player6,DestroyAllEquipment()).*
[^C]*CreateCreature(\"CSJON\",\[3210\.3304\],10).*
[^A]*ActionOverride(Player1,PlayDead(165)).*
~ ~,14))
SmallWait(4)~ //~
  COMPILE_BAF_TO_BCS

COPY_EXISTING ~baldur.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~OR(8).*
.*PartyHasItem(\"sw1h15\").*
.*PartyHasItem(\"sw1h16\").*
.*PartyHasItem(\"chan06\").*
.*PartyHasItem(\"bruenaxe\").*
.*PartyHasItem(\"bruenpla\").*
.*PartyHasItem(\"cattibow\").*
.*PartyHasItem(\"regisamu\").*
.*PartyHasItem(\"aegis2\").*
~ /* ~ */  ~OR(5)
PartyHasItem("bruenaxe")
PartyHasItem("bruenpla")
PartyHasItem("cattibow")
PartyHasItem("regisamu")
PartyHasItem("aegis2")
~ // ~
 COMPILE_BAF_TO_BCS

 

with this:

 

BEGIN ~Install Keep All BG1 Items On Imported Characters by Kevin 
Dorner~

INCLUDE ~MTS1/lib/extra_regexp_vars.tpa~

COPY_EXISTING ~ar0602.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~ActionOverride(\"DuegarClanChief\",TakeItemListPartyNum(\"IMPORT01\",1))~ ~~
REPLACE_TEXTUALLY ~ActionOverride(\"Shelf1\",TakeItemListPartyNum(\"IMPORT03\",1))~ ~~
REPLACE_TEXTUALLY ~TakePartyGold([0-9]+)~ ~~
REPLACE_TEXTUALLY ~ActionOverride(Player[1-6],DestroyAllEquipment())~ ~~
 COMPILE_BAF_TO_BCS

COPY_EXISTING ~baldur.bcs~ ~override~
 DECOMPILE_BCS_TO_BAF
REPLACE_TEXTUALLY ~OR(8)[%tab% %lnl%%mnl%%wnl%]+PartyHasItem(\"sw1h15\")[%tab% %lnl%%mnl%%wnl%]+PartyHasItem(\"sw1h16\")[%tab% %lnl%%mnl%%wnl%]+PartyHasItem(\"chan06\")[%tab% %lnl%%mnl%%wnl%]+PartyHasItem(\"bruenaxe\")[%tab% %lnl%%mnl%%wnl%]+PartyHasItem(\"bruenpla\")[%tab% %lnl%%mnl%%wnl%]+PartyHasItem(\"cattibow\")[%tab% %lnl%%mnl%%wnl%]+PartyHasItem(\"regisamu\")[%tab% %lnl%%mnl%%wnl%]+PartyHasItem(\"aegis2\")~
~OR(5)
PartyHasItem("bruenaxe")
PartyHasItem("bruenpla")
PartyHasItem("cattibow")
PartyHasItem("regisamu")
PartyHasItem("aegis2")~
 COMPILE_BAF_TO_BCS

 

You'll need to grab the extra_regexp_vars.tpa library from Fixpack and/or Tweaks, but this should be a lot more reliable. I was also a bit confused as to why the creation of CSJON and PlayDead calls were being removed in ar0602.bcs, so I have not included them in the re-write.

 

I got a parse error when trying to install ToC1_v2 ([sETUP-MTSTOC1.TP2] ERROR at line 109 column 58-58 Near Text: /) so I'm going by what it appears the code is trying to do.

[CamDawg]

For the curious, this was fixed by MTS is the latest release.