cmorgan

Very cool!

OK, taking a look - (I forgot I had so many area and conditional talks; tough to untangle now. They made sense to me when I wrote them, but I think I made a mare's nest for troubleshooting. Thank goodness I wrote lots of comments in the code...).

TL/DR - LT 15 is the first one to fire after Underdark if you are doing a long completionist play and have had 14 LTs and 8 LTs. By design, more intimacy = more content, so a Romance talk won't take the place of a friend talk, it will just add on .

If you haven't headed for Spellhold yet, that would explain the hangup.

/* Aran's FriendTalks Aim, c-aranfriendbg2, %ARAN_FTT% : delays some talks to be only available after chapter 5 is over */
/* This block takes the even variables set in dialog, and advances them to the odd */
IF
	GlobalGT("c-aranfriendbg2","GLOBAL",26)
	GlobalLT("c-aranfriendbg2","GLOBAL",39)	// shuts down sequence when finished
	RealGlobalTimerExpired("c-aranfriendtimer","GLOBAL")	// Timer Expired
	GlobalGT("Chapter","GLOBAL",%bg2_chapter_5%) // Not in Underdark, and must fire post-losing-soul
	OR(6) 
		Global("c-aranfriendbg2","GLOBAL",28) // set up SoA_FT_15
		Global("c-aranfriendbg2","GLOBAL",30) // set up SoA_FT_16
		Global("c-aranfriendbg2","GLOBAL",32) // set up SoA_FT_17
		Global("c-aranfriendbg2","GLOBAL",34) // set up SoA_FT_18
		Global("c-aranfriendbg2","GLOBAL",36) // set up SoA_FT_19
		Global("c-aranfriendbg2","GLOBAL",38) // set up SoA_FT_20
THEN
	RESPONSE #100
		IncrementGlobal("c-aranfriendbg2","GLOBAL",1)	// move up from even to odd
END

I can't remember if 15 is the sparring match; I probably need to move that one to be available pre-Underdark, as it fits *my* playthrough style. I linger in the first few chapters and delay Spellhold/underdark, and the sparring talk is a nice "alpha-omega" point. It can reinforce a friendship or an adversarial relationship, turn a female PC's attentions towards or away from having a relationship, and the "morning after" three pathways of talks for female PCs makes a really strong finish to a storyline if PC is about to drop Aran W and pick up a torrid romance with another NPC.

For the "by the numbers", I have lost track of the gazillion places where ther are interjections and mini reaction talks (thank goodness folks who don't want the whole thing can tell him to stick to only major conversations), but here goes the breakdowns on what I can see right now:

ToB CONTENT:
7 Friend Talks including the initial recruiting talk.
7 Love talks including the 1st initial "have your feeling changed" talk that signals that the romance is seen as active and gives PC a chance to disengage unwanted flirts/lovetalks if she is romancing someone else (or not - he happily/grumpily multiromances).

No major conditions attached to any of these other than the obvious.

SoA CONTENT:

Friend talks 1 - 14 fire without Chapter conditions other than not being in Underdark; so FT 1 - 14 could show up all game until they are done. You could recruit him after underdark and still get the main sequence.

Underdark suspends the regular talks, and puts up to 5 Underdark-specific friend talks into play (depending on how long you hang around in that chapter and your timer choices).

Friend talks 15 - 20 fire after Underdark so that no matter how long PC hangs around town before starting the "end-game" there is content.

Romance talks fire independently of Friendtalks (though female PCs can influence Friedtalks into more girlfriendy versions by responses). There should currently be 8 of them in BG2, so it looks like you have hit the end of the specific lovetalks until I get off my tail and get writing again.  

SPECIFIC TO SPARRING:

Just a regular lovetalk - but tthe follow-on for female PCs can be skipped over if something doesn't fire right away.

Dude PCs don't have a followup as they don't have the opportunity to take the conversation in that direction, while Dudette PCs can get three potential "Morning After" talks:

/* Sparring, females ; Morning After talk : heavy making out or bedding */
/* Sparring, females ; Morning After talk : kissing or making out */
/* Sparring, females : Morning After : disable if it doesn't fire in the morning - identify by global set to 15 */

Hope this helps!

I’m not sure whether to laugh or cry that this is the first thread I see after having to drop everything for RL for a year. 

@AL|EN heh - that was silly of me - I should have thought through that more completely

Does LABEL accept .tra references?

BEGIN @1007 DESIGNATED 10 LABEL @5207
  GROUP @1006

and 

ACTION_IF (MOD_IS_INSTALLED "BG1NPC" (ID_OF_LABEL "BG1NPC" @127)) BEGIN

? Docs on adding the additional label so that

@120 = AranWCore

@121 = AranWClassChange

etc?

On 2/24/2019 at 2:03 AM, PotiusMori said:

Not sure if Inn flirts are working as intended 

Not sure, though, if they're meant to be triggered by PID in the inns. They sometimes trigger spontaneously if the timer has run to 0 (e.g. game left on pause or AdvanceRealTime used), but PID in inns will return with that conversation rather than his standard PID menu - this seems to be blocked by the timer, though, so if talked to in the inn after this talk fires, his regular PID can be accessed. His regular flirts and talks still fire in inns. Several of the options result in a inn-rest (I can investigate which ones if needed) - which is kinda cool for free rests in inns, but maybe not intentional. 

 

Checked through my notes and the code comments, and this is intended behavior (or rather, it is a limitation of using PIDs this way). The Inn Rest ones are also intended, or rather a logic loophole on my part, as I never thought of them as “free”, but they actually fire without checking for coin or taking it - and neither do the bath house flirts, etc!

I’m cool with a free stay

The more difficult thing is doing the correct rest movie. If you find any mismatched (like an Inn rest when camping outdoors) I want to fix them. I have a cool “cover all the eventualities in one codeblock by AreaType”, but decided to tailor each one to its expected triggering matching everyone else’s mod code.

16 hours ago, PotiusMori said:

When talking to him again to rejoin the party, he returns all the following lines. Just not sure if they’re all meant to fire at once:

Heh. Wow I went overboard on those. Only one of the 5 is an error - I filtered these through several CHAIN s to try to capture other NPCs commentary on him rejoining. The entire set of structures is enough to be its own mod. Dang. 

Ok, I may need to revisit this after release and simplify it some. Local copy has the one “friendly gesture” line fixed, as it is supposed to fire only if Aerie responds to him rejoining - still has initial state, two intervening fishing nets for other NPCs, and then the action state, which by the “Rule of Three” is one too many. 

For v2 after release, we can simplify this greatly and simultaneously find more of the BioWare crew to have different responses. 

16 hours ago, PotiusMori said:

Aran’s drunk talk fires twice in SoA. Should it fire 3 times

I bet the fix I made to it bypasses the third one - I will recheck and re-enable it!

15 hours ago, PotiusMori said:

 

I believe I've found the locations of the issue with Orrin's quest. The following lines of the two clerks result in a receipt without the Small Package being taken out of inventory

 

Thank you for the research! Unfortunately, each one of these states leads from the dialogue state that removes the item. So the sequence is (one example - reply on line 29708 of c-arandialog.d TakePartyItem, go to a2538 - which is the first of the three GiveItemCreate() states.).

I am tinkering a bit today, and will have the addition of the Destroy in tonight’s upload. I am hoping that fixes that.

On 2/24/2019 at 7:07 AM, PotiusMori said:

Orrin’s FedEx quest, the clerk gave a receipt but didn’t take the package. Orrin wouldn’t accept the receipt unless the package is not in the inventory, but dropping the package (while keeping the receipt in the inventory) allows the quest to be completed.

Hmmm. Traced all these down, rechecked - not sure why TakePartyItem(“c-awpkg1”) would fail. I’ll take a second pass tonight to see if there is any possible way of getting the receipt without the package being taken, but tightened this up by making sure each instance of TPI() has an immediate DestroyItem() -

++ @11229 DO ~TakePartyItem(“c-awpkg1”) DestroyItem(“c-awpkg1”)~ + a2548

(a2548 does the GiveItemCreate())

The behavior is correct, except that it was set up with the assumption that you would never have both items at the same time. 

The Rasaad/AranW mixup is verified and now fixed in my temporary working files - I’ll post it up tonight with the next update. Apparently WeiDU can’t read my mind when switching between CHAIN and APPEND

still trying to figure out what would suspend his flirt initiation script in Underdark. An early version had him skip them, as a Drow male probably would not initiate, but I thought everything was re-enabled; he uses the same flirt timer for all chapters. 

A puzzle to solve! Cool!

Congratulations on the new mod!

On 2/20/2019 at 2:19 AM, PotiusMori said:

Even if flirts are enabled in the Underdark, Aran doesn’t seem to instigate any flirts.

Hmmm - still trying to track this one down.

If you use the PID menu to flirt, they successfully use the Underdark versions, right? The report is that he doesn't initiate flirts while in underdark?

/* ToB FriendTalk 7 : Inspiration: War stories about summoning saving/ruining the day properly - eric */
/* Moonshe Axes */
IF ~Global("c-aranfriendtob","GLOBAL",13)~ THEN BEGIN a5220
	SAY @13833 /* [ARAN] Did you ever get on th’ wrong side of a summonin’? */
	++ @13834 /* [PC] A what? */ DO ~SetGlobal("c-aranfriendtob","GLOBAL",14) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5221
	++ @13835 /* [PC] I am not sure. Does picking up a chatterbox of a sellsword on the Promenade of Athlaka count? */ DO ~SetGlobal("c-aranfriendtob","GLOBAL",14) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5222
	+ ~RandomNum(5,5)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3193 /* c-aranshutup60 */
	+ ~RandomNum(5,4)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3194 /* c-aranshutup61 */
	+ ~RandomNum(5,3)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3195 /* c-aranshutup62 */
	+ ~RandomNum(5,2)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3196 /* c-aranshutup63 */
	+ ~RandomNum(5,1)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3197 /* c-aranshutup64 */		
	++ @13837 /* [PC] I do not think that I have ever had that experience. */ DO ~SetGlobal("c-aranfriendtob","GLOBAL",14) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5225
	+ ~Class(Player1,MAGE_ALL)~ + @13838 /* [PC] I can tell you from both personal experience and study, it is not something most mages live through. */ DO ~SetGlobal("c-aranfriendtob","GLOBAL",14) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5225
	+ ~!Class(Player1,MAGE_ALL)~ + @13839 /* [PC] I have heard that a miscast summoning is not something most mages live through. */ DO ~SetGlobal("c-aranfriendtob","GLOBAL",14) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5225	
	++ @13840 /* [PC] Yes, I have. */ DO ~SetGlobal("c-aranfriendtob","GLOBAL",14) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5225
	++ @13841 /* [PC] Why talk about ancient history? We are very powerful now. Why bring up the distant past? */ DO ~SetGlobal("c-aranfriendtob","GLOBAL",14) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5236
END
/* ToB FriendTalk 7 : miscast summoning : goto followup7 */

/* ToB FriendTalk 7 : miscast summoning : followup7 */
IF ~~ a5221
	SAY @13842 /* [ARAN] Summonin’. You know, bringin’ in an animal or some sort o’ magical bein’ or somethin’ what to attack your foe. */
	++ @13843 /* [PC] No, I have not been on the wrong side of a summoning. */ + a5225
	++ @13844 /* [PC] I know what it means. It just isn't something that pops up regularly in idle conversation. */ + a5223
	++ @13845 /* [PC] Summoning by wand, by ring, by scroll, or by spell? */ + a5224
	++ @13846 /* [PC] Summ-o-ning. S u m m o n i n g. G. The first syllable is emphasized, and the last 'g' is a hard plosive. */ + a5222
	+ ~Class(Player1,CLERIC_ALL) Class("c-aran",CLERIC_ALL)~ + @13847 /* [PC] We should both pray together. It will take both of our divine contacts to clean up your speech. */ + a5222
	+ ~Class(Player1,CLERIC_ALL) !Class("c-aran",CLERIC_ALL)~ + @13848 /* [PC] I will pray for you, Aran. It will take all of my divine powers to clean up your speech. */ + a5222
	+ ~!Class(Player1,CLERIC_ALL) Class("c-aran",CLERIC_ALL)~ + @13849 /* [PC] You should go pray, Aran. It will take all of your divine contact to clean up your speech. */ + a5222
	+ ~!Class(Player1,CLERIC_ALL) !Class("c-aran",CLERIC_ALL)~ + @13850 /* [PC] We need to go find a cleric, Aran. It will take someone with strong contact with the divine to clean up your speech. */ + a5222
	++ @13841 /* [PC] Why talk about ancient history? We are very powerful now. Why bring up the distant past? */ + a5236
END
 
IF ~~ a5222
	SAY @13851 /* [ARAN] That be right funny. This be me, laughin'. */
	= @13852 /* [ARAN] That whole summonin' thing be a right tricky business, an' seein' it go wrong be an experience. */
	IF ~~ THEN GOTO a5225
END

IF ~~ a5223
	SAY @13853 /* That be an interestin' idea, there. Ordinary conversation. Naught that we do be ordinary, in any sense o' th' word. */
	IF ~~ THEN GOTO a5225
END

IF ~~ a5224
	SAY @13854 /* [ARAN] As far as I be knowin', any o' those can fail. But I were talkin' about th' spell. Most times, if it goes wrong, you don't rightly survive th' experience. */
	IF ~~ THEN GOTO a5225
END
	
IF ~~ a5225	
	SAY @13855 /* [ARAN] I did once. Serving’ up in Moonshea, we had ourselves a Wand what got ahead of himself an’ tried to help by summonin’ up some support. Intelligent sort o’ mage, but he were not that wise. */
	++ @13856 /* [PC] An intelligent self-aware wand? Or more tradespeak? */ + a5226
	++ @13857 /* [PC] Was that really necessary? */ + a5228
	++ @13858 /* [PC] So you fought off the summoned creatures, saved the day, and then promptly got drunk. */ + a5227
	++ @13859 /* [PC] Did the spell not work? */ + a5231
	++ @13860 /* [PC] Dear gods, you are determined to tell this story, aren't you. */ + a5227
	++ @13841 /* [PC] Why talk about ancient history? We are very powerful now. Why bring up the distant past? */ + a5236
END

IF ~~ a5226
	SAY @13861 /* [ARAN] Tradespeak. Th' Wand was castin' a spell, not usin' a wand or staff or naught o' th' sort. */
	IF ~~ THEN GOTO a5227
END

IF ~~ a5227
	SAY @13862 /* [ARAN]	Now, am I goin' to get to tell you th' story, or is this goin' to be one o' those times where you be interruptin' all th' time? */
	++ @13863 /* [PC] It is going to be one of those times. It is worth it to see your face turn all red and twisty when you are interrupted. */ + a5229
	++ @13864 /* [PC] Oh, by all means, tell your story. I will listen intently like a good little <PROGIRLBOY>. */ + a5229
	+ ~RandomNum(5,5)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3193 /* c-aranshutup60 */
	+ ~RandomNum(5,4)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3194 /* c-aranshutup61 */
	+ ~RandomNum(5,3)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3195 /* c-aranshutup62 */
	+ ~RandomNum(5,2)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3196 /* c-aranshutup63 */
	+ ~RandomNum(5,1)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3197 /* c-aranshutup64 */	
	++ @13865 /* [PC] *I* am interrupting *you*? Who started this conversation, anyways? */ + a5241
	++ @13866 /* [PC] Did I ever tell you about the time I single-handedly fought off a few rats in a storeroom at Candlekeep? It sounds about as exciting as this story. */ + a5241
	++ @13867 /* [PC] Tell the story. I will try not to interrupt. */ + a5229
END	
	
IF ~~ a5229
	SAY @13868 /* [ARAN] Fine, then. Glad to amuse you. On any account, th' mage were tryin' to summon up some help. */
	IF ~~ THEN GOTO a5228
END
	
IF ~~ a5228
	SAY @13869 /* [ARAN] It seemed a right fine idea at th’ time. Unfortunately for us, apparently we were close to some wellmoon, or moonwell, or some sort o’ mystical waters. An’ apparently shadow magic an’ regular summoning’ spells are supposed to be kept separate. */
	++ @13870 /* [PC] Let me guess. He summoned a dragon, and its shadow showed up and ate it. */ + a5231
	++ @13871 /* [PC] I am not really interested in hearing more of this story. I call the shots, Aran. Let's move on. */ + a5241
	++ @13872 /* [PC] I have heard this story at least four times, Aran. Perhaps we could just continue on in silence? */ + a5241
	++ @13873 /* [PC] What do you know about the Moonwells in Moonshea? */ + a5230
	++ @13874 /* [PC] It sounds like you were about to get illuminated by a targeting spell. */ + a5231
END

IF ~~ a5230
	SAY @13875 /* [ARAN] Naught, or less than naught. An' apparently th' mage what were with us knew less than me, eh? We thought things were on th' path to ruin when th' blighted mage started glowin' a strange bluish color. We were sure he were about to explode. */
	IF ~~ THEN GOTO a5231
END

IF ~~ a5231
	SAY @13876 /* [ARAN] Worse than that. Something’ went wrong right proper, it did. Instead o’ summonin’ help, he brought in a pack o’ dire wolves what decided that we were th’ best looking’ source o’ a snack around. */
	++ @13877 /* [PC] You are telling me this story, so obviously you found a way to deal with the situation. */ + a5232
	++ @13878 /* [PC] How did the mage react? Poorly, I suppose. */ + a5232
	++ @13879 /* [PC] Snacks. I could eat, you know. How about less talk and we have some of these berries. They are tasty... */ + a5241
	++ @13880 /* [PC] Easy fix - summon some rabbits or any food source, and then run away while the dire wolves feast. I should have been there to fix everything. */ + a5241
	++ @13881 /* [PC] That sounds.... dangerous. */ + a5232
END

IF ~~ a5232
	SAY @13882 /* [ARAN] Aye. Th’ poor lad panicked, an’ summoned again, an’ sure enough another pack showed up right in th’ midst. We scurried up th’ trees right quick, while th’ two packs fought over which one were going’ to eat us.  */
	++ @13883 /* [PC] So now you are stuck up a tree, you have two packs competing to eat you, and you still have your original enemies. This sounds bad. */ + a5233
	++ @13884 /* [PC] They killed each other? */ + a5237
	++ @13872 /* [PC] I have heard this story at least four times, Aran. Perhaps we could just continue on in silence? */ + a5241
	++ @13885 /* [PC] What about your original enemies? I would think you would attract lots of unwanted attention. */ + a5233
	++ @13886 /* [PC] You do realize I have heard this before, right? */ + a5234
END

IF ~~ a5233
	SAY @13887 /* [ARAN] That be th' whole sum o' it, aye. It did all work out for th' best, though. Our enemies came lookin' to see what all th' noise were about. Two shakes o' a lamb's tail, an' we had front row seats to a grand scrimmage. An when it be over, we just mopped up th' few what were still alive. */
	++ @13888 /* [PC] Are all these stories you tell me truth, or just tall tales? */ + a5239
	++ @13889 /* [PC] Let me guess... then Elminster's Army showed up and you defeated them with your curry. */ + a5240
	++ @13890 /* [PC] I would rather not do any of this, Aran. */ + a5235
	++ @13891 /* [PC] I can see why you like telling stories. They are just hard to believe. */ + a5239
	++ @13892 /* [PC] I think we should visit Moonshea some day. It sounds like it was exciting. */ + a5241
END

IF ~~ a5234
	SAY @13893 /* [ARAN] What do you be thinkin' happened, then? */
	++ @13894 /* [PC] Well, if it was anything like the last time you told this, then the mage managed to summon two sets of creatures at once, they ate each other, and you all lived happily ever after. */ + a5237
	+ ~Class(Player1,MAGE_ALL)~ + @13895 /* [PC] Does it matter? You are telling tall tales anyways. Summoning spells do not interact with the wellsprings on Moonshea. */ + a5239
	+ ~!Class(Player1,MAGE_ALL)~ + @13896 /* [PC] Does it matter? You are telling tall tales anyways. You could say that Cyric Himself showed up and scared you all away. */ + a5239
	++ @13897 /* [PC] The mage polymorphed himself into the shape of a squirrel, and the dire wolves ate him. */ + a5243
	++ @13898 /* [PC] I think the real story is that you fell asleep while on guard duty and had a very vivid dream. */ + a5242
	++ @13899 /* [PC] I really don't care, because the subject of the story should be me, not you. */ + a5242
	++ @13890 /* [PC] I would rather not do any of this, Aran. */ + a5235
END

 IF ~~ a5235 
 	SAY @13900 /* [ARAN] Do any o' what, exactly? */ 
 	 ++ @13901 /* [PC] Any of this talking. You tell a story, I tell a story... it distracts us from accomplishing our goals. */ + a5241   
 	 ++ @13902 /* [PC] I don't want to tell you your story. I don't want to hear you tell it, either. */ + a5242   
 	 ++ @13903 /* [PC] Oh, fine... you had trouble with a mage summoning not one but two separate packs of dire wolves, who ate each other and the enemy. You went home victorious. */ + a5244
 	 ++ @13904 /* [PC] All of the tasks, all of the fighting, all of the running all over, all of the making decisions. Just tell me what to do and I will do it. */ + a5245
 	 ++ @13905 /* [PC] You know me... you tell me. */ + a5245
END
 
IF ~~ a5236
	SAY @13906 /* [ARAN] We may be right powerful, but there always be th' need to communicate an' share. Th' ties what bind, an' all. */
	++ @13907 /* [PC] A philosopher and a sellsword. You never fit into any one category, do you. */ + a5238
	++ @13908 /* [PC] I do not need any ties to bind me to my fellow travelers. Talking about the past is a waste of time. */ + a5241
	++ @13909 /* [PC] I see your point. Telling old stories is a way we can all connect to each other. */ + a5238
	++ @13910 /* [PC] The only "connection" I need is for you to do your job. */ + a5241
	++ @13911 /* [PC] I can see why you like telling stories. Are all of them true? */ + a5239
	+ ~RandomNum(5,5)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3193 /* c-aranshutup60 */
	+ ~RandomNum(5,4)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3194 /* c-aranshutup61 */
	+ ~RandomNum(5,3)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3195 /* c-aranshutup62 */
	+ ~RandomNum(5,2)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3196 /* c-aranshutup63 */
	+ ~RandomNum(5,1)~ + @13836 /* [PC] Not interested. Let's move on, shall we? */ + a3197 /* c-aranshutup64 */	
END
	
IF ~~ a5237
	SAY @13912 /* [ARAN] Mostly, aye. But it ended up even better, on account o’ our original opponents came over to see what all th’ fuss were about, an’ got eaten for their troubles. We ended up wi’ a nice little victory, an’ all we had to do were finish off th’ stragglers on all sides. */
	++ @13888 /* [PC] Are all these stories you tell me truth, or just tall tales? */ + a5239
	++ @13913 /* [PC] That sounds like the best possible outcome for a very bad situation. */ + a2260
	++ @13914 /* [PC] I wish that you would stop telling stories and just tell me what to do to. */ + a5245
	++ @13889 /* [PC] Let me guess... then Elminster's Army showed up and you defeated them with your curry. */ + a5240
    ++ @13890 /* [PC] I would rather not do any of this, Aran. */ + a5235
END

IF ~~ a5238
	SAY @13915 /* [ARAN] Well now, I will shorten th' story up a bit. I were up in Moonshea, an' we had a mage what summoned a pack o' dire wolves what looked at us like we be dinner. Then he paniked, an' summoned a second set o' dire wolves. */ 
	++ @13888 /* [PC] Are all these stories you tell me truth, or just tall tales? */ + a5239
	++ @13916 /* [PC] Let me guess what happened next... */ + a5234
	++ @13889 /* [PC] Let me guess... then Elminster's Army showed up and you defeated them with your curry. */ + a5240
	++ @13899 /* [PC] I really don't care, because the subject of the story should be me, not you. */ + a5242	
    ++ @13890 /* [PC] I would rather not do any of this, Aran. */ + a5235	
END

IF ~~ a5239
	SAY @13917 /* [ARAN] All th’ truth, an’ nothin’ but, on my second sister’s grave. */
	++ @13918 /* [PC] You only have one sister, Aran, and she is very much alive. */ + a5242
	++ @13919 /* [PC] You do realize it is very hard to take you seriously when you exaggerate, right? */ + a5241
	++ @13920 /* [PC] I will take your word for it. */ + a5242
	++ @13921 /* [PC] Some time I will have to tell you about my adventures cleaning the dust out of Candlekeep's Readers Room. Now *there* is a story worth telling. */ + a5242
	++ @13922 /* [PC] Riiiiiiight. */ + a5242
END

IF ~~ a5240
	SAY @13923 /* [ARAN] Bane's Blood, no... we saw naught o' Elminster. An' an army? Does Elminster have an army? Hey, if he does, where be th' nearest recruitment place? A lad's got to look out for th' future, you know. */
	IF ~~ THEN EXIT
END
	
IF ~~ a5241
	SAY @13924 /* [ARAN] You do have a point. */
	IF ~~ THEN EXIT
END

IF ~~ a5242
	SAY @13925 /* [ARAN] Well, fancy that. */
	IF ~~ THEN EXIT
END

IF ~~ a5243
	SAY @13926 /* [ARAN] Hold on a mite bit, an' let me get a pen out o' my gear so's to write that down. That sounds like a better story than th; truth, it do. */
	IF ~~ THEN EXIT
END

IF ~~ a5244
	SAY @13927 /* [ARAN] Bane's Black Heart, I needs must apologise. I must have done told that one to you a dozen times if you know it by heart. */
	IF ~~ THEN EXIT
END

IF ~~ a5245
	SAY @13928 /* [ARAN] On that point, I will say naught. Speak to you, aye, an' often. Speak in support o' you, aye, an' rarely needed. Speak about you, aye. Speak for you, now that be a whole other matter entirely. */
	IF ~~ THEN EXIT
END
/* EXISTING_AYE_STATE found in existing files a2260 for ToB */

Content test installed and up on GitHub here

(code box not callable on the first topic in this interface, so adding it in the next post).

Cleanup and edits, test installed, and up on GitHub here

/* SoA FriendTalks */
/* BG2 FriendTalk 20 c-aranfriendbg2 = 39  : Tools, Weapons, and Intention */
IF ~Global("c-aranfriendbg2","GLOBAL",39)~ THEN BEGIN a5246
  SAY @13760 /* [ARAN] You know, you be a bit more powerful than you seem to realize. */
  ++ @13761 /* [PC] I don't know. It feels like I am becoming a weapon. */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",40) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5247
  ++ @13762 /* [PC] I realize exactly how powerful a weapon I am becoming. */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",40) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5247
  ++ @13763 /* [PC] No, I am not. */  DO ~SetGlobal("c-aranfriendbg2","GLOBAL",40) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5248
  ++ @13764 /* [PC] What about you? You seem to have grown a bit since we first met in that inn room. */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",40) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5264
  ++ @13765 /* [PC] This is a bad time to have another one of your deep existential conversations. */ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",340) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",%ARAN_FTT%)~ + a5250
END
/* GOTO BG2 FriendTalk 20 c-aranfriendbg2 = 39  : Tools, Weapons, and Intention : Replies */

/* BG2 FriendTalk 20 c-aranfriendbg2 = 39  : Tools, Weapons, and Intention : Replies */
IF ~~ a5248
  SAY @13766 /* [ARAN] Not what? Not powerful, not realize? */
  ++ @13767 /* [PC] Not powerful. */ + a5251
  ++ @13768 /* [PC] I don't think I am any more or less powerful than when I started out. */ + a5251
  ++ @13769 /* [PC] I seem to have trouble realizing exactly how powerful I have become. */ + a5249
  ++ @13770 /* [PC] I don't know. I am still figuring out who I really am. */ + a5255
  ++ @13765 /* [PC] This is a bad time to have another one of your deep existential conversations. */ + a5250
END

IF ~~ a5249
  SAY @13771 /* [ARAN] Mayhap it scares you a bit. It scares me, somehow, but more on your account than on mine. */
  IF ~~ THEN GOTO a5247
END

IF ~~ a5250
  SAY @13772 /* [ARAN] Now we have been naught but good companions for a fair while now. Can a lad have a real conversation about all this? */
  ++ @13773 /* [PC] I don't like talking about all the power I have gained. It feels like I am becoming a weapon. */ + a5247
  ++ @13774 /* [PC] I do not need to talk about it. I realize exactly how powerful a weapon I am becoming. */ + a5247
  ++ @13775 /* [PC] I suppose. You know, you seem to have grown a bit since we first met in that inn room. */ + a5264
  ++ @13776 /* [PC] I did not ask for any of this, Aran. It was forced on me. Talking about it is useless. */ + a5263
  ++ @13777 /* [PC] Shut up, Aran. */ + a5259
 END 
  
IF ~~ a5251
  SAY @13778 /* [ARAN] That be th' largest load o' crap I done heard from you, ever. */
  ++ @13779 /* [PC] Look... it scares me, Aran. Even talking about it scares me. */ + a5252
  ++ @13780 /* [PC] Well, you were due some retribution for the loads you throw around. What is next, casting me as the future Ruler of Toril? */ + a5258
  ++ @13781 /* [PC] I may be gaining power, but I do not seem to have any power over my own direction. I get tossed from battle to battle on the wind. */ + a5255
  ++ @13782 /* [PC] Perhaps your head would look better if it was separated from your body. You have gone way past what I tolerate from you, sellsword. */ + a5259  
  ++ @13777 /* [PC] Shut up, Aran. */ + a5259
END

IF ~~ a5264
  SAY @13783 /* [ARAN] That be a right solid way o' changin' th' subject, but I be serious. This be about you, not me. */
  ++ @13779 /* [PC] Look... it scares me, Aran. Even talking about it scares me. */ + a5252
  ++ @13776 /* [PC] I did not ask for any of this, Aran. It was forced on me. Talking about it is useless. */ + a5263  
  ++ @13784 /* [PC] Is that what you see me as? A weapon? */ + a5247
  + ~Class(Player1,CLERIC_ALL)~ + @13785 /* [PC] I serve my deity. I am guided by my faith wherever that takes me, and whatever that makes me. */ + a5247
  + ~Class(Player1,MAGE_ALL)~ + @13786 /* [PC] I study magic. I am guided by my research wherever that takes me, and whatever that makes me.  */ + a5247
  + ~Class(Player1,FIGHTER_ALL)~ + @13787 /* [PC] I fight. I am guided by my tasks wherever they take me, and however they shape me. */ + a5247
  + ~Class(Player1,THIEF_ALL)~ + @13788 /* [PC] I do not always choose the job. Wherever the work takes me, and whatever it makes me, I am always looking for opportunity. */ + a5247  
  ++ @13789 /* [PC] Whatever happened to the good old talks, where you stumbled through silly entertaining things like curry ingredients? You are too serious. */ + a5265
END

IF ~~ a5252
  SAY @13790 /* [ARAN] There be naught to be scared about, as long as you be in charge o' yourself. Your power be a sharp weapon, for sure. */
  IF ~~ THEN GOTO a5247
END

IF ~~ a5247
  SAY @13791 /* [ARAN] Weapons be tools, and naught else. It takes a person weildin' th' sword to make th' call, an' direct th' cut or thrust. Otherwise, th' sword be a heavy decoration good for naught but trippin' over, eh? */
  ++ @13792 /* [PC] I agree. But right now, I have a feeling I am not completely in command of my destiny. Who is really directing me? */ + a5255
  ++ @13793 /* [PC] That is why all this is important. I have the power to shape things, the strength to control it, and the willingness to direct it where I choose. */ + a5253
  ++ @13794 /* [PC] That is why all this is important. I have the power to shape things, but I may not have the strength to control it. */ + a5255
  ++ @13795 /* [PC] I did not ask for any of this, Aran. It was forced on me. */ + a5263
  ++ @13796 /* [PC] I don't think I want to talk about this any more. We should move on. */ + a5259
END

IF ~~ a5253
  SAY @13797 /* [ARAN] I just hope you be th' one really callin' th' shots, an' not some blighted mage or god or some such bein' behind th' scenes. */
  ++ @13798 /* [PC] If it appears others are dictating my actions, just remember... it is not the one who strikes first who wins the battle. It is the one who strikes last. */ + a5254
  ++ @13799 /* [PC] I might simply choose to become someone else's weapon. You seem to have found it easier to follow than to lead. */ + a5255
  ++ @13800 /* [PC] The gods call the shots. They interfere, they push, and they own the board. We just have to play along. */ + a5259
  ++ @13801 /* [PC] The gods mess about on the game board. We just have to take it from them and make it serve our will. */ + a5259
  ++ @13796 /* [PC] I don't think I want to talk about this any more. We should move on. */ + a5250
END

IF ~~ a5254
  SAY @13802 /* [ARAN] I suppose you be right. Only, if th' first strike be powerful enough, sometimes it wins outright, eh? */
  ++ @13803 /* [PC] Are you questioning my ability to use my power effectively? */ + a5256
  ++ @13804 /* [PC] This is more than a simple mercenary campaign. It takes time to build power, and sometimes it takes doing what others want in order to get what I want. */ + a5259
  ++ @13799 /* [PC] I might simply choose to become someone else's weapon. You seem to have found it easier to follow than to lead. */ + a5261
  ++ @13805 /* [PC] The secret to my overbearing power is eating your curry. It will be my tool for conquest. */ + a5258
  ++ @13800 /* [PC] The gods call the shots. They interfere, they push, and they own the board. We just have to play along. */ + a5259
  ++ @13801 /* [PC] The gods mess about on the game board. We just have to take it from them and make it serve our will. */ + a5259
END

IF ~~ a5255
  SAY @13806 /* [ARAN] Tyr's Eye, I blighted well hope you are th' one directin' yourself. You, I have some understandin' about, an' I put my trust in your judgement. Most others, not so much. */
  ++ @13807 /* [PC] Then I had better learn how to wield myself effectively. */ + a5256
  ++ @13799 /* [PC] I might simply choose to become someone else's weapon. You seem to have found it easier to follow than to lead. */ + a5255
  ++ @13800 /* [PC] The gods call the shots. They interfere, they push, and they own the board. We just have to play along. */ + a5259
  ++ @13801 /* [PC] The gods mess about on the game board. We just have to take it from them and make it serve our will. */ + a5259
  ++ @13799 /* [PC] I might simply choose to become someone else's weapon. You seem to have found it easier to follow than to lead. */ + a5261
END

IF ~~ a5256
  SAY @13808 /* [ARAN] Effectively be part o' th' matter, I guess. But I were hopin' for more along th' lines o' compassionately. */
  ++ @13809 /* [PC] I think you had better define what you mean by 'compassionately'. */ + a5257
  ++ @13810 /* [PC] It takes time to build power, and sometimes it takes doing what others want in order to get what I want. In the end, though, my will is what matters. */ + a5259
  ++ @13811 /* [PC] I weigh my decisions carefully when I can. But sometimes, people get hurt no matter what I choose. */ + a5259 
  ++ @13799 /* [PC] I might simply choose to become someone else's weapon. You seem to have found it easier to follow than to lead. */ + a5261
  ++ @13812 /* [PC] Effectively, compassionately... just words. Sometimes we just have to do what is in front of us and move on. */ + a5259
END

IF ~~ a5257
  SAY @13813 /* [ARAN] Hey, now, I hold my own counsel on that. Sometimes people get killed an' things get destroyed on account o' there be no choice. */
  = @13814 /* [ARAN] It be th' needless actions what might be held off on account o' compassion. */
  ++ @13815 /* [PC] We agree on that, Aran. We would not be traveling together if we did not. */ + a5259
  ++ @13799 /* [PC] I might simply choose to become someone else's weapon. You seem to have found it easier to follow than to lead. */ + a5261
  ++ @13816 /* [PC] I find myself doing no needless actions. Everything I do is designed to build my own power and control my own destiny. */ + a5261
  ++ @13811 /* [PC] I weigh my decisions carefully when I can. But sometimes, people get hurt no matter what I choose. */ + a5259 
  ++ @13817 /* [PC] I weigh my decisions carefully when I can. But people getting hurt is their problem, not mine. */ + a5261 
  ++ @13789 /* [PC] Whatever happened to the good old talks, where you stumbled through silly entertaining things like curry ingredients? You are too serious. */ + a5265
END
	
IF ~~ a5258
  SAY @13818 /* [ARAN] Aye, now there be a thought. <CHARNAME>, th' Force o' Faerun, Ruler o' All Toril, built up by serial doses o' my famous gut-bustin' fire-breathin' curry. */
  ++ @13819 /* [PC] Me? Ruler of all that I survey? Now that is a laugh. */ + a5261
  ++ @13820 /* [PC] Me? Ruler of all I survey? Of course. I shall make you my Chief Wineskin Washer. And Chief Wineskin Emptier, as well. */ + a5260
  ++ @13821 /* [PC] I think I might be more comfortable if you were in charge. Well, more in danger of bar brawls, but at least I would not be everyone's target. */ + a5261
  ++ @13822 /* [PC] Laugh all you want, Aran, my boy. I intend to find my own path, even if it means conquering the very Planes themselves to do it. */ + a5262
  ++ @13823 /* [PC] Dear gods... the curry. Somehow, I knew that was the source of true power. I shall place you in charge of all cooking. And cleaning. */ + a5260
END

IF ~~ a5259
  SAY @13824 /* [ARAN] I suppose you be right. But there be plenty o' time ahead to talk. Mayhap we pick this up later. */
  IF ~~ THEN EXIT
END

IF ~~ a5260
  SAY @13825 /* [ARAN] Now that sounds right fine, it does. In fact, here be th' first duty entrusted me, all done already. One wineskin, empty, an' just beggin' for a dip in th' water! */
  IF ~~ THEN EXIT
END

IF ~~ a5261
  SAY @13826 /* [ARAN] Think about what you just said right careful, there. You already be a fair sight more powerful than I could hope to get. I don't mind bein' your sword, an' even bein' a tool to be used by you. */
  = @13827 /* [ARAN] Me, I can make a cut here or there, an' mayhap be useful in a limited way. You... you will influence th' whole o' blighted Toril, an' mayhap more. */
  IF ~~ THEN EXIT
END

IF ~~ a5262
  SAY @13828 /* [ARAN] An' I believe you will do just that, too. Mayhap I needs be expandin' my cookin' options. Takes a might large bit o' food to fuel Planar domination. */
  IF ~~ THEN EXIT
END

IF ~~ a5263
  SAY @13829 /* [ARAN] Don't you be worryin' naught about that. You take charge o' your destiny, forced or not, an' I will be right here to make sure things work out for th' best. */
  IF ~~ THEN EXIT
END

IF ~~ a5265
  SAY @13830 /* [ARAN] Well, I can trot out a joke or somethin', if that be th' way you really feel. */
  = @13831 /* [ARAN] Last market day, I were goin' to be buyin' an invisible sword. I took my coin an' found a smith what dealt wi' them, but... */
  = @13832 /* [ARAN] ...when I got there , I just couldn't see th' point! */
  IF ~~ THEN EXIT
END

Rechecked and expanded slightly,

test installed, and up on GitHub here

/* ToB Love Talk #2 : Aran Romance vs Anomen Romance - Perspectives and Personalities : Global("c-arantobrom","GLOBAL",3) --> Global("c-arantobrom","GLOBAL",4) */
IF ~Global("c-arantobrom","GLOBAL",3)~ THEN BEGIN a5266
  SAY  @13929 /* [ARAN] Mayhap this be a bad time, but you know me... always talkin' out o' turn. I need to ask you, though...  */
  = @13930 /* [ARAN] Any regrets? I mean, so far, you done experienced more trouble than a thousand others what walk Toril. */
  ++ @13931 /* [PC] No regrets. In the end, I will get things accomplished my way. */ DO ~SetGlobal("c-arantobrom","GLOBAL",4) RealSetGlobalTimer("c-aranromtimer","GLOBAL",%ARAN_LTT%)~ + a5267
  ++ @13932 /* [PC] What's the matter, Aran? Are you having regrets about a life of neverending adventure? */ DO ~SetGlobal("c-arantobrom","GLOBAL",4) RealSetGlobalTimer("c-aranromtimer","GLOBAL",%ARAN_LTT%)~ + a5268
  ++ @13933 /* [PC] Only one regret, Aran... I regret that I have not had enough time to start building a family with you. */ DO ~SetGlobal("c-arantobrom","GLOBAL",4) RealSetGlobalTimer("c-aranromtimer","GLOBAL",%ARAN_LTT%)~ + a5269
  ++ @13934 /* [PC] My only regret is you. I should never have brought you here. */ DO ~SetGlobal("c-arantobrom","GLOBAL",4) RealSetGlobalTimer("c-aranromtimer","GLOBAL",%ARAN_LTT%)~ + a5274
  ++ @13935 /* [PC] Well, I always wanted to be an exotic Calishite dancer.... */ DO ~SetGlobal("c-arantobrom","GLOBAL",4) RealSetGlobalTimer("c-aranromtimer","GLOBAL",%ARAN_LTT%)~ + a5275 
END
/* GOTO ToB Love Talk #2 : Perspectives and Personalities : replies */

/* ToB Love Talk #2 : Perspectives and Personalities : replies */
IF ~~ a5267
  SAY @13936 /* [ARAN] I don't rightly know whether you be jokin'. Sometimes I feel like th' current sitution be what you love to do. */
  ++ @13937 /* [PC] Joking, of course. Things never work out quite the way I plan. */ + a5278
  ++ @13938 /* [PC] Don't be silly. I am strong enough to bend Fate's pathways to my will. I have you, don't I? */ + a5285
  ++ @13939 /* [PC] Blood, conflict, strife, murder, death, the end of the world as we know it, and I feel fine. Come on, it is exciting, isn't it? */ + a5276
  ++ @13940 /* [PC] None of the above. But the Fates will not be denied. I am just glad that they included you along the way. */ + a5285
  ++ @13941 /* [PC] Hey, is this deep conversation just another way of getting me into your bedroll? */ + a5284  
END

IF ~~ a5268
  SAY @13942 /* [ARAN] Well, mayhap I do. Accomplishin' great deeds an' becomin' the most known name in this part o' th' world, right up there wi' Elmister an' Blackstaff, that seemed like a great idea at the time, eh? */
  = @13943 /* [ARAN]But we have already done all that, an' received naught but more trouble for th' pain.  Even worse, it be your name alone what gets out there, really. */
  + ~CheckStatGT(Player1,12,WIS)~ + @13944 /* [PC] You do not really want that fame for yourself, Aran. You just said it was thankless pain. Does it really hurt you that I am more famous than you? */ + a5278
  + ~CheckStatGT(Player1,15,INT)~ + @13945 /* [PC] So you feel that you are getting less fame than you deserve? Or do you feel I am getting too much credit? */ + a5278
  ++ @13946 /* [PC] Fame, fortune, infamy, power, bard's tales and songs... I would give it all up if I could start life over as an exotic Calishite dancer. */ + a5275 
  + ~Alignment(Player1,MASK_GOOD)~ +  @13947 /* [PC] What is wrong with me being famous? */ + a5271
  + ~!Alignment(Player1,MASK_GOOD)~ +  @13948 /* [PC] What is wrong with me being famous? Or infamous? */ + a5272
  ++ @13949 /* [PC] Your name is out there as much as mine. */ + a5270
  ++ @13950 /* [PC] I did not ask for this. */ + a5270
  ++ @13951 /* [PC] I deserve every bit of fame. You are useful, but secondary. */ + a5274
END

IF ~~ a5269
  SAY @13952 /* [ARAN] Chauntea's Golden Arms. A child, hearth an' home, when you keep gettin' dragged into th' worst parts o' th' god's conflicts? That be an invitation to disaster, eh? But it be a nice dream. */
  IF ~~ THEN GOTO a5270
END

IF ~~ a5270
  SAY @13953 /* [ARAN] You always come out on top, but it be a sure bet that your life will never be what folks call 'ordinary'. */
  ++ @13954 /* [PC] Does that bother you? */ + a5273
  ++ @13955 /* [PC] I like it on top. Actually, I like it on the bottom, and in several other very fun variants... */ + a5284
  ++ @13956 /* [PC] Did you want things to be very different than they are now? */ + a5273
  ++ @13957 /* [PC] I was never ordinary. You, on the other hand, are very ordinary. One of you on every streetcorner. */ + a5274
  ++ @13958 /* [PC] I never wanted to be ordinary. */ + a5267
END

IF ~~ a5271
  SAY @13959 /* [ARAN] Doin' th' right thing by others seems to be more about th' harp edge o' th' sword an' less about talkin'. That do get a bit tirin' to th' spirit, is all. */
  IF ~~ THEN GOTO a5278
END

IF ~~ a5272
  SAY @13960 /* [ARAN] I mean, I know my place, an' you call th' targets. That be th' right o' it. */
  IF ~~ THEN GOTO a5278
END

IF ~~ a5273
  SAY @13961 /* [ARAN] Sometimes. I wish that the world would remake itself, an' leave you a mite bit o' space for yourself. You know, some o' those ordinary dreams we might be makin' together. */
  IF ~Alignment(Player1,MASK_GOOD)~ THEN GOTO a5271
  IF ~!Alignment(Player1,MASK_GOOD)~ THEN GOTO a5272
END

IF ~~ a5274
  SAY @13962 /* [ARAN] Well hells, that be right cold o' you. */
  ++ @13963 /* [PC] Truth is cold. Power is cold. I am cold. I think it is about time you stop talking and warmed me up. */ + a5284
  ++ @13964 /* [PC] You never really understand when I am teasing you. Perhaps if I said it with a pouty face, like a Calishite dancer? */ + a5275
  ++ @13965 /* [PC] Try again. You can do better with your compliments. How do you feel when I am here with you? */ + a5281
  ++ @13966 /* [PC] Truth is cold. Power is cold. Reality is reality, and we can do little to change it. */ + a5282
  ++ @13967 /* [PC] I am sorry. You mean well. I am just a little on edge. */ + a5278
END

IF ~~ a5275 
  SAY @13968 /* [ARAN] Now that be a mental image I am not likely to get out o' my head any time soon! I can just see it now - I'd be a right smart protector. Only I'd want all th' dancin' to be for me, eh? */
  ++ @13969 /* [PC] Seriously. I would give it all up. I never wanted to be the sharp edge of a blade gods wield about like crazed bandits. I would rather be a Calshite dancer. It amounts to the same thing... being continually used by others for their own pleasure and profit. */ + a5279
  ++ @13970 /* [PC] And every dance would be for you. Maybe you would even dance for me. Or we could dance together... */ + a5280
  + ~CheckStatGT(Player1,15,INT)~ + @13971 /* [PC] Ahha! I have successfully distracted you from your deep and dreary introspection! I shall follow up with some sharp satire, a witticism or two, followed by an intensive bought of kissing. */ + a5276
  + ~CheckStatGT(Player1,12,WIS)~ + @13972 /* [PC] I know you had some important feelings to discuss, Aran, but I need more distraction and less thinking right now. So you have a woman with low willpower in need of a boost of self-esteem, standing right here, loosening her clothing a little... */ + a5284
  ++ @13973 /* [PC] I was teasing you. Sometimes you are really slow. */ + a5267
  ++ @13974 /* [PC] So tell me why I am worth all this trouble. */ + a5281
END

IF ~~ a5276
  SAY @13975 /* [ARAN] Hey, I be serious here! How is a man supposed to be a right good partner when... */
  ++ @13976 /* [PC] I know how you feel, Aran. You don't have to tell me all the time. */ + a5277
  ++ @13977 /* [PC] You can be a good partner by assuring me that you will always be there for me. */ + a5277
  ++ @13978 /* [PC] I thought we had settled all this long ago. Why does it bother you that you and I have different strengths? */ + a5277
  ++ @13979 /* [PC] We have one area where we will always be equal. We both love each other very, very much. */ + a5277  
  ++ @13980 /* [PC] You are still talking. You are wasting my time. */ + a5279
END

IF ~~ a5277
  SAY @13981 /* [ARAN] I... Melliki's Wild Whiskers. I think I be a bloody idiot. I didn't realize I was bein' such a fool. You be right, <CHARNAME>. An' the only measure o' accomplishment that I need, anyhow, be your comfort. */
  ++ @13941 /* [PC] Hey, is this deep conversation just another way of getting me into your bedroll? */ + a5284
  ++ @13939 /* [PC] Blood, conflict, strife, murder, death, the end of the world as we know it, and I feel fine. Come on, it is exciting, isn't it? */ + a5279
  ++ @13974 /* [PC] So tell me why I am worth all this trouble. */ + a5281
  ++ @13982 /* [PC] I agree that you are an idiot. */ + a5278
  ++ @13983 /* [PC] Well then, you had better get me a really nice set of boots. That would make me more comfortable. */ + a5283
END

IF ~~ a5278
  SAY @13984 /* [ARAN] Look... mayhap my words be all wrong for what I be tryin' to say. I want naught more fame, naught more fortune, as long as I can be wi' you. But... */
  ++ @13985 /* [PC] You don't have to talk to comfort me. You could take action. */ + a5284
  ++ @13986 /* [PC] But. There is always a "but" with you. I thought you were completely mine. */ + a5285
  ++ @13987 /* [PC] Your words were wrong, and you are making it worse. */ + a5279
  ++ @13988 /* [PC] Your words are fine. Your actions are fine. Me, I am not fine. */ + a5285
  ++ @13989 /* [PC] Dreary, boring, talk talk talk. We need to find something to kill, and quickly. */ + a5284
END

IF ~~ a5279
  SAY @13990 /* [ARAN] Aye, now, that be me. Always tryin' to cheer you up a mite bit, an' failin'. */
  ++ @13991 /* [PC] You succeeded. At least you distracted me for a little while, and I could pretend things were normal. */ + a5280
  ++ @13992 /* [PC] You are right. Next time, you could try telling me a story, or acting out part of a play, or something. */ + a5280
  ++ @13993 /* [PC] Next time you want to distract me, you could try something more physical... */ + a5284
  ++ @13994 /* [PC] I am not sure the distraction worked, but I appreciate you trying. */ + a5285
  ++ @13995 /* [PC] There are some situations where nothing you can do can provide comfort. */ + a5285
END

IF ~~ a5280
  SAY @13996 /* [ARAN]  Well, now, if we be play actin', the least I can do is play along, eh? I done heard o' plays where clothin' be optional, too. Mayhap that would be th' right kind o' distraction to cheer you up. */
  IF ~~ THEN EXIT
END

IF ~~ a5281
  SAY @13997 /* [ARAN] Now, you be a sight for sore eyes, an' just bein' by your side makes me feel like I be ten feet tall. */
  ++ @13998 /* [PC] So I damage your eyesight and make you puffed up to the size of a giant. Great. I suppose I also make you gassy? */ + a5279
  ++ @13999 /* [PC] I think you are trying to compliment me... but it is missing the mark. */ + a5278
  ++ @14000 /* [PC] I could compliment you as well, but it is silly. We have more important things to be focused on. */ + a5279
  ++ @14001 /* [PC] And you make me feel practically invinceable, supported, and loved. */ + a5284
  ++ @14002 /* [PC] I know. I have that effect on people. */ + a5285
END

IF ~~ a5282
  SAY @14003 /* [ARAN] I believe some o' that, but not all. */
  IF ~~ THEN GOTO a5285
END

IF ~~ a5283
  SAY @14004 /* [ARAN] One decent pair o' boots? That could be done. I will keep a sharp eye out, eh? */
  IF ~~ THEN EXIT
END

IF ~~ a5284
  SAY @14005 /* [ARAN] Can we skip right to th' part where you tackle me an' start th' kissin'? When you talk like that to me, it gets me right excited, it does! */
  IF ~~ THEN EXIT
END

IF ~~ a5285
  SAY @14006 /* [ARAN] I done signed a contract wi' you in my heart a while back, <CHARNAME>. Good times an' bad times, I be your shield. Small comfort, but comfort to you, I hope. */
  IF ~~ THEN EXIT
END

Repaired .tp2 mismatch item creation with giveitemcreate() and cleaned up string assignment for .tp2 GROUP clarity

Cool - glad you find him amusing!!

There is no specific unique BIG quest in-game right now - the "hook" for any future series of quests is Teldara (Mercenary Recruiter in The Broken Sword, area C-AR01). I wrote up a bunch of ideas on the forum, but right now the actual big quest is still a bunch of mismatched partially coded ideas. There are "mini-encounters" scripted in, and multiple talks for bit-players (pun intended) but I am coming back to the quest.

There is a sort-of-joking quest, for fun - it is an homage to Darious and Miera's Amber mod (which I love as a male PC romancing her), and follows a similar pattern. To get it, you have to talk to Orrin (the bartender) a number of times. He gives you a FedEx quest to take tax papers to the Government District, where you go through the standard "Burocratic Shuffle" - I had fun writing it, and find it amusing, but it is definitely not an original idea!

Details on getting it:

Talk to Orrin in The Broken Sword (have a reputation of higher than 6 or the "quest" is blocked). In Orrin's main ~True()~ state, if you talk to him 6 times with Aran in the party, he will break down and offer the quest. It may be possible to loop through his initial dialogue 6 times to get the correct line to play, but I haven't tried it for years and years.

The conversation snippet where you know you have the quest set up (it sets the variable) is

Quote

~[C-AW01TK] Ah, <CHARNAME>... well met. Aran, given our longstanding friendship and good relations...~
~[ARAN] Cut the bullshit an' stop lyin' through your nose, you soddy ol' bastard. What do you be wantin'?~
~[C-AW01TK] As gracefully eloquent as ever, I see. Actually, I would say this is so meager a request that only you need to be present, but perhaps your adventuring party might enjoy a small walk in the fresh air.~

The last reply on that is

Quote

~[PC] What is in the package?~

Follow that, and you should be off and running.

The reward is minimal

Hmm. Have to revisit it. Originally it was an "Easter Egg" rewarding folks for doing the "keep talking to all the bit players several times to see the different responses", since that is not usually a large part of the i.e. gaming experience The "reward' component mostly was having banters between Orrin and Aran to flesh out the "backstory relationship". 

Edit: Thanks for the bug report on Gaelen Bayle - I will take a look and see what might be going wrong - I think Aran has an interjection there, and perhaps it was blocking something!

Cool, I am on it - still catching up with your first PM, PotiusMori, but I think I got everything there - moving on to the next and to amellg and your posts here I like getting stuff done!

(after dinner.)

Edit: Hah - logged to post this so you see what has been done:

PotiusMori Report - SoA LT5

PM Report - replies incorrectly linked, reversed for Chapter checks and possible loops. Rebuilt LT and as a bonus added more reactions  and pathing to bring in more mod-added male NPC romance potential partners (side reaction with PC being either coy or honest about other RA=2)

PM PotiusMori Story Mismatch in PiD

Story mismatch in PID swapping carbonara for calimport and vice versa

PotiusMori Typo Reports in .tra

Via PM - Large number of typos repaired in c-aranw.tra and one tra string made unmatched by extra space repaired.

On that last one, did you kill Bodhi? 

(Those two lines would probably be better matched switched though, anyways)

Very cool - thank you! I will run this list down and get fixes up within a few days. Some quick surface responses:

9 hours ago, amellg said:

discover new interesting things!

Awesome - that makes my day, as one of the points of doing all the random number and PC specific stuff was to make an NPC that was familiar, but could throw a curve ball and make things interesting after several playthroughs!

The ToB 2 and 4 are mostly intact, just have to play about with them a little to get them into line with the new ones. They are progressing - I am setting myself a 30 minute "every night write a little" goal and it seems to be working (though sometimes as with any writing it ends up being stuff for a scrapheap )

Those are definitely typos - I'll hunt 'em down.

Awesome confirmation on the apology thing - working as intended - IF the PC can continue to do the "just friends" from within the dialog (and also can change her mind, etc.)

Awesome confirmation that you can roll through a game and keep things at the level you want; I was worried it was too easy to slip into content folks might not want.

On the 2EE/EET split, heh - I should have realized that - it is definitely stuff I need to screen on the EET side to fire in SoA|ToB. I need to check Spellhold, and I need to check to make sure everything in the SoA file on EET is screened from playing once ToB starts, so that the ToB variants of the same PID and talks fire appropriately.

Yes, there should have been a gift received - I'll check the code and make sure that the darned thing is not misnamed!!

Thank you very much, especially the EE | EET comparison. It very quickly identifies what to fix and how.

Hey there, folks! Any possibility of the highlighting code display using Argent77’s WeiDU .baf .tp2 .d highlighting?

(not that important in the grand scheme of things, but if we have all those programming languages already there, so I thought I’d ask)

OK, should be a solid roster. Please drop any new stuff folks find on this thread, and I will update it. Happy modding - Cheers!

Still have a bunch to do - I may have to reformat all this so it isn’t as cumbersome to navigate (and is quicker to search)!

Jastey's Solaufein added - thanks!