Cutscene movement

[nethrin]

I have the following code in a cutscene. However, Weidu claims there are "too many arguments" in the EscapeAreaMove command. I know that the coordinates look odd, but they are correct for EscapeAreaMove. (Not only is it so listed in IESDP, but I have it in another mod, and it works.)

 

What is wrong?

 

Sillara, the stumped

 

Edit: (Sorry, I forgot to log-out nethrin)

 

IF
 True()
THEN
 RESPONSE #100
   CutSceneId("Edorem")
   Wait(1)
   SaveGame(0)
   FadeToColor([30.0],0)
   Wait(2)
   EscapeAreaMove("Edorem","ar1204",422,430,0)
   ActionOverride("Player1",EscapeAreaMove("ar1204",423,431,0))
   ActionOverride("Player2",EscapeAreaMove("ar1204",424,432,0))
   ActionOverride("Player3",EscapeAreaMove("ar1204",425,433,0))
   ActionOverride("Player4",EscapeAreaMove("ar1204",426,434,0))
   ActionOverride("Player5",EscapeAreaMove("ar1204",427,435,0))
   ActionOverride("Player6",EscapeAreaMove("ar1204",428,436,0))
   Wait(5)
   FadeFromColor([20.0],0)
   ActionOverride("Edorem",StartDialogueNoSet(Player1))
   EndCutSceneMode()
END

[jcompton]

The first EscapeAreaMove has too many arguments. Drop the "Edorem."

 

For the rest, the number of parameters are correct, but having "Player1" etc. in quotes is not.

[Sillara of the Tamari]

Oh thank you!!!!!

 

Goes off to fix the code.

 

(And I did know, honestly , the bit about the quotes, but I always seem to forget it whenever I go to code something important! Thank you for catching that, too! )

 

Sillara

[CamDawg]

Also, Player1 is a valid object--don't wrap it in quotes. This makes the game look for a creature with a death variable of "player1".

[jcompton]

See, Cam knew that I said that already. He just wanted to make sure you knew that he knew the answer.

[CamDawg]

I need to try this "reading" of which I've heard.

[jcompton]

I'm sorry, that's wrong.

 

Your correct response was, "Yes, but I told her why, not just what, so my answer is more complete and therefore superior to yours."

 

I can hack your database and correct that mistake for you, if you'd like.

[Sillara of the Tamari]

Regardless, thank you both!

 

Sillara

[Smoketest]

If you copy your BAF into an empty BCS file in NI and Compile, NI will report every error/warning at once, rather than halting on the first problem and leaving you clueless about the rest like WeiDU does. NI will also let you jump to the line in question. When you're done, you can use Export > Source to generate a BAF file. While you're in NI, you also have access to the handy IDS browser for quick reference. Something to consider. (I've requested the ability to convert BAF to BCS, but Jon Olav hasn't added it yet. NI will open BAF files into its text editor if they're in the override folder.)

[Sillara of the Tamari]

Oh dear. Yes, I am back again. I do not understand why this is not working. Do I have to do a cutscene chain like they do in the game?

 

This is my code:

 

IF
 True()
THEN
 RESPONSE #100
   CutSceneId("NSEDOREM")
   Wait(1)
   FadeToColor([30.0],0)
   Wait(2)
   EscapeAreaMove("ar1204",422,430,0)
   ActionOverride(Player1,EscapeAreaMove("ar1204",423,431,0))
   ActionOverride(Player2,EscapeAreaMove("ar1204",424,432,0))
   ActionOverride(Player3,EscapeAreaMove("ar1204",425,433,0))
   ActionOverride(Player4,EscapeAreaMove("ar1204",426,434,0))
   ActionOverride(Player5,EscapeAreaMove("ar1204",427,435,0))
   ActionOverride(Player6,EscapeAreaMove("ar1204",428,436,0))
   Wait(5)
   FadeFromColor([20.0],0)
   ActionOverride("NSEDOREM",StartDialogueNoSet(Player1))
   EndCutSceneMode()
END

 

The problem is that only NSEDOREM actually goes anywhere. The rest of the people just stand there, waiting for the color to come back up. Of course, since the dialogue cannot be initiated, due to the awkward fact that NSEDOREM is in another area, the cutscene never ends.

 

Do I have to chain cutscenes? Or is there something I am missing? Some trick I do not know? Any help is appreciated!

 

Thank you!

 

Sillara

[CamDawg]

It's possible that EscapeAreaMove doesn't like to be used on party members. This is what I used for G3A to move the party and Drini to a new location, modified for your script:

 

IF
 True()
THEN
 RESPONSE #100
   CutSceneId("NSEDOREM")
   Wait(1)
   FadeToColor([30.0],0)
   Wait(2)
   ActionOverride("NSEDOREM",MoveBetweenAreas("ar1204",[422.430],0))
   ActionOverride(Player1,LeaveAreaLUA("ar1204","",[423.431],0))
   ActionOverride(Player2,LeaveAreaLUA("ar1204","",[424.432],0))
   ActionOverride(Player3,LeaveAreaLUA("ar1204","",[425.433],0))
   ActionOverride(Player4,LeaveAreaLUA("ar1204","",[426.434],0))
   ActionOverride(Player5,LeaveAreaLUA("ar1204","",[427.435],0))
   ActionOverride(Player6,LeaveAreaLUA("ar1204","",[428.436],0))
   Wait(5)
   FadeFromColor([20.0],0)
   ActionOverride("NSEDOREM",StartDialogueNoSet(Player1))
   EndCutSceneMode()
END

[Sillara of the Tamari]

Oh thank you, thank you!!!

 

 

That was exactly what I needed, and it is good to know that EscapeAreaMove does not work on party members.

 

Sillara

[nethrin]

ok, it's official: sillara is silly.

 

plea to G3 global moderator(s): please disable sillara's emoticon panel.

[Sillara of the Tamari]

Now, nethrin, that wasn't very nice!

 

Sillara, taking her revenge by posting another smilie

 

 

(Sillara & nethrin)