berelinde

You can release Mazzy and then not recruit her, you know.

It's probable that the issue is reinstalling the mod without backing out Edwin flirts first. WeiDU is usually really good about not corrupting files when reinstalling, but file corruption does sometimes occur. You'll probably be alright once you're in areas you haven't visitied yet. For future reference, I did neglect to delete the beta-testing reinstallation instructions in the documents folder, so it's there should the occasion arise.

Regarding the typos, I was able to find the greet/great one, but I can't find the other. I'm dyslexic, so it's really, really tough for me to spot typos in written text. Could someone else have a peek?

So much for no issues.

You got v7?

Edit: Now I'm on the BG2 computer, so I can address this more thoroughly. Evaine Dian reported this issue and it was fixed already. I just confirmed that the fix is still present in v7. As long as your mods are installed in the same order, you should be able to reload an old save.

This is the dialogue block that was glitching. Previously, I had forgotten the DO, but now that's there, so there's no reason for this dialogue to repeat... if you're using v7. If you just reinstalled an older version, it will still be glitching.

/* Gavin-Mazzy 2 - breakfast in high places */
CHAIN
IF ~Global("B!GavMaz2","GLOBAL",1)~ THEN ~B!GavJ~ BGavMaz2 
~[GAVIN] Can I get that for you, Mazzy?~ [bgav244] 
DO ~SetGlobal("B!GavMaz2","GLOBAL",2)~ 
== MAZZYJ ~[MAZZY] No, I can reach...~ 
= ~[MAZZY] Confound it, I can't reach it. Why do we have to tie our food up so high?~ 
== ~B!GavJ~ ~[GAVIN] It's the bears. They'll rummage through anything we leave on the ground.~ 
== MAZZYJ ~[MAZZY] Still, it's rather inconsiderate to task someone with cooking breakfast and then tie all the food eight bloody feet off the ground.~ 
== ~B!GavJ~ ~[GAVIN] Heh. I suppose it is, at that.~ 
EXIT

Well, it's been over 24 hours and nothing new here. Either that means that nobody's having any more issues or it means that everyone has given up. Let's hope for the latter.

OK, v7 is uploaded. Now the Lust Chamber Specials work and the evil PC redemption path works as intended. There are also a number of incidental typos fixed, but we won't talk about that.

The Masyrd bug is real, though. I ran into it in testing and fixed it, but then dummy went and packaged the wrong file, so the changes never made it into the finished mod. It's mostly dialogue typos, though, rather than code typos.

Just as well. The evil PC redemption path wasn't working properly before. Now it is. Part of the reason that this has taken so long is that I went back and tested everything to make sure the fixes actually fixed what they were supposed to fix. With over 70 saved games to choose from, I had one close to that point.

I'm uploading v7 as I type. This will have all the fixes that were included in alpha 43. With any luck, this will be the last of them, although it's still possible that there are typos in the mod. No matter how careful I am or how thorough my proofreaders were (and they really were... you should have *seen* some of the typos!), there are always a few that sneak through. Heck, BG2 has been out for 10 years and people are still finding typos.

Heh. Looks like congratulations may be a bit premature. I was wondering why some of the reported bugs looked so familiar, like things I fixed in earlier releases. Now I know the reason. I accidentally packaged alpha 42 instead of alpha 43, so all the bugs I fixed in alpha 43 are still there. (big sigh)

Well, at least I kept meticulous changelogs, so going back and fixing the rest won't be a big deal.

Apologies for any inconvenience this might cause. It's going to take me a little while to sort this out, but I should still be able to have a fixed version up in an hour or so.

Yeah, I kind of need either screenshots or quotes for the typos and NVROL.

I'm starting to wonder if I uploaded the wrong version or something, because I *know* I fixed that drow encounter. This thing had 43 alphas, so I suppose it's possible that I packaged the wrong one. You are talking about the one with Masyrd, right?

Does he keep repeating "Thank you for that" or do you have to go through the whole dialogue over and over? And I really don't get it, because I'm closing the variables in every PC reply option in the first state. Not only that, but the dialogue is called from the cutscene, not by the script, so it really should only get triggered once.

Nope, I uploaded the wrong version, I'm sure of it now. Because it's got the same error I had in alpha 42 that I fixed in alpha 43.

I'll check the rest of the stuff I had on the changelog for that alpha and upload v7 in 45. Gods, I feel like an ass.

If you find any, please put them here.

OK, udated version updated. Kind of makes me wish I was using decimal numbers for releases. I wouldn't feel so bad about 6 versions out in 48 hours.

Yup. I'm an idiot. It's official. I'm missing a DO in a crucial spot.

I'll update (again...), but you can get that banter to stop looping by typing this into the console:

CLUAConsole:SetGlobal("B!GavMaz2","GLOBAL",2)

Or you can wait for the update, which will take half an hour, assuming the cat leaves me alone long enough to do it.

Haldamir NPC for BGII



Haldamir is an NPC mod for Baldur's Gate II, BGT, or BGII:EE. He is an unkitted elven fighter and can be found in the Den of the Seven Vales in Waukeen's Promenade.

• Learn more about the mod
• View the Readme
• Download the mod

Questions? Comments? Bug/Typo reports? They can go here until there's a forum.

I'll start with an answer.

At the moment, Haldamir has no ToB content, but it will have some soonish.

Cool. Checking that BCS will be the definitive answer, I think.

Stranger and stranger, as they say. The "breakfast in high places" banter is only supposed to happen when the party has rested. Does it keep repeating again and again and again, or is it just happening every once in a while?

Back when BG1 Gavin was still in alpha testing, I had a scripted dialogue that repeated against all possibility because another scripted banter was set to fire but could not due to impossible triggers. Is it possible that another mod is telling Mazzy that it's time to say something but there's nothing in her dialogue file to say? When an NPC has player-initiated dialogue, the PID menu keeps popping up over and over, but when the NPC has no PID, you'll get a scripted dialogue at random. Mazzy has no PID.

If you were really curious, you could follow the steps that I outlined for KathStoneDog and use mazzy.bcs instead of minsc.bcs. If a dialogue keeps firing over and over, there's bound to be a script block associated with it. Even if the problem is with some other mod or the vanilla game, I'm sure the information would be useful.

OK, v5 up. It fixes the Jan dialogue loop.

And yes, I don't know what's up with Aerie and Yoshimo, but I do know it isn't Gavin. One of my testers took Aerie along the whole time and the only stutter she had was a vanilla game bug because the reminder to go see Raelis wasn't firing. I personally took Yoshimo through the whole way without a hiccup. Perhaps, as you say, it is the Yoshimo friendship. None of my testers were using it, IIRC.

Yup, I see that the banter with Jan is set to repeat. I'll put up a fix momentarily, but I'm going to post the code for the others so you can see that the variables are all closing properly.

Anyway, give me less than half an hour and I'll have your Jan issue resolved. Unfortunately, there isn't much I can do for Mazzy, since her banter shouldn't be repeating at all.

Mazzy with the food out of reach:

CHAIN
IF ~Global("B!GavMaz2","GLOBAL",1)~ THEN ~B!GavJ~ BGavMaz2 
~[GAVIN] Can I get that for you, Mazzy?~ [bgav244] 
~SetGlobal("B!GavMaz2","GLOBAL",2)~ 
== MAZZYJ ~[MAZZY] No, I can reach...~ 
= ~[MAZZY] Confound it, I can't reach it. Why do we have to tie our food up so high?~ 
== ~B!GavJ~ ~[GAVIN] It's the bears. They'll rummage through anything we leave on the ground.~ 
== MAZZYJ ~[MAZZY] Still, it's rather inconsiderate to task someone with cooking breakfast and then tie all the food eight bloody feet off the ground.~ 
== ~B!GavJ~ ~[GAVIN] Heh. I suppose it is, at that.~ 
EXIT

Aerie's banters. If she's got stutter, it isn't Gavin.

/* Gavin-Aerie 1 - Quayle */
CHAIN
IF ~
InParty("Aerie")
Global("B!GavAer1","GLOBAL",0)
Dead("Kalah")
!Dead("Quayle")
!StateCheck(Myself,CD_STATE_NOTVALID)
!StateCheck("Aerie",CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
See("Aerie")
~ THEN ~BB!Gav~ GavAer1
~[GAVIN] Quayle means a lot to you, doesn't he?~ [bgav200] 
DO ~SetGlobal("B!GavAer1","GLOBAL",1)~
== BAERIE ~[AERIE] He was my only friend in the circus. I will never forget his kindness.~
== ~BB!Gav~ ~[GAVIN] I am glad that you can recall even one part of your past fondly, after your ordeal.~
== BAERIE ~[AERIE] He was the only one who did not taunt me, torture me. I... don't want to remember.~
== ~BB!Gav~ ~[GAVIN] I can understand that. Still, you developed a strength few people could claim. That Quayle can take credit for encouraging it speaks well of him, but the strength was yours, not his.~
== BAERIE ~[AERIE] I was not given a choice. It was all forced on me. Quayle did not have to help me, but he did.~
== ~BB!Gav~ ~[GAVIN] But you did help him. From what I understand, he was far less compassionate before he met you.~
== BAERIE ~[AERIE] You shouldn't t-talk about him like that!~
== ~BB!Gav~ ~[GAVIN] You're right. I should not. I am sorry.~
EXIT

/* Gavin-Aerie additional banter 1 - backward tunic */ 
CHAIN
IF ~
InParty("B!Gavin2")
Global("B!GavAerAdd1","LOCALS",0)
!StateCheck(Myself,CD_STATE_NOTVALID)
!StateCheck("B!Gavin2",CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
See("B!Gavin2")
~ THEN BAERIE GavAerAdd1
~[AERIE] Heehee! You've got your tunic on backward.~ [bg_blank] 
DO ~SetGlobal("B!GavAerAdd1","LOCALS",1)~
== ~BB!Gav~ ~[GAVIN] Ah, yes. So I do. No wonder it felt funny.~ [bgav201] 
== BAERIE ~[AERIE] Don't you even look at your clothes when you're putting them on?~
== ~BB!Gav~ ~[GAVIN] Not usually, no.~
== BAERIE ~[AERIE] That explains a lot.~
EXIT 

/* Gavin-Aerie 2 - ogres and circuses */
CHAIN
IF ~
InParty("Aerie")
Global("B!GavAer2","GLOBAL",0)
Dead("Kalah")
!StateCheck(Myself,CD_STATE_NOTVALID)
!StateCheck(Myself,CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
See("Aerie")
~ THEN ~BB!Gav~ GavAer2
~[GAVIN] I wonder why people find ogres so funny.~ [bgav202] 
DO ~SetGlobal("B!GavAer2","GLOBAL",1)~
== BAERIE ~[AERIE] What?~
== ~BB!Gav~ ~[GAVIN] You aren't the first ogre to have graced a circus.~
== BAERIE ~[AERIE] B-but I'm not an ogre! I'm an avariel!~
== ~BB!Gav~ ~[GAVIN] You were turned into an ogre for the circus, though. I suppose Kalah thought it was comical.~
== BAERIE ~[AERIE] Well, I didn't think it was funny. I was so... ugly, and huge! I was so happy when <CHARNAME> turned me back again. If only I could have been turned back whole...~
== ~BB!Gav~ ~[GAVIN] Yes, well, as I said, I have seen an ogre - a real ogre, or at least I thought he was, at the carnival at Nashkel. His keeper, the Great Gazib, would make him explode, over and over again.~
== BAERIE ~[AERIE] That's monstrous!~
== ~BB!Gav~ ~[GAVIN] It was. One day, the ogre decided he'd had enough, and struck Gazib hard enough to kill him.~
== BAERIE ~[AERIE] What happened then?~
== ~BB!Gav~ ~[GAVIN] I don't know. I would like to think that the ogre made it to freedom and is raising a family of little ogres far, far away from humans.~
== BAERIE ~[AERIE] But what would have happened if the ogre had been chained?~
== ~BB!Gav~ ~[GAVIN] I suppose the chains would have fallen off when he blew up. But he got away. I guess ogres and circuses don't work out, after all.~
== BAERIE ~[AERIE] Circuses are always cruel, though.~
== ~BB!Gav~ ~[GAVIN] You are probably right. I still like to watch the jugglers, though.~
EXIT

/* Gavin-Aerie Additional 2 - Early riser */ 
CHAIN 
IF WEIGHT #-1 ~Global("B!GavAerAdd2","GLOBAL",1)~ THEN ~B!GavJ~ BGavAerAdd2 
~[GAVIN] Ah, you're up already. Not often I meet someone who rises as early as I do.~ [bgav203] 
DO ~SetGlobal("B!GavAerAdd2","GLOBAL",2)~ 
== AERIEJ ~[AERIE] This is my favorite time of the day, when the birds are just starting to sing and the dew is on the grass. Everything is so peaceful.~ 
== ~B!GavJ~ ~[GAVIN] Then your reasons are better than mine.~ 
== AERIEJ ~[AERIE] What do you mean?~ 
== ~B!GavJ~ ~[GAVIN] I worship at dawn, so I have to get up early enough to be awake for it.~ 
== AERIEJ ~[AERIE] I thought you just enjoyed the quiet.~ 
== ~B!GavJ~ ~[GAVIN] It's habit as much as anything else. Though I do admit, I like the stillness before the world wakes up.~ 
== NALIAJ IF ~InParty("Nalia") 
  See("Nalia") 
  !StateCheck("Nalia",CD_STATE_NOTVALID)~ ~[NALIA] Oh, Gavin, you're up. When's breakfast?~ 
== ANOMENJ IF ~InParty("Anomen") 
  See("Anomen") 
  !StateCheck("Anomen",CD_STATE_NOTVALID) 
  OR(3) !InParty("Nalia") 
	  !See("Nalia") 
	  StateCheck("Nalia",CD_STATE_NOTVALID)~ ~[ANOMEN] Ah, I see you're awake. Is the water on?~ 
== EDWINJ IF ~InParty("Edwin") 
  See("Edwin") 
  !StateCheck("Edwin",CD_STATE_NOTVALID) 
  OR(3) !InParty("Nalia") 
	  !See("Nalia") 
	  StateCheck("Nalia",CD_STATE_NOTVALID) 
  OR(3) !InParty("Anomen") 
	  !See("Anomen") 
	  StateCheck("Anomen",CD_STATE_NOTVALID)~ ~[EDWIN] All this chatter, and still no breakfast?~ 
== JAHEIRAJ IF ~InParty("Jaheira") 
  See("Jaheira") 
  !StateCheck("Jaheira",CD_STATE_NOTVALID) 
  OR(3) !InParty("Nalia") 
	  !See("Nalia") 
	  StateCheck("Nalia",CD_STATE_NOTVALID) 
	  OR(3) !InParty("Anomen") 
		  !See("Anomen") 
		  StateCheck("Anomen",CD_STATE_NOTVALID)
	  OR(3) !InParty("Edwin") 
		 !See("Edwin") 
		 StateCheck("Edwin",CD_STATE_NOTVALID) ~ ~[JAHEIRA] You're awake? And I see you have the fire started. Good, we can set off soon after breakfast.~ 
== KORGANJ IF ~InParty("Korgan") 
  See("Korgan") 
  !StateCheck("Korgan",CD_STATE_NOTVALID) 
  OR(3) !InParty("Nalia") 
	  !See("Nalia") 
	  StateCheck("Nalia",CD_STATE_NOTVALID) 
  OR(3) !InParty("Anomen") 
	  !See("Anomen") 
	  StateCheck("Anomen",CD_STATE_NOTVALID) 
  OR(3) !InParty("Edwin") 
	  !See("Edwin") 
	  StateCheck("Edwin",CD_STATE_NOTVALID) 
  OR(3) !InParty("Jaheira") 
	  !See("Jaheira") 
	  StateCheck("Jaheira",CD_STATE_NOTVALID)~ ~[KORGAN] Such a racket! You'd damn well better have breakfast ready.~ 
== AERIEJ IF ~OR(3) !InParty("Nalia") 
	  !See("Nalia") 
	  StateCheck("Nalia",CD_STATE_NOTVALID) 
  OR(3) !InParty("Anomen") 
	  !See("Anomen") 
	  StateCheck("Anomen",CD_STATE_NOTVALID) 
  OR(3) !InParty("Edwin") 
	  !See("Edwin") 
	  StateCheck("Edwin",CD_STATE_NOTVALID) 
  OR(3) !InParty("Jaheira") 
	  !See("Jaheira") 
	  StateCheck("Jaheira",CD_STATE_NOTVALID) 
  OR(3) !InParty("Korgan") 
	  !See("Korgan") 
	  StateCheck("Korgan",CD_STATE_NOTVALID)~ ~[AERIE] And you've already started breakfast.~
== ~B!GavJ~ ~[GAVIN]That, too, is a habit.~ 
EXIT 

/* Gavin-Aerie 3 - slavery is wrong */
CHAIN
IF WEIGHT #-1 ~Global("B!GavAer3","GLOBAL",2)~ THEN ~AERIEJ~ GavAer3
~[AERIE] It is just wrong for those slavers to treat people like that.~ [bg_blank] 
DO ~SetGlobal("B!GavAer3","GLOBAL",3)~
== ~B!GavJ~ ~[GAVIN] I agree.~ [bgav204] 
== ~AERIEJ~ ~[AERIE] Life means nothing to those... savages! They treat people like animals and never care if they sicken in captivity.~
== ~B!GavJ~ ~[GAVIN] Aerie, what they did to you was unspeakable. I am filled with admiration that you could have emerged from it alive, yet you did, without losing your compassion.~
== ~AERIEJ~ ~[AERIE] Well, I don't want anyone else to have to suffer, either.~
== ~B!GavJ~ ~[GAVIN] No, of course not. But your story brings me hope that some of those that we rescued may one day overcome the hurt that was done them.~
== ~AERIEJ~ ~[AERIE] Will their scars ever really heal, though?~
EXIT

/* Gavin-Aerie 4 - the fight */
CHAIN
IF WEIGHT #-1 ~Global("B!GavAerConflict","GLOBAL",2)~ THEN ~AERIEJ~ GavAer4
~[AERIE] What are you doing?~ [bg_blank] 
DO ~SetGlobal("B!GavAerConflict","GLOBAL",3)~
== ~B!GavJ~ ~[GAVIN] Writing a letter to my parents. I haven't written to them in months. I am sure they will want to know I'm alive.~ [bgav205] 
== ~AERIEJ~ ~[AERIE] You are so cruel!~
== ~B!GavJ~ ~[GAVIN] What did I do?~
== ~AERIEJ~ ~[AERIE] You are always reminding me of the things I'll never have again, like my wings, or a life without the memory of captivity, or a family. (sniff) Do you have any idea how... alone I am? How much I've lost?~
== ~B!GavJ~ ~[GAVIN] Oh, no. Not this time.~
= ~Aerie, I am very sorry about everything that has been done to you, but you need to let it go.~
== ~AERIEJ~ ~[AERIE] It is easy for you to say. You weren't there. No one... hacked off the one thing that connected you to the rest of your kin. No matter where I go, now, I will never be one of them again.~
== ~B!GavJ~ ~[GAVIN] You are more than a pair of wings, Aerie.~
== ~AERIEJ~ ~[AERIE] You make it sound so easy, like all I have to do is forget it happened, but every time I look up and see the sky, I remember flying.~
== ~B!GavJ~ ~[GAVIN] The infection that took your wings could have easily taken your life. I have seen it. A leg wound sours, the infection spreads. There are men that would choose to risk their lives for a chance to keep a festering leg.~
== ~AERIEJ~ ~[AERIE] I was never given the choice!~ 
= ~My whole life, other people have decided my fate. Ever since I was stolen away from my parents... ~
= ~It was always someone else's decision, always someone else controlling my life, and I can't forgive them for taking away the one thing that made me what I was.~ 
== ~B!GavJ~ ~[GAVIN] Believe me, he did not do it for his own benefit. Is it so hard to forgive a fool? You were worth more to him whole. With wings, you were a novelty. Without them, you were just an elf, and no one pays money to see elves.~
== ~AERIEJ~ ~[AERIE] You're s-supposed to be a priest! How can you say such things?~
== ~B!GavJ~ ~[GAVIN] There is evil in this world. I did not invent it. If you cling to this evil, this resentment, you will forever be your captor's victim.~
== ~AERIEJ~ ~[AERIE] How can you say such things to me?! <CHARNAME>, Gavin is being cruel to me!~
END
+ ~GlobalGT("AerieRomanceActive","GLOBAL",0)~ + ~[PC] Gavin, back off! Aerie has been through enough.~ EXTERN ~B!GavJ~ GavAer4.1
+ ~Global("AerieRomanceActive","GLOBAL",0)~ + ~[PC] Gavin, back off! Aerie has been through enough.~ EXTERN ~B!GavJ~ GavAer4.2
+ ~GlobalGT("AerieRomanceActive","GLOBAL",0)~ + ~[PC] Aerie, please try to be reasonable.~ EXTERN ~AERIEJ~ GavAer4.3
+ ~Global("AerieRomanceActive","GLOBAL",0)~ + ~[PC] Aerie, please try to be reasonable.~ EXTERN ~AERIEJ~ GavAer4.4

CHAIN
IF ~~ THEN ~B!GavJ~ GavAer4.1
~[GAVIN] (sigh) Yes. Of course.~
END
++ ~[PC] I'll have no more squabbling. We're all on the same side.~ EXTERN ~B!GavJ~ GavAer4.5
++ ~[PC] You owe Aerie an apology.~ EXTERN ~B!GavJ~ GavAer4.6
++ ~[PC] It's been a long day, and we've all had a lot on our minds. Let's just sleep on it.~ EXTERN ~B!GavJ~ GavAer4.7

CHAIN
IF ~~ THEN ~B!GavJ~ GavAer4.2
~[GAVIN] Coddling her is not going to help.~
END
++ ~[PC] I'll have no more squabbling. We're all on the same side.~ EXTERN ~B!GavJ~ GavAer4.5
++ ~[PC] You owe Aerie an apology.~ EXTERN ~B!GavJ~ GavAer4.8
++ ~[PC] It's been a long day, and we've all had a lot on our minds. Let's just sleep on it~ EXTERN ~B!GavJ~ GavAer4.7

CHAIN
IF ~~ THEN ~AERIEJ~ GavAer4.3
~[AERIE] How can I be reasonable when he attacks me like that?! After everything I've been through, he has no right to yell at me like that.~
== ~B!GavJ~ ~[GAVIN] She's right, <CHARNAME>, I don't. Listen, it just isn't worth arguing over this. You've got a fine cleric in Aerie, and you don't need a quarrelsome Lathandrite right now.~
= ~[GAVIN] I do not wish to be a source of friction in this company. If you've no objection, I think I will go back to the temple for a while and meditate, or go visit my daughter at the temple of Oghma, if I can interrupt her studies for a while.~
END
+ ~RandomNum(2,1)~ + ~[PC] If that is what you want to do. I will know where to find you.~ EXTERN ~B!GavJ~ GavAer4.9
+ ~RandomNum(2,2)~ + ~[PC] If that is what you want to do. I will know where to find you.~ EXTERN ~B!GavJ~ GavAer4.10
++ ~[PC] No, Gavin, I want you to stay.~ EXTERN ~B!GavJ~ GavAer4.11

CHAIN
IF ~~ THEN ~AERIEJ~ GavAer4.4
~[AERIE] How can I be reasonable when he attacks me like that?! After everything I've been through, he has no right to yell at me like that.~
== ~B!GavJ~ ~[GAVIN] When you start basing accusations on whether or not someone is close to his family, it is kind of hard to come to the conclusion that you are being anything other than unreasonable.~
END
++ ~[PC] Gavin, Aerie, that's enough from both of you. I am going to bed. I'll hear no more of this.~ DO ~RestParty()~ EXIT
++ ~[PC] Gavin, you're never going to win this one. Just let it be.~ EXTERN ~B!GavJ~ GavAer4.12
++ ~[PC] Aerie, just let it be. Please.~ EXTERN ~AERIEJ~ GavAer4.13

APPEND ~B!GavJ~

IF ~~ THEN BEGIN GavAer4.5
SAY ~[GAVIN] Er, yes, of course... If you'll excuse me, I think I'll just go to bed now.~
IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ THEN BEGIN GavAer4.6
SAY ~[GAVIN] Would it even mean anything? Never mind. I have swallowed worse things than my pride.~
= ~[GAVIN] Aerie, I am sorry my actions bring back painful memories. Now, if you will excuse me, I am going to bed.~
IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ THEN BEGIN GavAer4.7
SAY ~[GAVIN] Most sensible thing I've heard for hours.~
IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ THEN BEGIN GavAer4.8
SAY ~[GAVIN] Like hells I do. Listen, <CHARNAME>, if you want to pamper her, that's your business. I'm going to bed.~
IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ THEN BEGIN GavAer4.9 /* Gavin was going to go to the Temple of Oghma, but now he's going to the temple of Lathander */
SAY ~[GAVIN] Farewell.~
IF ~Global("B!GavRA","GLOBAL",2)~ THEN DO ~SetGlobal("B!GavJoin","GLOBAL",0) 
		SetGlobal("B!GavRomBreak","GLOBAL",1) 
		SetGlobal("B!GavRA","GLOBAL",3) 
		EscapeAreaMove("AR0902",805,1053,10)~ EXIT 
IF ~Global("B!GavRA","GLOBAL",4)~ THEN DO ~SetGlobal("B!GavJoin","GLOBAL",0) 
		SetGlobal("B!GavRA","GLOBAL",3) 
		SetGlobal("B!GavRA","GLOBAL",2) 
		EscapeAreaMove("AR0902",805,1053,10)~ EXIT 
IF ~OR(2) Global("B!GavRA","GLOBAL",0) 
  Global("B!GavRA","GLOBAL",3)~ THEN DO ~SetGlobal("B!GavJoin","GLOBAL",0) 
		EscapeAreaMove("AR0902",805,1053,10)~ EXIT 
END 

IF ~~ THEN BEGIN GavAer4.10 /* Gavin goes to Temple of Lathander */
SAY ~[GAVIN] Farewell.~
IF ~Global("B!GavRA","GLOBAL",2)~ THEN DO ~SetGlobal("B!GavJoin","GLOBAL",0) 
		SetGlobal("B!GavRomBreak","GLOBAL",1) 
		SetGlobal("B!GavRA","GLOBAL",3) 
		EscapeAreaMove("AR0902",805,1053,10)~ EXIT 
IF ~Global("B!GavRA","GLOBAL",4)~ THEN DO ~SetGlobal("B!GavJoin","GLOBAL",0) 
		SetGlobal("B!GavRA","GLOBAL",3) 
		SetGlobal("B!GavRA","GLOBAL",2) 
		EscapeAreaMove("AR0902",805,1053,10)~ EXIT 
IF ~OR(2) Global("B!GavRA","GLOBAL",0) 
  Global("B!GavRA","GLOBAL",3)~ THEN DO ~SetGlobal("B!GavJoin","GLOBAL",0) 
		EscapeAreaMove("AR0902",805,1053,10)~ EXIT 
END 

IF ~~ THEN BEGIN GavAer4.11
SAY ~[GAVIN] If you insist, I will. But I am going to bed. Goodnight.~
IF ~~ THEN DO ~RestParty()~ EXIT
END

IF ~~ THEN BEGIN GavAer4.12
SAY ~[GAVIN] As you wish. Goodnight.~
IF ~~ THEN DO ~RestParty()~ EXIT
END
END 

APPEND AERIEJ 

IF ~~ THEN BEGIN GavAer4.13
SAY ~[AERIE] B-but...! Oh! You're as mean as Gavin! I am going to bed!~
IF ~~ THEN DO ~RestParty()~ EXIT
END
END 

CHAIN 
IF ~Global("B!GavAerConflict","GLOBAL",5)~ THEN ~B!GavJ~ BGavAerApology 
~[GAVIN] I shouldn't have blown up at you, Aerie. It isn't easy to say it, but I'm sorry.~ [bgav206] 
DO ~SetGlobal("B!GavAerConflict","GLOBAL",6)~ 
== AERIEJ ~[AERIE] Why is it hard to say?~ 
== ~B!GavJ~ ~[GAVIN] Because it's the same as admitting I was wrong.~ 
== AERIEJ ~[AERIE] Thank you. Why did you do it? B-Blow up, I mean?.~ 
== ~B!GavJ~ ~[GAVIN] I get frustrated, sometimes. I say things I shouldn't say.~ 
== AERIEJ ~[AERIE] That would mean... you really think that way.~ 
== ~B!GavJ~ ~[GAVIN] Sometimes... ~ 
== ~B!GavJ~ ~[GAVIN] No, Aerie. I don't. Not really.~ 
== VICONIJ IF ~InParty("Viconia") See("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN ~[VICONIA] Liar.~ 
== ~B!GavJ~ IF ~InParty("Viconia") See("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN ~[GAVIN] Shut up, Viconia. You don't know what I'm thinking.~ 
== VICONIJ IF ~InParty("Viconia") See("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN ~[VICONIA] I've heard you muttering.~ 
== ~B!GavJ~ IF ~InParty("Viconia") See("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN ~[GAVIN] Everybody grumbles, sometimes. It's nothing more than blowing off steam.~ 
== VICONIJ IF ~InParty("Viconia") See("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN ~[VICONIA] Hmf. You really will say anything to keep the waif happy.~ 
== ~B!GavJ~ IF ~InParty("Viconia") See("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN ~[GAVIN] Ignore her, Aerie. She doesn't know what she's talking about.~ 
== AERIEJ IF ~InParty("Viconia") See("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN ~[AERIE] I... I don't know what to think. Are you just patronizing me?~ 
== ~B!GavJ~ IF ~InParty("Viconia") See("Viconia") !StateCheck("Viconia",CD_STATE_NOTVALID)~ THEN ~[GAVIN] No, Aerie, I'm not. I swear.~ 
== AERIEJ ~[AERIE] All right... I believe you.~ 
== ~B!GavJ~ ~[GAVIN] Thank you.~ 
EXIT 

CHAIN
IF ~
InParty("B!Gavin2")
Global("B!GavAerAdd3","LOCALS",0)
!StateCheck(Myself,CD_STATE_NOTVALID)
!StateCheck("B!Gavin2",CD_STATE_NOTVALID)
CombatCounter(0)
!See([ENEMY])
See("B!Gavin2")
~ THEN BAERIE GavAerAdd3
~[AERIE]I think I know that song.~ [bg_blank] 
DO ~SetGlobal("B!GavAerAdd3","LOCALS",1)~
== ~BB!Gav~ ~[GAVIN]You jest. No one has ever been able to recognize a tune I'm humming.~ [bgav207] 
== BAERIE ~[AERIE]No, you're completely tone-deaf, I'm sure, but I know that meter.~ 
== ~BB!Gav~ ~[GAVIN]Now I'm amazed. I didn't mean to, but I was humming a bawdy song I heard in a tavern back in Beregost.~ 
== BAERIE ~[AERIE]Really? It sounded so much like a tune I remembered from my childhood.~ 
== ~BB!Gav~ ~[GAVIN]It's probably hard to tell, the way I hum it.~ 
EXIT

Thanks!

And KathStoneDog, your issue was a vanilla game bug, apparently, just like the one Gavin's testers found with Aerie. Minsc is trying to remind you to go to Imnesvale. I've got directions on how to solve it up in the other thread.

Good news! At least for me. Well, I'm happy it isn't my mod, anyway.

Like the person who found the previously undiscovered Aerie bug, you've found a previously discovered Minsc bug. Minsc is trying to remind you that you told Delon that you will go to Imnesvale.

There are two ways that you can fix this. Either you can go to Imnesvale and talk to Minister Lloyd or you can use the console to get Minsc to stop stuttering.

If you want to use the console, open it up, select Minsc, and leave the mouse hovering over Minsc's portrait. Now type the following into the console and hit enter.

CLUAConsole:SetGlobal("MinscReminder","LOCALS",2)

Keep in mind that if you don't go to Imnesvale, it's possible that Delon will chase you all over Athkatla.

If you want to use the console but don't know how, I can tell you how to do that.

No, I didn't know you sent a zip. I'll look at it right away.

Gavin for BG2 is now up to version 4. Apparently my custom of using EXTEND_BOTTOM wherever possible was causing some difficulties on a mega-install. Another script was blocking it.

Yeah, I was in the process of updating the mod because another user was having issues getting BG2 Gavin to play nicely on a mega-install. The Temple District cutscene was never starting because of some script introduced by another mod.

This won't help with your Minsc stutter, though. You're probably still going to have to decompile and send that file.

Just load your last save. You will want to use one as close to the stutter as you possibly can.

"Lag" is usually used when *all* the characters are slowing down, the game clock is moving jerkily, and scripts frequently misfire. It is usually caused by having an override folder that's too large, i.e. too many mods installed.

"Stutter" is usually used when only one character doesn't complete movement commands. It's usually caused by a script loop. You've got stutter.

But I'm glad you're willing to try it. It's always possible that it is the Gavin mod, though you'd think that with all the testers we had whose party included Minsc we would have found it. Regardless of whether it is or it isn't, we'll find the culprit and fix it. One way or another.

Edit: You did great! Once you've got that script decompiled, we'll be able to sort it out quickly.

This is strange. I'm only making one script call on Minsc in the entire mod, when Gavin is drunk, and the scripts and variables check out for it.

During testing, one of my testers discovered a vanilla game bug that was leading to Aerie stutter. It's possible that this could be something similar. It could also be another mod... or something else entirely. If you're up to doing a little bit of detective work, you might be doing the gaming community a great service. It will involve a little bit of effort on your part, though, but I'll walk you through it every step of the way.

I made up a little mod to help the testers troubleshoot any stutter they might encounter. You can download it here. Just install this at the end of your installation like you would any other mod and then restart the game. You'll see the dialogue box fill up with things like Player1: running block 8 or minsc.bcs. One of them will repeat over and over. Once you have found out which script is looping, you can follow these steps to pinpoint the exact location of the stutter.

1. Download a version of WeiDU to your game directory, like you do with mods. Get it here.
   
2. Extract (unzip) the archive, and then open it.
   
3. Inside the WeiDU folder, you will find a file called WeiDU.exe. Right-click on it and select COPY.
   
4. Go back to your game directory and PASTE WeiDU.exe there.
   
5. Open a command prompt (DOS window). If you are using Windows XP, you can do this by clicking on the Start button and typing cmd into the box next to "run". That will open a command prompt. If you are using Vista, type cmd into the box next to "Search". You should see several Help topics. One of them will be "Open Command Prompt?" Choose that one, and it will open a command prompt.
   
6. Go to the new window and navigate to your game installation directory. If you used the default installation, you would type in
   cd c:\program files\black isle\bgii - soa
   
7. Notice how the prompt now shows the path to your BG2 installation? Good, that's what you want.
   
8. You're ready to decompile files!
   
9. To decompile a file, type in weidu foo.ext, where foo is the file you want to decompile and .ext is the extension type. Dialogue files use the extension .dlg, script files use the extension .bcs. So, if it's Minsc's script that's looping, you would type in "weidu minsc.bcs" without the quotes.
   
10. WeiDU will create the decompiled file in your game directory, alongside all your mods. Dialogue files will use the extension .d, script files will use the extension .baf. So you would be looking for minsc.baf.
    
11. Put the decompiled scripts into an archive and either attach it here or email it to me at my screen name at gmail dot com.
    

If you run into trouble at any point or if you need additional clarification, just ask. I keep an eye on this forum all day.

Nah, you won't have to go that far. I'll just have a peek at Minsc's scripted banters and get back to you in a few moments. I'm kind of confused, though, because a couple of my testers had Minsc the whole time without stutter (and so did I), but that doesn't mean that something didn't slip through.

OK, v3 is uploaded.

If you're running through with an evil PC, you will need to update, otherwise, you won't have to worry about it unless your next playthrough includes an evil PC.