FriendTalk 4: Pen vs Sword, Might vs [WwRr]ri[gh]t[e]

[cmorgan]

Giving Equal Time: PC can take over the conversation.

 

I have a simple premise. Aran is developing a relationship, and giving Player1 some background. One character point is the sword vs pen debate. Obviously, Aran has grown up doing both - fighting, and writing. So which is the backbone of his character, force of arms or force of literacy?

On a second level, when the NPC has all the punchlines and all the answers, the player is forced into a passive role. One of the reasons I dislike cutscene-driven plotpoints is that they often strangle PC choice in significant ways. So let's try a friendtalk that argues sword vs. pen, but allows the PC to get ahead of the curve if the player wants to. In some situations, this would be rolls for wisdom, intellegence, etc.; here it is basically player choice that drives options.

 

 

Draft #1, on the rebuild - drafts before this one were just completely garbage and needed to be datamined for useful ideas and then dumped.

 

working file: FT4_PenSword.d

/* BG2 FriendTalk 4 c-aranfriendbg2 = 7 */
/* "Irresistable Forces and Immovable Objects", or, is the pen really mightier than the sword, or does he just have a better PR firm?  */

IF ~Global("c-aranfriendbg2","GLOBAL",7)~ THEN BEGIN c-aranft4
 SAY ~[ARAN] Hey, <CHARNAME>, how about a few extra coins on some right fine parchament next time we see someplace to get a mite o' supplies?~ 
 ++ ~[PC] That depends. What is in it for me?~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",8) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranft4.1
 ++ ~[PC] You already spend way too much time scribbling and muttering with a pen in your mouth when you should be resting, Aran.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",8) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranft4.2
 ++ ~[PC] Why do you waste your time puttering on that parchament every night, instead of working on your weapons skills?~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",8) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranft4.3
 ++ ~[PC] Absolutely. Do you mind me asking what you want it for?~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",8) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranft4.4
 ++ ~[PC] No. And stop talking to me.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",8) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranshutup17
 ++ ~[PC] No. And stop talking to me.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",8) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranshutup18
 ++ ~[PC] No. And stop talking to me.~ DO ~SetGlobal("c-aranfriendbg2","GLOBAL",8) RealSetGlobalTimer("c-aranfriendtimer","GLOBAL",ARAN_FTT)~ + c-aranshutup19
END

IF ~~ c-aranft4.1
 SAY ~[ARAN] How about th' nice warm feelin' you get when you support an' identify wi' th' people what's watchin' your back?~
 ++ ~[PC] When you put it that way, sure. But I would appreciate knowing what it is for.~ + c-aranft4.c
 ++ ~[PC] You must be mistaking me for someone who cares. If you want something, prove it is necessary.~ + c-aranft4.1a
 ++ ~[PC] Nice try. No.~ +  c-aranft4.1a
 ++ ~[PC] We need to conserve our coin. Is this something you really need, or is it something you want?~ +  c-aranft4.1a
END

IF ~~ c-aranft4.1a
 SAY ~[ARAN] Hey, now, I don't go askin' for naught I don't rightly need. Come on, <CHARNAME>, it won't be more than 200gp or so.~
 ++ ~[PC] For 200gp, I expect to know exactly what you expect to do with the purchase.~ + c-aranft4.4
 ++ ~[PC] I will give you 10gp and you can go chew your own twigs and make your own paper.~ + c-aranft4.1c
 + ~OR(2) Class(Player1,MAGE_ALL)  Class(Player1,CLERIC_ALL)~ + ~[PC] That is a good deal of money for paper. My scroll vellum costs about that.~ + c-aranft4.1b 
 + ~!Class(Player1,MAGE_ALL) !Class(Player1,CLERIC_ALL)~ + ~[PC] What kind of paper costs so much coin?~ + c-aranft4.1c
END

IF ~~ c-aranft4.1b
 SAY ~[ARAN] Exactly. I have enough trouble concentratin' on buildin' scrolls an' preparin' em for spells while we be on th' trail. In fact, I'm just about th' only one I know what can do it in the first place. So, about that purchase...  ~
 ++ ~[PC] I think we should invest in better equipment instead. A few words on some parchament will have little long term effect.~ + c-aranft4.2
 ++ ~[PC] Scribing scrolls is useful, but not necessary. I think we need to save our coin.~ + c-aranft4.npc
 ++ ~[PC] Convince me it is worth it, Aran.~ + c-aranft4.npc
 ++ ~[PC] I understand. I will provide you the supplies as soon as I am able.~ + c-aranft4.2
 ++ ~[PC] I guess I know where you fall on the 'pen versus sword' debate, then.~ + c-aranft4.pcfinish
END

IF ~~ c-aranft4.1c
 SAY ~[ARAN] Well, you might not know this, but all that scroll preparation, it takes strong materials an' strong concentration. In fact, I'm just about th' only one I know what can do it while travellin' in the first place. So, about that purchase...  ~
 ++ ~[PC] I think we should invest in better equipment instead. A few words on some parchament will have little long term effect.~ + c-aranft4.2
 ++ ~[PC] Scribing scrolls is useful, but not necessary. I think we need to save our coin.~ + c-aranft4.npc
 ++ ~[PC] Convince me it is worth it, Aran.~ + c-aranft4.npc
 ++ ~[PC] I understand. I will provide you the supplies as soon as I am able.~ + c-aranft4.2
 ++ ~[PC] I guess I know where you fall on the 'pen versus sword' debate, then.~ + c-aranft4.pcfinish
END

IF ~~ c-aranft4.2
 SAY ~[ARAN] Just doin' my part, is all. Th' pen's a bit stronger than th' sword, an' I am makin' sure you have that power available to you, eh?~
 ++ ~[PC] So you believe the pen is mightier than the sword?~ + c-aranft4.prep
 ++ ~[PC] Hey, that is a silly notion.~ + c-aranft4.prep
 ++ ~[PC] I did not expect philosophy debates from a sellsword, but go on...~ +  c-aranft4.prep
 ++ ~[PC] I will get you those materials. But I am tired of talking right now. It is time to move on.~ EXIT
 ++ ~[PC] Swords, pens, magic, might... I know my own choices on their relative power.~ + c-aranft4.pcfinish
END

IF ~~ c-aranft4.3
 SAY ~[ARAN] Well, if you must know, I be scribin' a scroll. That takes a fair amount o' work. I can practice spar an' keep myself limber on th' rail, but I can't rightly work on scribin' while walkin', eh?~
 ++ ~[PC] That seems like a waste of time to me.~ + c-aranft4.2
 ++ ~[PC] Can you actually do that while we travel?~ + c-aranft4.1c
END

IF ~~ c-aranft4.prep
 SAY ~[ARAN] See, this little feather I'm usin' here can do some pretty powerful things.~
 ++ ~[PC] Ah, trail talk about philosophy. The 'might versus write' debate. I think I would rather be boiled in oil or served raw to a pack of gibberlings.~ + c-aranft4.gib
 ++ ~[PC] You are smarter than you appear, Aran.~ + c-aranft4.npc
 ++ ~[PC] A feather. A sharpened feather, dipped in ink. Are you joking?~ + c-aranft4.npc
 + ~OR(3) !InParty("Korgan") !InMyArea("Korgan") StateCheck("Korgan",CD_STATE_NOTVALID)~ + ~[PC] (Lean forward and cut Aran's quill in half.) ~ + c-aranft4.cut
 + ~InParty("Korgan") InMyArea("Korgan") !StateCheck("Korgan",CD_STATE_NOTVALID)~ THEN EXTERN c-aranft4.korgan
END

CHAIN ~KORGANJ~ c-aranft4.korgan
~[KORGAN] *whack*~
== ~AERIEJ~ IF ~InParty("Aerie") InMyArea("Aerie") !StateCheck("Aerie",CD_STATE_NOTVALID)~ THEN ~[AERIE] That was not very nice, Korgan. You cut his quill in half!~ 
END
++ ~[PC] Good one, Korgan. Ah, trail talk about philosophy. The 'might versus write' debate. I think I would rather be boiled in oil or served raw to a pack of gibberlings.~ EXTERN ~C-ARANJ~ c-aranft4.gib
++ ~[PC] A feather. A sharpened feather, dipped in ink. Versus weapons. I think Korgan just answered you, Aran.~ EXTERN ~C-ARANJ~ c-aranft4.cut
++ ~[PC] Cut straight to the point, didn't he?~ EXTERN ~C-ARANJ~ c-aranft4.cut

IF ~~ c-aranft4.cut
 SAY ~[ARAN] Aye, that's real funny, that is. A perfectly good quill ruined. You could have just said you didn't agree.~
 ++ ~[PC] Philosophy is not my strong point. I would rather save this for a deep discussion in an inn.~ + c-aranft4.gib
 ++ ~[PC] Actually, that was funny, but I think I get your point. You are talking about power.~ + c-aranft4.npc
 ++ ~[PC] Look, I do not want to talk about this any more.~ + c-aranft4.gib
 ++ ~[PC] I thought the point was made well. Actions speak louder than words.~ + c-aranft4.npc 
 ++ ~[PC] I would debate philosophy with you, but I am afraid I would be taking advantage of your feebleness of intellect.~ + c-aranft4.npc  
END

CHAIN ~C-ARANJ~ c-aranft4.npc

~[ARAN] I guess th' central question boils down to th' basics - which be mightier, th' pen or th' sword?~

== ~EDWINJ~ IF ~InParty("Edwin") InMyArea("Edwin") !StateCheck("Edwin",CD_STATE_NOTVALID)~ THEN ~[EDWIN] Bah. It is not the tool. It is how one uses it. (Imbeciles. Let them prattle on about swords. My superior intellect shall shatter them in a heartbeat.) ~

== ~HAERDAJ~ IF ~InParty("HaerDalis") InMyArea("HaerDalis") !StateCheck("HaerDalis",CD_STATE_NOTVALID)~ THEN ~[HAERDALIS]  A fine feather from a wise sparrow, my friend. Penned works last for centuries after the creatures who wrote them have turned to dust, for they immortalize the stories that we pass on. But I do not think I would place them in a duel together to decide the result.~

== ~JAHEIRAJ~ IF ~InParty("Jaheira") InMyArea("Jaheira") !StateCheck("Jaheira",CD_STATE_NOTVALID)~ THEN ~[JAHEIRA]  Unless you are talking of the destruction of the forests for paper and the harvesting of sheepskin to produce vellum, I do not see how the pen can be mightier than the sword. Nature needs no written word to show her power.~

== ~KELDORJ~ IF ~InParty("Keldorn") InMyArea("Keldorn") !StateCheck("Keldorn",CD_STATE_NOTVALID)~ THEN ~[KELDORN]  I think that I disagree with both points. Niether pen nor sword can sway a determined heart. Faith is stronger than both.~

== ~KORGANJ~ IF ~InParty("Korgan") InMyArea("Korgan") !StateCheck("Korgan",CD_STATE_NOTVALID)~ THEN ~[KORGAN] I'll take me axe, an' you take yer pansy little feather, an' I bet you your purse I'd beat th' crap outta ye.~

== ~MINSCJ~ IF ~InParty("Minsc") InMyArea("Minsc") !StateCheck("Minsc",CD_STATE_NOTVALID)~ THEN ~[MINSC] Swords, not words, Boo! That is my motto.~

== ~NALIAJ~ IF ~InParty("Nalia") InMyArea("Nalia") !StateCheck("Nalia",CD_STATE_NOTVALID) OR(3) !InParty("Aerie") !InMyArea("Aerie") StateCheck("Aerie",CD_STATE_NOTVALID)~ THEN ~[NALIA] I might scribe a scroll of lightning, and do the damage of a hundred swords. But I am not sure it is really the pen that does it.~
== ~AERIEJ~ IF ~InParty("Aerie") InMyArea("Aerie") !StateCheck("Aerie",CD_STATE_NOTVALID) OR(3) !InParty("Nalia") !InMyArea("Nalia") StateCheck("Nalia",CD_STATE_NOTVALID)~ THEN ~[AERIE] I... I might scribe a scroll of lightning, and do the damage of many swords. But I am not sure it is really the pen that does it.~

END

IF ~~ THEN EXTERN ~C-ARANJ~ c-aranft4.5

IF ~~ c-aranft4.5
 SAY ~[ARAN] I guess I can see th' 'might is all' argument. Short term, sword takes pen. You don't see me grubbin' about for quill an' parchament right afore combat, now, do you? But I don't rightly agree long term.~
 ++ ~[PC] If you have a good bunch of swords or any weapon, weilded well, you can take what you want by force. Set yoursef up a stronghold, raid, do what you want. So sword takes pen, and the game is finished.~ + c-aranft4.6
 ++ ~[PC] Just for the sake of argument, pretend I have the most powerful charm spell written down, and I speak it... and it fails. That would seem to me to indicate that a sharp blade would win the day.~  + c-aranft4.6
 ++ ~[PC] I have my own beliefs on this.~ + c-aranft4.pcfinish
 ++ ~[PC] My head hurts.~ + c-aranft4.gib
END

IF ~~ c-aranft4.6
 SAY ~[ARAN] Really, now. That sounds right simple. I'm no sage, but tell me this... why do we end up takin' orders an' rules from folks what's less powerful than we are?~
 ++ ~[PC] They have more swords. They can call on more forces.~ + c-aranft4.7
 ++ ~[PC] I think I know where you are heading. You are about to say that the trade contract is the basis of civilization, aren't you.~ + c-aranft4.8
 ++ ~[PC] I do not think about such things. And I try not to pay much attention to rules, orders, and governments that fall outside of what I think is right.~ + c-aranft4.8
 ++ ~[PC] I do not.~  + c-aranft4.8
 ++ ~[PC] They have governments, laws... oh. OK, point taken. Written laws.~ + c-aranft4.8
END

IF ~~ c-aranft4.7
 SAY ~[ARAN] An' how do they do that?~
 ++ ~[PC] They have governments, laws... oh. OK, point taken. Written laws.~ + c-aranft4.8
 ++ ~[PC] They do not. Look, I get the whole civilization and magic and transfer of power thing. But I take what I want, when I want, and from whom I want. No piece of paper, scribed spell, or silly rule is going to stop me.~ + c-aranft4.finish
 ++ ~[PC] You are looking at the debate too narrowly, Aran. The words on the paper are not what provides the power.~ + c-aranft4.pcfinish
END

IF ~~ c-aranft4.8
 SAY ~[ARAN] You have to hold what you take, <PRO_GIRLBOY>, an' you can't be everywhere. So to do that you have laws, contracts, bounty notices, accounts receivable... Gond's Bladder, th' whole communicatin' long distance thing what sticks whole countries an' civilizations together, let's 'em trade. All paper, an silly little quills dipped in ink.~
 ++ ~[PC] None of that fancy writing makes any difference if you don't back it up with force.~ + c-aranft4.finish
 ++ ~[PC] Point conceded. I would mention that all it takes to set civilization back a thousand years is one warrior with a torch, but I think the words would be lost on you. If I grabbed this weapon and put it at your throat, though, you might agree with me.~ + c-aranft4.finish
 ++ ~[PC] You have not convinced me. Nothing can resist force of arms. Even beliefs can be changed, or the believers destroyed.~ + c-aranft4.finish
 ++ ~[PC] Too much thoughtful conversation for me. I prefer to philosophize while drunk.~ + c-aranft4.drunk
 ++ ~[PC] Well, I have my own beliefs.~ + c-aranft4.pcfinish
END

IF ~~ c-aranft4.gib
 SAY ~[ARAN] Sorry, point taken. I get a bit deep on th' trail. It be all that readin' an' tryin' to expand my mind.~
 ++ ~[PC] Well, I am not one to stop someone from expanding their mind. I have my own beliefs.~ + c-aranft4.pcfinish
 ++ ~[PC] Too much thoughtful conversation for me. I prefer to philosophize while drunk.~ + c-aranft4.drunk
 ++ ~[PC] How about less of the expanding of your mind, and more of the expanding of our purse. Time to move on.~ EXIT
 ++ ~[PC] How can you possibly expand anything inside of that thick skull of yours? I would think it would squeeze out of those flapping ears you use to shade the sides of your head.~ EXIT
END

IF ~~ c-aranft4.drunk
 SAY ~[ARAN] Aye, now that be a right fine idea. tell you what, you but me those supplies, an' I'll buy th' first two rounds, next inn we get to.~
 IF ~~ THEN EXIT
END

IF ~~ c-aranft4.finish
 SAY ~[ARAN] I say the pen's a force greater than a million swords. One bounty notice in Candlekeep, an' you change the entire Sword Coast politics, social order, an' ends up settlin' a battle most of my friends didn't walk away from whole. Which is a damned fine thing, 'cause we wasn't expectin' any of us to survive.~
 IF ~~ THEN EXIT
END

IF ~~ c-aranft4.pcfinish
 SAY ~[ARAN] Well, now, I know my own mind, but I be right interested in what you think.~
 + ~[PC] I say the pen is a force greater than a million swords. One bounty notice in Candlekeep, and I end up changing the entire Sword Coast.~ EXIT
 + ~[PC] I say the sword is a force greater than a million pens. One bounty notice in Candlekeep just triggered off the inevitable. I would have ended up changing the entire Sword Coast even without Sarevok and all of his machinations.~ EXIT
 + ~[PC] I say the sword rules all. Try taking on a hord of orcs with an inkbottle, and see what happens. I prefer something blunt to bash heads, or something sharp to remove them completely.~ EXIT
 + ~[PC] I say the question is silly. It is not force that wins the day, and it is not power from writing or communication. It is planning, preparation, and education on how to apply what power you have, and having the force of arms to back it up.~ EXIT
 + ~[PC] I say the question is too tightly focused. It is the faith behind the sword, and the faith behind the words, written or spoken, that provides the true power.~ EXIT
 + ~[PC] I say that questions like these are best left to the sages, and that the best we can do is hope they come up with an answer we can live with.~ EXIT
END

 

 

Playing with this concept showed me the real headache/puzzle of creating immersive game dialog that *isn't* narrowed down by alignment choice, class choice, etc. The problem is, how do you really allow the RL player to feel like they have not been railroaded, and cover enough roleplaying options? This is actually a massively cut version. I started to wind my way through trying to get more options opened up - and figured out that in the case of game design, too many open choices lead to long and confusing dialogs. Worse, they are counter-productive. This point is brought up in JCompton's musings, and Gaider's stuff, as well as a number of other different sources (Darious and Miera point to a cool study on creating interactive characters in video games that I now use as a resource - check their readme for further info). But I had to try it out for myself, and re-invent the wheel, so to speak.

[Ardanis]

The problem is, how do you really allow the RL player to feel like they have not been railroaded, and cover enough roleplaying options?

Don't. Either simply don't or go linear-in-disguise, that's how I see it. Frankly, were I to choose from two, I think I'd take the latter, even if it speaks bad of me as a designer.

 

Still, I believe there's a reason to - the way IE's dialog system works. Having too many options presented (more than 5-6) takes a little while to read them all before responding, and sometimes it feels weird. Who remembers Kotor2 and a talk with Atris, when she speaks her line (voiced, mind you!) then suddenly abrupts, looking like PC is gonna to interrupt her, while in reality still reading all those options, trying to figure out which one would be the most insulting? Immersion breaks and shatters like a bottle falling from 100 feet high onto a rocky spot.

 

Hm, in fact there've been a similar case not long ago, about the suggested length of PC's replies http://forums.pocketplane.net/index.php/topic,26348.0.html

[cmorgan]

Yep - I agree. I think the engine design is just not set up for this kind of free-form "net" of dialog options.

 

I think my advice for folks working on more traditional NPCs (instead of code concept dudes like Aran), and in any work I do on other things, is disguised linear. I think I agree with Gaider and JCompton (thanks for the links - can't look 'em, up as I am blocked from PPG and such at work) with as many options as can be brought into the discussion (up to that magic "5" mark). I started that way, and except for PIDs, have kept to it. This month-or-two-long experiment to challenge that idea really kicked the whole idea over hard.

 

By diguised linear, the concept is either homogenous

 

a -> {1,2,3} -> b  {1,2,3} -> c (branching and returning to chokepoints)

or divergent

a {1}  -> b {1}
			  {2}
  {2}  -> c {1}
			  {2}
  {3}  -> d {1}
			  {2}

or some combination of the above, with decision points keeping things simple.

 

While I am at it, a test review in-game shows some points to reconsider ofn the action dialogs :

 

(You do this action) = cumbersome prose that slows down the pace and feels distancing.

 

(action.) = moves things along.

 

Another tried and true concept that proves itself to be valid

 

Third concept that goes along with this "things we have been told that I am re-proving to myself through experimentation" - Less Is More . I like giving the player lots of options, but that good old "if you *force* me to click 15 times to have the conversation, I might as well be playing Supreme Commander" is holding true. So far, i can get the player out in one click if they don't want to talk, in two to three if they do - some 4. And for people who want to explore more deeply, more if they choose options that point towards opening up the conversation. But if anyone reading this stuff thinks these are typical Friend/Lovetalks, grab a mod and look. These are relatively heavyhanded.

 

I think I am going to include a PID variable for people who want him to be a bit more silent. I think blocking some of the unsolicited commentary and area talks, the quick comments when a vampire gets killed, etc. leaving him more in line with Bioware would be a good thing for players who want less talk and more action.

[Aeryn]

I agree that providing too many options can create more of a mess than anything else (learning that more every day). As a player, I don't mind once in a while feeling like I'm settling for the best response when I don't see a perfect response for my PC, because frankly there's no realistic way to provide for every single player's individual needs. Disguised linear is really not as "linear" as it seems if you take tone into context - a single line before the next set of options can change the entire feel of the rest of the dialog even though the words are the same.

 

Since you mentioned checks, I might as well throw out something I was thinking of recently. I can't think of a single instance in any mod when being too smart or too perceptive was a bad thing, but it really could be in a more realistic sense. I love the idea of a PC with a very high INT/WIS (for example, I'm sure it could work for other stats in other situations as well) who is constantly one-upping/out-reasoning the NPC's thoughts until the NPC just drops the conversation completely. Aran seems pretty even-tempered and not the type to get flustered (Sarevok makes a much better candidate for this kind of thing ) but still, it would be interesting to me to have a high stat be a bad thing instead of always a bonus.

 

By the way, thank you for laying Aran out the way you have. I come here daily to double check or just browse through your coding to see if I'm on the right track, and you've really opened up a great gift for baby-modders like me.

[cmorgan]

Cool stuff - really glad it is useful - and good idea! But that reminds me. I had better go through and get the next round of drafts up, so that little tiny oversights like forgetting to set timers in 80% of the posted friend talks doesn't send people off on the wrong tangent.