It never ends

[devSin]

XP bonus should have a timing mode of 1 and not 9, else the effect is attached to the creature, leaving the actual XP stat unchanged. Probably makes it possible to bork XP checks. SPIN607, SPIN640, and SPIN751.

 

Talons has a timing mode of 2 (!) for the icon effect. Doesn't make much difference (the icon is automatically applied with the blindness), but still. Should be 9. SPIN613.

 

AR4500.bcs tries to set LOCALS ActiveKeldorn. Excepting that this is completely pointless (it's only for SoA if you go to the sewers before getting the quest), ActionOverride() may work (if not, I'd just move it to Keldorn's 25 script).

 

BSHOP02, GARLENA, SAHPR1, and SUELF10 will all try to sell you a single throwing axe. Thanks a bunch. They should sell quantity 5.

[CamDawg]

XP bonus should have a timing mode of 1 and not 9, else the effect is attached to the creature, leaving the actual XP stat unchanged. Probably makes it possible to bork XP checks. SPIN607, SPIN640, and SPIN751.

 

spin751 already uses timing mode 1.

 

// xp effect not being applied with correct timing
COPY_EXISTING ~spin607.spl~ ~override~
             ~spin640.spl~ ~override~
 READ_LONG  0x64 "abil_off"
 READ_SHORT 0x68 "abil_num"
 READ_LONG  0x6a "fx_off"
 FOR (index = 0; index < abil_num; index = index + 1) BEGIN
   READ_SHORT ("%abil_off%" + 0x1e + (0x28 * "%index%")) "abil_fx_num"
   READ_SHORT ("%abil_off%" + 0x20 + (0x28 * "%index%")) "abil_fx_idx"
   FOR (index2 = 0; index2 < abil_fx_num; index2 = index2 + 1) BEGIN
     READ_SHORT ("%fx_off%" +        (("%abil_fx_idx%" + "%index2%") * 0x30)) "opcode"
     PATCH_IF ("%opcode%" = 104) BEGIN // xp bonus
       WRITE_BYTE ("%fx_off%" + 0x0c + (("%abil_fx_idx%" + "%index2%") * 0x30)) 1 // timing mode
     END
   END
 END
 BUT_ONLY_IF_IT_CHANGES

 

Talons has a timing mode of 2 (!) for the icon effect. Doesn't make much difference (the icon is automatically applied with the blindness), but still. Should be 9. SPIN613.

 

// talons icon eff has different timing than other effects
COPY_EXISTING ~spin613.spl~ ~override~
 READ_LONG  0x64 "abil_off"
 READ_SHORT 0x68 "abil_num"
 READ_LONG  0x6a "fx_off"
 FOR (index = 0; index < abil_num; index = index + 1) BEGIN
   READ_SHORT ("%abil_off%" + 0x1e + (0x28 * "%index%")) "abil_fx_num"
   READ_SHORT ("%abil_off%" + 0x20 + (0x28 * "%index%")) "abil_fx_idx"
   FOR (index2 = 0; index2 < abil_fx_num; index2 = index2 + 1) BEGIN
     READ_SHORT ("%fx_off%" +        (("%abil_fx_idx%" + "%index2%") * 0x30)) "opcode"
     READ_ASCII ("%fx_off%" + 0x14 + (("%abil_fx_idx%" + "%index2%") * 0x30)) "eff_file"
     PATCH_IF (("%opcode%" = 283) AND ("%eff_file%" STRING_COMPARE_CASE "deck613a" = 0)) BEGIN // use deck613a.eff as curse
       WRITE_BYTE ("%fx_off%" + 0x0c + (("%abil_fx_idx%" + "%index2%") * 0x30)) 9 // timing mode
       WRITE_LONG ("%fx_off%" + 0x0e + (("%abil_fx_idx%" + "%index2%") * 0x30)) 0 // duration
     END
   END
 END
 BUT_ONLY_IF_IT_CHANGES

 

AR4500.bcs tries to set LOCALS ActiveKeldorn. Excepting that this is completely pointless (it's only for SoA if you go to the sewers before getting the quest), ActionOverride() may work (if not, I'd just move it to Keldorn's 25 script).

 

IIRC, I've tried setting LOCALS via ActionOverride and it doesn't work. I just extended keld25 with this:

 

IF
       Global("KeldornSummoned","GLOBAL",1)
       Global("KeldornSpawnPlane","GLOBAL",1)
       !Global("ActiveKeldorn","LOCALS",1)
       AreaCheck("ar4500")
THEN
       RESPONSE #100
               SetGlobal("ActiveKeldorn","LOCALS",1)
END

 

BSHOP02, GARLENA, SAHPR1, and SUELF10 will all try to sell you a single throwing axe. Thanks a bunch. They should sell quantity 5.

// sell stacks of 1 throwing axe
COPY_EXISTING ~bshop02.sto~ ~override~
 ADD_STORE_ITEM + ~ax1h04~ #5 #0 #0 ~IDENTIFIED~ #3
 BUT_ONLY_IF_IT_CHANGES

// sell stacks of 1 throwing axe
COPY_EXISTING ~garlena.sto~ ~override~
             ~sahpr1.sto~  ~override~
             ~suelf10.sto~ ~override~
 ADD_STORE_ITEM + ~ax1h04~ #5 #0 #0 ~IDENTIFIED~ #2
 BUT_ONLY_IF_IT_CHANGES

[SimDing0]

IIRC, I've tried setting LOCALS via ActionOverride and it doesn't work. I just extended keld25 with this:

I've always thought it does. Hmm.

[CamDawg]

Don't put too much weight in that statement. It was during a bugfix session where I threw a bunch of patches at the bug to see which one stuck.